// item types (decorate only, needs to be kept in sync with ACS)
enum {
	ItemType_Pistol			= 1,
	ItemType_Shotgun		= 2,
	ItemType_SMG			= 3,
	ItemType_Rifle			= 4,
	ItemType_RocketLauncher	= 5,
	ItemType_DemonStaff		= 6,
	ItemType_Shield			= 7,
};



ACTOR PickupBase : CustomInventory
{
	Activation THINGSPEC_TriggerTargets	// player sets its target to the pickup-item
	Height 24

	var int user_isBDPickupItem;	// used to identify thing as BorderDoom pickup item
	var int user_pickupType;	// type of pickup: weapon, shield, ...

	// weapon pickup values
	var int user_damage;
	var int user_accuracy;
	var int user_bulletCount;
	var int user_firerate;	// 1 is fastest, higher values are slower
	var int user_clipSize;
	var int user_recoil;
	var int user_value;
	var int user_itemlevel;

	+SHOOTABLE	// needed so player can look at this item and use AAPTR_PLAYER_GETTARGET to access it
	DamageFactor 0
	+NOBLOOD
	+SPECTRAL	// to make shots pass through the item - needed because of SHOOTABLE
	+DONTGIB	// prevent items from being crushed (only available in r4215+)
	// set to avoid pickup being pushed around by explosions etc
	-PUSHABLE
	+DONTTHRUST
	+NODAMAGE	// actor cannot receive any damage (includes telefrag). this prevents the pickup from getting telefragged.

	States
	{
		// can not be picked up by walking over it
		Pickup:
			TNT1 A 0
			fail
	}
}
