
// FORMER OVERWATCH
/*
"Yay, Riker zombies!" - Seryder, 2014
*/
ACTOR RLFormerOverwatch : RLShotgunGuyBase 16553
{
  Health 70
  GibHealth -40
  
  PainChance 190
  PainThreshold 5
  
  DamageFactor "Bullet", 0.85
  
  SeeSound "eliteformer/sight"
  PainSound "eliteformer/pain"
  DeathSound "eliteformer/death"
  ActiveSound "eliteformer/active"
  
  Obituary "%o was blasted to shreds by a Former Overwatch's super shotgun."
  Tag "Former Overwatch [Super Shotgun]"
    //$category "MP Armageddon"
  
	DropItem "RLFormerOverwatchDrop"
	// Guncaster compatibility
	DropItem "Amber"
  States
  {
  Spawn:
    TNT1 A 0 NoDelay A_Jump (220, "NoDrone")
    TNT1 A 0 A_JumpIfInventory ("RLFormerOverwatchDroneControl", 1, "Spawn2")
    TNT1 A 0 A_SpawnItemEx ("RLUACDefenceDrone", -48,random(-32,32),random(12,32), 0,0,0, 0, SXF_SETMASTER)
    TNT1 A 0 A_GiveInventory ("RLFormerOverwatchDroneControl", 1)
  Spawn2:
    AZSG AB Random(9,10) A_Look
    Loop
  NoDrone:
    TNT1 A 0 A_GiveInventory ("RLFormerOverwatchDroneControl", 1)
    Goto Spawn2
	
  See:
    TNT1 A 0 A_JumpIfInventory ("RLFormerOverwatchSuperShotgunShotCounter", 1, "RetreatReload")
    AZSG A 3 A_Chase ("", "Missile")
    TNT1 A 0 A_CheckSight (1)
	Goto See1
    TNT1 A 0 A_JumpIfCloser (300, "Overwatch")
  See1:
    AZSG A 3 A_Chase ("", "Missile")
    TNT1 A 0 A_CheckSight (1)
	Goto See2
    TNT1 A 0 A_JumpIfCloser (300, "Overwatch")
  See2:
    AZSG B 3 A_Chase ("", "Missile")
    TNT1 A 0 A_CheckSight (1)
	Goto See3
    TNT1 A 0 A_JumpIfCloser (300, "Overwatch")
  See3:
    AZSG B 3 A_Chase ("", "Missile")
    TNT1 A 0 A_CheckSight (1)
	Goto See4
    TNT1 A 0 A_JumpIfCloser (300, "Overwatch")
  See4:
    AZSG C 3 A_Chase ("", "Missile")
    TNT1 A 0 A_CheckSight (1)
	Goto See5
    TNT1 A 0 A_JumpIfCloser (300, "Overwatch")
  See5:
    AZSG C 3 A_Chase ("", "Missile")
    TNT1 A 0 A_CheckSight (1)
	Goto See6
    TNT1 A 0 A_JumpIfCloser (300, "Overwatch")
  See6:
    AZSG D 3 A_Chase ("", "Missile")
    TNT1 A 0 A_CheckSight (1)
	Goto See7
    TNT1 A 0 A_JumpIfCloser (300, "Overwatch")
  See7:
    AZSG D 3 A_Chase ("", "Missile")
    TNT1 A 0 A_CheckSight (1)
	Goto See
    TNT1 A 0 A_JumpIfCloser (300, "Overwatch")
	Goto See
  RetreatReload:
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 1)
    AZSG AA 2 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    AZSG BB 2 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    AZSG CC 2 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    AZSG DD 2 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    TNT1 A 0
    Goto RetreatReload+1
	
  Overwatch:
    TNT1 A 0 A_JumpIfInventory ("RLFormerOverwatchSuperShotgunShotCounter", 1, "Reload")
    TNT1 A 0 A_Chase ("", "RepeatSpecialAttackCheck", CHF_DONTMOVE)
    AZSG E 3 A_FaceTarget
    TNT1 A 0 A_JumpIfCloser (300, "Overwatch")
    Goto See
	
  MissileProper:
    AZSG EEE 5 A_FaceTarget
  MissileAmbush:
  RepeatProper:
    AZSG E random(3,10) A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLFormerOverwatchSuperShotgunShotCounter", 1, "RetreatReload")
    TNT1 A 0 A_GiveInventory ("RLFormerOverwatchSuperShotgunShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/supershotgun", CHAN_WEAPON, 1, 0, 0.5)
    TNT1 A 0 A_PlaySound("rlmonsters/supershotgun", CHAN_ITEM, 0.05, 0, 0.20)
    AZSG F 10 Bright A_CustomBulletAttack (40, 10, 10, random(1,5)*3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    AZSG EE 5 A_FaceTarget
    Goto See
	
  Reload:
    AZSG EE 7 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/supershotgunopen", 7)
    AZSG E 21
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_TakeInventory ("RLFormerOverwatchSuperShotgunShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/supershotgunload", 7)
    AZSG E 18
    TNT1 A 0 A_PlaySound("rlmonsters/supershotgunclose", 7)
    AZSG E 5 A_FaceTarget
    Goto See
	
  PainMain:
    AZSG G 3
    AZSG G 3 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_KillChildren
    TNT1 A 0 A_GiveInventory ("RLFormerOverwatchKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    AZSG H 5
    AZSG I 5 A_Scream
    AZSG J 5 A_NoBlocking
    AZSG K 5
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    AZSG L 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    AZSG L 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLFormerOverwatchKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_KillChildren
    AZSG M 5
    AZSG N 5 A_XScream
    AZSG O 5 A_NoBlocking
    AZSG P 5
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    AZSG QRST 5
    AZSG U 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_KillChildren
    TNT1 A 0 A_GiveInventory ("RLFormerOverwatchKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    AZSG M 5
    AZSG N 5 A_XScream
    AZSG O 5 A_NoBlocking
    AZSG P 5
    AZSG QRST 5
    AZSG U 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLFormerOverwatchKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    AZSG L 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, 2)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_TakeInventory ("RLFormerOverwatchSuperShotgunShotCounter", 1)
    AZSG K 5
    AZSG J 5
    AZSG I 5
    AZSG H 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_ChangeFlag ("ALWAYSFAST", 1)
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1) 
    TNT1 A 0 A_ChangeFlag ("SEEINVISIBLE", 1)
    TNT1 A 0 A_ChangeFlag ("MISSILEMORE", 1)
    Goto RaiseContinue
  Crush:
    TNT1 A 0 A_GiveInventory ("RLFormerOverwatchKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 1 A_SpawnItem("RLCrushedSmall",0,0,0,0)
    Stop
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Duke2LaserCheck:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_specialstarts") == 2, "Duke2LaserAttack")
	Goto Missile+2
  Duke2LaserCheck2:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_specialstarts") == 2, "Duke2LaserAttack")
	Goto MissileAmbush+1
	
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F2 Q 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F2 Q 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_KillChildren
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLFormerOverwatchKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_KillChildren
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLFormerOverwatchKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  Duke2LaserAttack:
    AZSG EEE 5 A_FaceTarget
  Duke2LaserRepeat:
    AZSG E random(3,10) A_FaceTarget
    TNT1 A 0 A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-31,-29), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(29,31), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-16,-14), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(14,16), CMF_OFFSETPITCH, frandom(-1,1))
    AZSG F 10 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-1,1), CMF_OFFSETPITCH, frandom(-1,1))
    AZSG E 10
    Goto See
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MinorManaPod",-1,54)
    AZSG G 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		AZSG G 0 A_SpawnItemEx("Midas_Statue_ShotgunGuy", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		AZSG G 0 A_SpawnItemEx("Midas_Statue_ShotgunGuy", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		AZSG G 0 A_SpawnItemEx("Midas_Statue_ShotgunGuy", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		AZSG G 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		AZSG G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		AZSG G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

Actor RLFormerOverwatchSuperShotgunShotCounter : Inventory
{
inventory.maxamount 1
}

Actor RLFormerOverwatchDroneControl : Inventory
{
inventory.maxamount 1
}

ACTOR RLCCFormerOverwatch : RLFormerOverwatch
{
  +TOUCHY
  States
  {
  See:
    AZSG AABBCCDD 3
    Loop
  Missile:
    AZSG E 10
    AZSG F 10 Bright
    AZSG E 24
    AZSG E 21
    AZSG E 18
    AZSG E 5
    Goto See
  Melee:
    Stop
  Death:
    AZSG H 5
    AZSG I 5 A_Scream
    AZSG J 5 A_NoBlocking
    AZSG K 5
    AZSG L -1
    Stop
  }
}

//==============================================================================
//							MONSTER'S ITEM POOL

ACTOR RLFormerOverwatchDrop : RLEnemyWeaponDrop
{
	States
	{
	WeaponDrop: // Drops for DRLA Arsenal + Monsterpack
		TNT1 A 0 A_DropItem("RLSuperShotgunPickup", 1, 20)
		TNT1 AA 0 A_DropItem("RLShell")
		Stop
	WeaponDropNoArsenal: // Drops for Monsterpack
		TNT1 AA 0 A_DropItem("Shell")
		Stop
	WeaponDropVanilla: // Drops for Monsterpack if vanilla drops option is enabled
		TNT1 A 0 A_DropItem("Shotgun")
		Stop
	DonutstealDrop: // Drops for Demonsteele
		TNT1 AA 0 A_DropItem("Shell")
		Stop
	}
}
