
// MECH-STROSITY
/*
"I swear to God If that's a hitscan weapon, I'll murder you." - insightguy, 2014
*/
ACTOR RLArmageddonDemon : RLDemonBase 16557
{
  Health 500
  GibHealth -90
  BloodType "RLNashGore_CyberBlood", "RLMNullActor", "RLNashGore_SlashBlood"
  
  PainChance 75
  PainChance "Melee", 160
  
  SeeSound "mechstrosity/sight"
  AttackSound ""
  PainSound "mechstrosity/pain"
  DeathSound "mechstrosity/death"
  ActiveSound "mechstrosity/active"
  
  +QUICKTORETALIATE
  
  Obituary "%o was unable to stop a Mech-strosity in time."
  Tag "Mech-strosity"
    //$category "MP Armageddon"
  
	// Guncaster compatibility
	DropItem "Dosh1", 128
	DropItem "Dosh1", 192
	DropItem "Amber"
  States
  {
  Spawn:
    ADEM AB Random(9,10) A_Look
    Goto Spawn
	
  See:
    TNT1 A 0 A_JumpIfHealthLower (300, "Chase")
    TNT1 A 0 A_PlaySound("mechdemon/walk", 7, 1, 0, 1.25)
    ADEM AA 2 Fast A_Chase ("Melee", "")
    ADEM BB 2 Fast A_Chase ("Melee", "")
    TNT1 A 0 A_PlaySound("mechdemon/walk", 7, 1, 0, 1.25)
    ADEM CC 2 Fast A_Chase ("Melee", "")
    ADEM DD 2 Fast A_Chase ("Melee", "")
    Goto See
  Chase:
    TNT1 A 0 A_SetSpeed(12)
    TNT1 A 0 A_PlaySound("mechdemon/walk", 7, 1, 0, 1.25)
    ADEM AA 1 Fast A_Chase ("Melee", "")
    ADEM BB 1 Fast A_Chase ("Melee", "")
    TNT1 A 0 A_PlaySound("mechdemon/walk", 7, 1, 0, 1.25)
    ADEM CC 1 Fast A_Chase ("Melee", "")
    ADEM DD 1 Fast A_Chase ("Melee", "")
    Goto See
	
  MeleeProper:
    TNT1 A 0 A_PlaySound("mechstrosity/attack", CHAN_VOICE)
    ADEM EF 6 Fast A_FaceTarget
    ADEM G 6 Fast A_CustomMeleeAttack (5 * random(1, 10), "", "", "Melee")
    Goto See
	
  PainMain:
    TNT1 A 0 A_JumpIfHealthLower (300, 1)
    Goto PainMain+2
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    TNT1 A 0 A_JumpIfInTargetInventory ("PowerRLMechstrosityOverwatch", 1, "PainOverwatch")
    ADEM H 3 Fast
    ADEM H 3 Fast A_Pain
    TNT1 A 0 A_JumpIfHealthLower (300, "Chase")
    TNT1 A 0 A_JumpIfCloser (1024, "OverwatchStart")
    Goto See
  Pain.MeleeKick:
  Pain.Melee:
    TNT1 A 0 A_JumpIfHealthLower (300, 1)
    Goto Pain.Melee+2
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    TNT1 A 0 A_JumpIfInTargetInventory ("PowerRLMechstrosityOverwatch", 1, "PainOverwatch")
    ADEM H 2 Fast
    ADEM H 2 Fast A_Pain
    TNT1 A 0 A_JumpIfHealthLower (300, "Chase")
    Goto See
  PainOverwatch:
    ADEM R 4 Fast
    ADEM R 4 Fast A_Pain
    TNT1 A 0 A_JumpIfHealthLower (300, "Chase")
    TNT1 A 0 A_JumpIfCloser (1024, "Overwatch")
    Goto See
	
//Oh look it shoots you have fun (°∀°)
  OverwatchStart:
    TNT1 A 0 A_GiveInventory ("PowerRLMechstrosityOverwatch", 1)
  Overwatch:
    TNT1 A 0 A_JumpIfInventory ("PowerRLMechstrosityOverwatch", 1, 1)
    Goto See
    ADEM O 0 A_Chase ("", "MissileRestartFire", CHF_DONTMOVE)
    ADEM O 1 A_FaceTarget
    ADEM O 0 A_Chase ("", "MissileRestartFire", CHF_DONTMOVE)
    ADEM O 1 A_FaceTarget
    TNT1 A 0 A_JumpIfCloser (1024, "Overwatch")
    ADEM O 0 A_MonsterRefire(0, "See")
    Loop
  MissileRestartFire:
    ADEM O 2 A_FaceTarget
    TNT1 A 0 A_Jump (256, 1,2,3,4)
    ADEM OOOO 2 A_FaceTarget
    Goto RepeatFriendlyCheck
	
  MissileProper:
  RepeatProper:
    TNT1 A 0 A_PlaySound("rlmonsters/chaingun", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/chaingun", CHAN_ITEM, 0.05, 0, 0.20)
    TNT1 A 0 A_JumpIfInventory ("RLMechstrosityStateCounter", 1, "MissileAlt")
    TNT1 A 0 A_GiveInventory ("RLMechstrosityStateCounter", 1)
    ADEM P 3 Bright A_CustomBulletAttack (22.5, 0, 1, random(1,5) * 3, "RLEnemyBulletPuffNoInfight", 0, CBAF_NORANDOM)
    ADEM O 1 A_MonsterRefire(100, "Overwatch")
    TNT1 A 0 A_JumpIfInventory ("PowerRLMechstrosityOverwatch", 1, "RepeatFriendlyCheck")
    Goto See
  MissileAlt:
    TNT1 A 0 A_TakeInventory ("RLMechstrosityStateCounter", 1)
    ADEM Q 3 Bright A_CustomBulletAttack (22.5, 0, 1, random(1,5) * 3, "RLEnemyBulletPuffNoInfight", 0, CBAF_NORANDOM)
    ADEM O 1 A_MonsterRefire(100, "Overwatch")
    TNT1 A 0 A_JumpIfInventory ("PowerRLMechstrosityOverwatch", 1, "RepeatFriendlyCheck")
    Goto See
	
  XDeathMain:
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLArmageddonDemonKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    ADEM I 8
    ADEM J 8 A_Scream
    ADEM K 4
    ADEM L 4 A_NoBlocking
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    ADEM M 4
    ADEM N 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLArmageddonDemonKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    ADEM I 8
    ADEM J 8 A_Scream
    ADEM K 4
    ADEM L 4 A_NoBlocking
    ADEM M 4
    ADEM N 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    ADEM N 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLArmageddonDemonKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    ADEM N 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    ADEM NMLKJI 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    Goto RaiseContinue
  Crush:
    TNT1 A 0 A_GiveInventory ("RLArmageddonDemonKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 1 A_SpawnItem("RLCrushedMedium",0,0,0,0)
    Stop
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  ArsenalMissileCheck:
	"####" "#" 0 A_JumpIf(CallACS("DRLA_specialstarts") == 2, "Duke2LaserAttack")
    "####" "#" 0 A_JumpIfInventory("DRPGShadowAuraToken", 1, "DoorpegShadowAuraMissileAttack") // DRPG Shadow Aura
    "####" "#" 0 A_JumpIfInventory("LDLegendaryMonsterTransformed", 1, "LegendaryMissileAttack") // LegenDoom legendary monster
    "####" "#" 0 A_Jump(256, "MissileProper")
	Goto MissileProper
  ArsenalRepeatCheck:
	"####" "#" 0 A_JumpIf(CallACS("DRLA_specialstarts") == 2, "Duke2LaserAttack")
    "####" "#" 0 A_JumpIfInventory("DRPGShadowAuraToken", 1, "ShadowAuraRepeatAttack") // DRPG Shadow Aura
    "####" "#" 0 A_JumpIfInventory("LDLegendaryMonsterTransformed", 1, "LegendaryRepeatAttack") // LegenDoom legendary monster
    "####" "#" 0 A_Jump(256, "RepeatProper")
	Goto RepeatProper
	
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F2 T 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F2 T 2 Bright
    Goto See
  Pain.CyberDisruptor:
    TNT1 A 0
    Goto Pain.LightningBlue
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLArmageddonDemonKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLArmageddonDemonKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  Duke2LaserAttack:
  Duke2LaserRepeat:
    ADEM P 3 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 0, frandom(-3,3), CMF_OFFSETPITCH, frandom(-3,3))
    ADEM O 1
    ADEM Q 3 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 0, frandom(-3,3), CMF_OFFSETPITCH, frandom(-3,3))
    ADEM O 1
	TNT1 A 0 A_MonsterRefire (40, "See")
    Goto RepeatFriendlyCheck
	
  ShadowAuraMeleeAttack:
    TNT1 A 0 A_PlaySound("mechstrosity/attack", CHAN_VOICE)
    ADEM EF 3 A_FaceTarget
    ADEM G 3 A_CustomMeleeAttack (3 * random(1, 10), "", "", "Melee")
    Goto MissileRestartFire

//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  Pain.SliceMelee:
  Pain.SlashMelee:
  Pain.SlashEnergyMelee:
    "####" "#" 0 A_Jump(256, "Pain.Melee")
    Goto Pain.Melee
	
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MinorManaPod",-1,54)
    ADEM H 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
			//Melee
	Pain.SuperCloseCombat:
	Pain.SuperMidasCloseCombat:
		TNT1 A 0 A_FaceTarget
		TNT1 A 0 A_ChangeVelocity(frandom(-10.0,-12.0),0,frandom(1.0,3.0),CVF_RELATIVE)
		"####" "#" 0 A_Jump(256,"Pain.Melee")
		Goto Pain.Melee
	Pain.SuperShoelaces:
	Pain.SuperMidasShoelaces:
		TNT1 A 0 A_FaceTarget
		TNT1 A 0 A_ChangeVelocity(frandom(-15.0,-20.0),0,frandom(10.0,15.0),CVF_RELATIVE)
		"####" "#" 0 A_Jump(256,"Pain.Melee")
		Goto Pain.Melee
		
	MidasFrame1:
		ADEM H 0 A_SpawnItemEx("Midas_Statue_Demon", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		ADEM H 0 A_SpawnItemEx("Midas_Statue_Demon", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		ADEM H 0 A_SpawnItemEx("Midas_Statue_Demon", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		ADEM H 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		"####" "#" 0 A_JumpIfInTargetInventory ("PowerRLMechstrosityOverwatch", 1, 3)
		ADEM H 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_Jump(256,2)
		ADEM R 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_TakeInventory ("PowerRLMechstrosityOverwatch", 1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		"####" "#" 0 A_JumpIfInTargetInventory ("PowerRLMechstrosityOverwatch", 1, 3)
		ADEM H 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_Jump(256,2)
		ADEM R 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_TakeInventory ("PowerRLMechstrosityOverwatch", 1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

Actor RLMechstrosityStateCounter : Inventory
{
inventory.maxamount 1
}

ACTOR PowerRLMechstrosityOverwatch : Powerup
{
	Powerup.Duration -6
   +INVENTORY.UNTOSSABLE
}

ACTOR RLCCArmageddonDemon : RLArmageddonDemon
{
  +TOUCHY
  States
  {
  Spawn:
    ADEM AB 10
    Loop
  See:
    ADEM AABBCCDD 2
    Loop
  Missile:
    ADEM EF 6
    ADEM G 6
    Goto See
  Melee:
    ADEM H 8
    ADEM Q 3
    ADEM O 1
    ADEM P 3
    ADEM O 1
    ADEM Q 3
    ADEM O 1
    ADEM P 3
    ADEM R 8
    Goto See
  Death:
    ADEM I 8
    ADEM J 8 A_Scream
    ADEM K 4
    ADEM L 4 A_NoBlocking
    ADEM M 4
    ADEM N -1
    Stop
  }
}
