
// FORMER SHOCKTROOPER
/*
*/
ACTOR RLFormerShocktrooper : RLChaingunguyBase 16554
{
  Health 100
  GibHealth -40
  Speed 6
  Mass 500
  
  PainChance 220
  PainThreshold 6
  
  DamageFactor "Bullet", 0.75
  DamageFactor "Fire", 0.75
  DamageFactor "Plasma", 0.75
  
  -SHOOTABLE
  -SOLID
  +BLOCKEDBYSOLIDACTORS
  +NOTELEFRAG
  +NOTONAUTOMAP
  +INVISIBLE
  -CANUSEWALLS
  
  SeeSound "shocktrooper/active"
  PainSound "eliteformer/pain"
  DeathSound "eliteformer/death"
  ActiveSound "shocktrooper/active"
  
  Obituary "%o was ambushed by a Former Shocktrooper."
  Tag "Former Shocktrooper [High Power Minigun]"
    //$category "MP Armageddon"
  
	DropItem "RLFormerShocktrooperDrop"
	// Guncaster compatibility
	DropItem "Dosh35", 192
	DropItem "Amber"
  States
  {
  Spawn:
    TNT1 A 0 A_StopSound(CHAN_ITEM)
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_StopSound(6)
    TNT1 A 0 A_JumpIfInventory ("RLFormerShocktrooperTeleported", 1, "Searching")
    TNT1 A 0 A_LookEx (LOF_NOSEESOUND, 0, 0, 0, 360, "TeleportSeek")
    TNT1 A 4 A_Wander
    Loop
  Searching:
    TNT1 A 0 A_ChangeFlag ("SOLID", 1)
    TNT1 A 0 A_ChangeFlag ("SHOOTABLE", 1)
    TNT1 A 0 A_ChangeFlag ("CANUSEWALLS", 1)
    TNT1 A 0 A_ChangeFlag ("BLOCKEDBYSOLIDACTORS", 0)
    TNT1 A 0 A_ChangeFlag ("NOTELEFRAG", 0)
    TNT1 A 0 A_ChangeFlag ("INVISIBLE", 0)
    TNT1 A 0 A_ChangeFlag ("NOTONAUTOMAP", 0)
    TNT1 A 0 A_GiveInventory ("RLFormerShocktrooperTeleported", 1)
    TNT1 A 0 A_StopSound(CHAN_ITEM)
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_StopSound(6)
    TNT1 A 0 A_LookEx (LOF_NOSEESOUND, 0, 0, 0, 0, "See")
    ASHK A 4 A_Wander
    TNT1 A 0 A_LookEx (LOF_NOSEESOUND, 0, 0, 0, 0, "See")
    ASHK A 4 A_Wander
    TNT1 A 0 A_LookEx (LOF_NOSEESOUND, 0, 0, 0, 0, "See")
    ASHK B 4 A_Wander
    TNT1 A 0 A_LookEx (LOF_NOSEESOUND, 0, 0, 0, 0, "See")
    ASHK B 4 A_Wander
    TNT1 A 0 A_LookEx (LOF_NOSEESOUND, 0, 0, 0, 0, "See")
    ASHK C 4 A_Wander
    TNT1 A 0 A_LookEx (LOF_NOSEESOUND, 0, 0, 0, 0, "See")
    ASHK C 4 A_Wander
    TNT1 A 0 A_LookEx (LOF_NOSEESOUND, 0, 0, 0, 0, "See")
    ASHK D 4 A_Wander
    TNT1 A 0 A_LookEx (LOF_NOSEESOUND, 0, 0, 0, 0, "See")
    ASHK D 4 A_Wander
    Loop
	
  TeleportSeek:
    TNT1 A 0 A_StopSound(CHAN_ITEM)
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_StopSound(6)
    TNT1 A 4 A_Chase ("", "", CHF_NOPLAYACTIVE)
    TNT1 A 0 A_Jump (3, "TeleportChanceNormal")
    TNT1 A 0 A_JumpIfInTargetLOS ("TeleportSeek", 110, JLOSF_CLOSENOJUMP | JLOSF_DEADNOJUMP, 2048, 325)
    TNT1 A 0 A_JumpIfCloser (325, "TeleportSeek")
    Goto TeleportChance
  TeleportChance:
    TNT1 A 0 A_Jump (50, "TeleportIn")
    Goto TeleportSeek
  TeleportChanceNormal:
    TNT1 A 0 A_JumpIfCloser (325, "TeleportSeek")
    Goto TeleportIn
  TeleportIn:
    TNT1 A 0 A_SpawnItemEx ("TeleportFog", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_ChangeFlag ("SOLID", 1)
    TNT1 A 0 A_ChangeFlag ("SHOOTABLE", 1)
    TNT1 A 0 A_ChangeFlag ("CANUSEWALLS", 1)
    TNT1 A 0 A_ChangeFlag ("BLOCKEDBYSOLIDACTORS", 0)
    TNT1 A 0 A_ChangeFlag ("NOTELEFRAG", 0)
    TNT1 A 0 A_ChangeFlag ("INVISIBLE", 0)
    TNT1 A 0 A_ChangeFlag ("NOTONAUTOMAP", 0)
    TNT1 A 0 A_GiveInventory ("RLFormerShocktrooperTeleported", 1)
    Goto Missile
  TeleportOut:
    TNT1 A 0 A_StopSound(CHAN_ITEM)
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_StopSound(6)
    TNT1 A 0 A_SpawnItemEx ("TeleportFog", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_ChangeFlag ("SOLID", 0)
    TNT1 A 0 A_ChangeFlag ("SHOOTABLE", 0)
    TNT1 A 0 A_ChangeFlag ("CANUSEWALLS", 0)
    TNT1 A 0 A_ChangeFlag ("BLOCKEDBYSOLIDACTORS", 1)
    TNT1 A 0 A_ChangeFlag ("NOTELEFRAG", 1)
    TNT1 A 0 A_ChangeFlag ("INVISIBLE", 1)
    TNT1 A 0 A_ChangeFlag ("NOTONAUTOMAP", 1)
    TNT1 A 0 A_TakeInventory ("RLFormerShocktrooperTeleported", 1)
    TNT1 A 0 A_TakeInventory ("RLFormerShocktrooperMinigunShotCounter", 130)
    Goto TeleportSeek
	
  See:
    TNT1 A 0 A_ChangeFlag ("SOLID", 1)
    TNT1 A 0 A_ChangeFlag ("SHOOTABLE", 1)
    TNT1 A 0 A_ChangeFlag ("CANUSEWALLS", 1)
    TNT1 A 0 A_ChangeFlag ("BLOCKEDBYSOLIDACTORS", 0)
    TNT1 A 0 A_ChangeFlag ("NOTELEFRAG", 0)
    TNT1 A 0 A_ChangeFlag ("INVISIBLE", 0)
    TNT1 A 0 A_ChangeFlag ("NOTONAUTOMAP", 0)
    TNT1 A 0 A_GiveInventory ("RLFormerShocktrooperTeleported", 1)
    TNT1 A 0 A_StopSound(CHAN_ITEM)
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_StopSound(6)
    TNT1 A 0 A_JumpIfInventory ("RLFormerShocktrooperMinigunShotCounter", 130, "RetreatReload")
    ASHK AABBCCDD 4 A_Chase ("", "Missile")
    Loop
  RetreatReload:
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 1)
    ASHK AA 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, "TeleportOut")
    TNT1 A 0 A_Jump (24, "Reload")
    ASHK BB 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, "TeleportOut")
    TNT1 A 0 A_Jump (24, "Reload")
    ASHK CC 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, "TeleportOut")
    TNT1 A 0 A_Jump (24, "Reload")
    ASHK DD 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, "TeleportOut")
    TNT1 A 0 A_Jump (24, "Reload")
    TNT1 A 0
    Goto RetreatReload+1
	
  Overwatch:
    TNT1 A 0 A_StopSound(CHAN_ITEM)
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_JumpIfInventory ("RLFormerShocktrooperMinigunShotCounter", 130, "RetreatReload")
    TNT1 A 0 A_PlaySound("rlmonsters/sentinelspin", 6, 1, 1, 1.2)
    ASHK X 0 A_Chase ("", "MissileRestartFire", CHF_DONTMOVE | CHF_NOPLAYACTIVE)
    ASHK X 4 A_FaceTarget
    ASHK X 0 A_Chase ("", "MissileRestartFire", CHF_DONTMOVE | CHF_NOPLAYACTIVE)
    ASHK X 4 A_FaceTarget
    TNT1 A 0 A_Jump (240, 2)
    TNT1 A 0 A_PlaySound("shocktrooper/radio", CHAN_VOICE, 1, 0, 1.1)
    Loop
    TNT1 A 0 A_Jump (8, "MissileEnd")
    Loop
  MissileRestartFire:
    ASHK X 4 A_FaceTarget
    TNT1 A 0 A_Jump (256, 1,2,3,4,5,6)
    ASHK XXXXXX 4 A_FaceTarget
    Goto RepeatSpecialAttackCheck
	
  MissileProper:
    ASHK X 8 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/sentinelwindup", 6)
    ASHK XXXXXX 4 A_FaceTarget
  MissileFire:
  RepeatProper:
    TNT1 A 0 A_PlaySound("rlmonsters/sentinelspin", 6, 1, 1, 1.2)
    TNT1 A 0 A_JumpIfInventory ("RLFormerShocktrooperMinigunShotCounter", 130, "MissileEnd")
    TNT1 A 0 A_GiveInventory ("RLFormerShocktrooperMinigunShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/hpminigun", CHAN_WEAPON, 1, 1, 0.6)
    TNT1 A 0 A_PlaySound("rlmonsters/hpminigun", CHAN_ITEM, 0.05, 1, 0.20)
    TNT1 A 0 A_JumpIfInventory ("RLFormerShocktrooperMinigunStateCounter", 1, "MissileAlt")
    TNT1 A 0 A_GiveInventory ("RLFormerShocktrooperMinigunStateCounter", 1)
    ASHK F 1 Bright A_CustomBulletAttack (35, 6, 1, random(1,7) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ASHK X 0 A_MonsterRefire(2, "Overwatch")
    Goto RepeatSpecialAttackCheck
  MissileAlt:
    TNT1 A 0 A_TakeInventory ("RLFormerShocktrooperMinigunStateCounter", 1)
    ASHK E 1 Bright A_CustomBulletAttack (35, 6, 1, random(1,7) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ASHK X 0 A_MonsterRefire(2, "Overwatch")
    Goto RepeatSpecialAttackCheck
  MissileEnd:
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_StopSound(CHAN_ITEM)
    TNT1 A 0 A_PlaySound("rlmonsters/sentinelwinddown", 6)
    ASHK XXXXX 4
    ASHK X 2
    Goto See
	
  Reload:
    TNT1 A 0 A_StopSound(6)
    ASHK XXXXXX 5
    TNT1 A 0 A_PlaySound("rlmonsters/pistolreloadout", 7)
    ASHK XX 5
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_PlaySound("rlmonsters/chaingunload", 7)
    TNT1 A 0 A_TakeInventory ("RLFormerShocktrooperMinigunShotCounter", 130)
    ASHK XXXXXXXX 4
    ASHK X 2
    TNT1 A 0 A_PlaySound("rlmonsters/chaingunwinddown", 7)
    ASHK XXXXX 4
    ASHK X 2 A_FaceTarget
    Goto See
	
  PainMain:
    TNT1 A 0 A_StopSound(6)
    TNT1 A 0 A_StopSound(CHAN_ITEM)
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    ASHK G 3
    ASHK G 3 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLFormerShocktrooperKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_StopSound(6)
    TNT1 A 0 A_StopSound(CHAN_ITEM)
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_JumpIfInventory ("RLFormerShocktrooperTeleported", 1, 1)
	Goto NeverExistedToBeginWith
    ASHK H 4
    ASHK I 4 A_Scream
    ASHK J 4 A_NoBlocking
    ASHK K 4
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    ASHK L 4
    ASHK M 4
    ASHK N 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  NeverExistedToBeginWith:
    TNT1 A 0 A_NoBlocking
    TNT1 A 15
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    TNT1 A 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLFormerShocktrooperKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_JumpIfInventory ("RLFormerShocktrooperTeleported", 1, 1)
	Goto NeverExistedToBeginWith
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_StopSound(6)
    TNT1 A 0 A_StopSound(CHAN_ITEM)
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    ASHK O 3
    ASHK P 3 A_XScream
    ASHK Q 3 A_NoBlocking
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    ASHK RSTUV 3
    ASHK W 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLFormerShocktrooperKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_JumpIfInventory ("RLFormerShocktrooperTeleported", 1, 1)
	Goto NeverExistedToBeginWith
    TNT1 A 0 A_StopSound(6)
    TNT1 A 0 A_StopSound(CHAN_ITEM)
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    ASHK O 3
    ASHK P 3 A_XScream
    ASHK Q 3 A_NoBlocking
    ASHK RSTUV 3
    ASHK W 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLFormerShocktrooperKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_JumpIfInventory ("RLFormerShocktrooperTeleported", 1, 1)
	Goto NeverExistedToBeginWith
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    ASHK M 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, 2)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_TakeInventory ("RLFormerShocktrooperMinigunShotCounter", 130)
    ASHK M 5
    ASHK L 5
    ASHK K 5
    ASHK J 5
    ASHK I 5
    ASHK H 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_ChangeFlag ("ALWAYSFAST", 1)
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1) 
    TNT1 A 0 A_ChangeFlag ("SEEINVISIBLE", 1)
    TNT1 A 0 A_ChangeFlag ("MISSILEMORE", 1)
    Goto RaiseContinue
  Crush:
    TNT1 A 0 A_GiveInventory ("RLFormerShocktrooperKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_StopSound(6)
    TNT1 A 0 A_StopSound(CHAN_ITEM)
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 1 A_SpawnItem("RLCrushedSmall",0,0,0,0)
    Stop
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
	
  Pain.RigelBlast:
    TNT1 A 0 A_StopSound(6)
    TNT1 A 0 A_StopSound(CHAN_ITEM)
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F2 R 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F2 R 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_JumpIfInventory ("RLFormerShocktrooperTeleported", 1, 1)
	Goto NeverExistedToBeginWith
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 2000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLFormerShocktrooperKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_StopSound(6)
    TNT1 A 0 A_StopSound(CHAN_ITEM)
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_JumpIfInventory ("RLFormerShocktrooperTeleported", 1, 1)
	Goto NeverExistedToBeginWith
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 2000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLFormerShocktrooperKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_StopSound(6)
    TNT1 A 0 A_StopSound(CHAN_ITEM)
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  Duke2LaserAttack:
    ASHK X 8 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/sentinelwindup", 6)
    ASHK XXXXXX 4 A_FaceTarget
  Duke2LaserRepeat:
    ASHK FE 1 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 27, 10, frandom(-12,12), CMF_OFFSETPITCH, frandom(-9,9))
    ASHK X 0 A_MonsterRefire(2, "Overwatch")
    Goto RepeatSpecialAttackCheck

//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MinorManaPod",-1,54)
    ASHK G 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		TNT1 A 0 A_JumpIfInventory ("RLFormerShocktrooperTeleported", 1, 1)
		Goto NeverExistedToBeginWith
		ASHK G 0 A_SpawnItemEx("Midas_Statue_ChaingunGuy", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		TNT1 A 0 A_JumpIfInventory ("RLFormerShocktrooperTeleported", 1, 1)
		Goto NeverExistedToBeginWith
		ASHK G 0 A_SpawnItemEx("Midas_Statue_ChaingunGuy", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		TNT1 A 0 A_JumpIfInventory ("RLFormerShocktrooperTeleported", 1, 1)
		Goto NeverExistedToBeginWith
		ASHK G 0 A_SpawnItemEx("Midas_Statue_ChaingunGuy", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		TNT1 A 0 A_JumpIfInventory ("RLFormerShocktrooperTeleported", 1, 1)
		Goto NeverExistedToBeginWith
		ASHK G 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		ASHK G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		ASHK G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

Actor RLFormerShocktrooperMinigunShotCounter : Inventory
{
inventory.maxamount 130
}

Actor RLFormerShocktrooperMinigunStateCounter : Inventory
{
inventory.maxamount 1
}

Actor RLFormerShocktrooperTeleported : Inventory
{
inventory.maxamount 1
}

ACTOR RLCCFormerShocktrooper : RLFormerShocktrooper
{
  SeeSound "shocktrooper/radio"
  +TOUCHY
  States
  {
  Spawn:
    ASHK AB 10
    Loop
  See:
    ASHK XXXXX 4
    Loop
  Missile:
    ASHK E 1 Bright
    ASHK F 1 Bright
    Loop
  Melee:
    Stop
  Death:
    ASHK H 4
    ASHK I 4 A_Scream
    ASHK J 4 A_NoBlocking
    ASHK K 4
    ASHK L 4
    ASHK M 4
    ASHK N -1
    Stop
  }
}

//==============================================================================
//							MONSTER'S ITEM POOL

ACTOR RLFormerShocktrooperDrop : RLEnemyWeaponDrop
{
	States
	{
	WeaponDrop: // Drops for DRLA Arsenal + Monsterpack
		TNT1 A 0 A_DropItem("RLHighPowerMinigunPickup", 1, 4)
		TNT1 A 0 A_DropItem("RLRandomPhaseDeviceSpawner", 1, 10)
		TNT1 A 0 A_DropItem("RLClipBox")
		Stop
	WeaponDropNoArsenal: // Drops for Monsterpack
		TNT1 A 0 A_DropItem("Chaingun")
		TNT1 A 0 A_DropItem("ClipBox")
		Stop
	WeaponDropVanilla: // Drops for Monsterpack if vanilla drops option is enabled
		TNT1 A 0 A_DropItem("Chaingun")
		Stop
	DonutstealDrop: // Drops for Demonsteele
		TNT1 A 0 A_DropItem("ClipBox")
		Stop
	}
}
