
// FORMER ASSAULT TROOPER
/*
*/
ACTOR RLFormerAssaultTrooper : RLZombiemanBase 16552
{
  Health 50
  GibHealth -40
  
  PainChance 190
  PainThreshold 4
  
  DamageFactor "Bullet", 0.85
  
  SeeSound "eliteformer/sight"
  PainSound "eliteformer/pain"
  DeathSound "eliteformer/death"
  ActiveSound "eliteformer/active"
  
  Obituary "%o was eliminated by a Former Assault Trooper."
  Tag "Former Assault Trooper [Battle Rifle]"
    //$category "MP Armageddon"
  
	DropItem "RLEliteHumanBattleRifleDrop"
	// Guncaster compatibility
	DropItem "Dosh35"
  States
  {
  Spawn:
    AFM1 AB Random(9,10) A_Look
    Loop
	
  See:
    TNT1 A 0 A_JumpIfInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 20, "RetreatReload")
    AFM1 AABBCCDD 3 A_Chase ("", "Missile")
    Loop
  RetreatReload:
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 1)
    AFM1 AA 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    AFM1 BB 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    AFM1 CC 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    AFM1 DD 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    TNT1 A 0
    Goto RetreatReload+1
	
  MissileProper:
    TNT1 A 0 A_JumpIfCloser (220, 7)
    AFM1 EEEEEEEEEE 1 A_FaceTarget (10)
  RepeatProper:
    TNT1 A 0 A_FaceTarget
    TNT1 A 0 A_JumpIfCloser (700, 1)
	Goto MissileSnipe
    TNT1 A 0 A_JumpIfCloser (220, 1)
	Goto MissileBurst
    TNT1 A 0 A_JumpIfInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 20, "RetreatReload")
    TNT1 A 0 A_GiveInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    AFM1 F 3 Bright A_CustomBulletAttack (30, 5, 1, random(1,5) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    AFM1 E 1 A_MonsterRefire(80, "Overwatch")
    Goto RepeatSpecialAttackCheck
  MissileBurst:
    TNT1 A 0 A_JumpIfInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 20, "RetreatReload")
    TNT1 A 0 A_GiveInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    AFM1 F 3 Bright A_CustomBulletAttack (22.5, 2.5, 1, random(1,5) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    AFM1 E 1 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 20, "RetreatReload")
    TNT1 A 0 A_GiveInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    AFM1 F 3 Bright A_CustomBulletAttack (22.5, 2.5, 1, random(1,5) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    AFM1 E 1 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 20, "RetreatReload")
    TNT1 A 0 A_GiveInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    AFM1 F 3 Bright A_CustomBulletAttack (22.5, 2.5, 1, random(1,5) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    AFM1 E 1 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 20, "RetreatReload")
    TNT1 A 0 A_GiveInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    AFM1 F 3 Bright A_CustomBulletAttack (22.5, 2.5, 1, random(1,5) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    AFM1 E 1 A_FaceTarget
    AFM1 EEEEEEEEEE 1 A_FaceTarget (10)
    AFM1 E 1 A_MonsterRefire(0, "Overwatch")
    Goto RepeatSpecialAttackCheck
  MissileSnipe:
    TNT1 A 0 A_Jump (256,1,10,15,20,25)
    AFM1 EEEEEEEEEEEEEEEEEEEEEEEEEEEEEE 1 A_FaceTarget (10)
    TNT1 A 0 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 20, "RetreatReload")
    TNT1 A 0 A_GiveInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    AFM1 F 3 Bright A_CustomBulletAttack (16, 0, 1, random(1,5) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    AFM1 E 1 A_MonsterRefire(0, "Overwatch")
    Goto RepeatSpecialAttackCheck
  Overwatch:
    TNT1 A 0 A_JumpIfInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 20, "Reload")
    TNT1 A 0 A_Chase ("", "Missile", CHF_DONTMOVE)
    AFM1 E 5 A_FaceTarget (10)
    TNT1 A 0 A_Chase ("", "Missile", CHF_DONTMOVE)
    AFM1 E 5 A_FaceTarget (10)
    TNT1 A 0 A_Jump (200, 1)
    Goto Overwatch
    TNT1 A 0
    Goto See
	
  Reload:
    AFM1 EE 4
    TNT1 A 0 A_PlaySound("rlmonsters/pistolreloadout", 7)
    AFM1 EEEEEEEE 4
    AFM1 E 2
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_PlaySound("rlmonsters/pistolreloadin", 7)
    TNT1 A 0 A_TakeInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 20)
    AFM1 EE 5 A_FaceTarget
    AFM1 E 6 A_FaceTarget
    Goto See
	
  PainMain:
    AFM1 G 3
    AFM1 G 3 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLFormerAssaultTrooperKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_GiveToTarget ("RLBerserkerBloodlustBonusCheck", 1)
    AFM1 H 5
    AFM1 I 5 A_Scream
    AFM1 J 5 A_NoBlocking
    AFM1 K 5
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    AFM1 L 5
    AFM1 M 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    AFM1 M 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLFormerAssaultTrooperKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    AFM1 N 5
    AFM1 O 5 A_XScream
    AFM1 P 5 A_NoBlocking
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    AFM1 Q 5
    AFM1 R 5
    AFM1 S 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLFormerAssaultTrooperKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    AFM1 N 5
    AFM1 O 5 A_XScream
    AFM1 P 5 A_NoBlocking
    AFM1 Q 5
    AFM1 R 5
    AFM1 S 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLFormerAssaultTrooperKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    AFM1 M 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, 2)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_TakeInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 20)
    AFM1 L 5
    AFM1 K 5
    AFM1 J 5
    AFM1 I 5
    AFM1 H 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_ChangeFlag ("ALWAYSFAST", 1)
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1) 
    TNT1 A 0 A_ChangeFlag ("SEEINVISIBLE", 1)
    TNT1 A 0 A_ChangeFlag ("MISSILEMORE", 1)
    Goto RaiseContinue
  Crush:
    TNT1 A 0 A_GiveInventory ("RLFormerAssaultTrooperKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 1 A_SpawnItem("RLCrushedSmall",0,0,0,0)
    Stop
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
	
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F2 P 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F2 P 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 800, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLFormerAssaultTrooperKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 800, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLFormerAssaultTrooperKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  Duke2LaserAttack:
    AFM1 E 10 A_FaceTarget
    AFM1 F 3 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-3,3), CMF_OFFSETPITCH, frandom(-3,3))
    AFM1 E 1
    AFM1 F 3 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-3,3), CMF_OFFSETPITCH, frandom(-3,3))
    AFM1 E 1
    AFM1 F 3 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-3,3), CMF_OFFSETPITCH, frandom(-3,3))
    AFM1 E 1
    AFM1 F 3 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-3,3), CMF_OFFSETPITCH, frandom(-3,3))
    AFM1 E 1
    Goto See

  ShadowAuraMissileAttack:
    AFM1 E 15 A_FaceTarget
  ShadowAuraRepeatAttack:
    TNT1 A 0 A_JumpIfInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 20, "RetreatReload")
    TNT1 A 0 A_GiveInventory ("RLFormerAssaultTrooperBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    AFM1 F 3 Bright A_CustomBulletAttack (30, 5, 1, random(1,5) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    AFM1 E 1 A_MonsterRefire(80, "Overwatch")
    Goto RepeatSpecialAttackCheck
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MinorManaPod",-1,54)
    AFM1 G 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		AFM1 G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		AFM1 G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		AFM1 G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		AFM1 G 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		AFM1 G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		AFM1 G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

Actor RLFormerAssaultTrooperBattleRifleShotCounter : Inventory
{
inventory.maxamount 20
}

ACTOR RLCCFormerAssaultTrooper : RLFormerAssaultTrooper
{
  +TOUCHY
  States
  {
  See:
    AFM1 AABBCCDD 3
    Loop
  Missile:
    AFM1 E 10
    AFM1 F 3 Bright
    AFM1 E 1
    Goto Missile+1
  Melee:
    Stop
  Death:
    AFM1 H 5
    AFM1 I 5 A_Scream
    AFM1 J 5 A_NoBlocking
    AFM1 K 5
    AFM1 L 5
    AFM1 M -1
    Stop
  }
}
