
// AGONY ELEMENTAL
//"Ohhhh my god, that thiiiing..." - Kyle873, 2014
ACTOR RLAgonyElemental : RLWildcardBossBase 16511
{
  Health 5000
  GibHealth -1000
  Radius 40
  Height 100
  Speed 4
  Scale 1.5
  Mass 15000
  
  MeleeThreshold 148
  PainChance "Lith_Energy", 0 // Lithium compatibility
  MeleeRange 96
  MinMissileChance 4
  
  RadiusDamageFactor 0.2
  DamageFactor "Melee", 1.5
  DamageFactor "Holy", 2
  DamageFactor "Unholy", 0.25
  
  +QUICKTORETALIATE
  -CANUSEWALLS
  
  SeeSound "agonyelemental/sight"
  ActiveSound "agonyelemental/sight"
  PainSound "agonyelemental/pain"
  DeathSound "agonyelemental/death"
  
  Obituary "%o was unprepared for an Agony Elemental."
  HitObituary "%o was consumed by an Agony Elemental."
  Tag "Agony Elemental"
    //$category "MP Nightmare"
  
	DropItem "RLAgonyElementalDrop"
	// Guncaster compatibility
	DropItem "TreasureChest"
	DropItem "TreasureChest"
  States
  {
  Spawn:
    AGON AAA Random(1,2) A_Look
    Loop
	
  See:
    AGON AAABBB 2 A_Chase
    Loop
	
  MeleeCharge:
    TNT1 A 0 A_FaceTarget
    TNT1 A 0 ThrustThing(angle*256/360, 2, 0, 0)
    AGON A 1 A_Chase ("Melee", "", CHF_DONTMOVE | CHF_NOPLAYACTIVE)
    TNT1 A 0 A_FaceTarget
    AGON A 1 A_Chase ("Melee", "", CHF_DONTMOVE | CHF_NOPLAYACTIVE)
    TNT1 A 0 A_FaceTarget
    AGON A 1 A_Chase ("Melee", "", CHF_DONTMOVE | CHF_NOPLAYACTIVE)
    TNT1 A 0 A_FaceTarget
    AGON A 1 A_Chase ("Melee", "", CHF_DONTMOVE | CHF_NOPLAYACTIVE)
    TNT1 A 0 A_FaceTarget
    AGON A 1 A_Chase ("Melee", "", CHF_DONTMOVE | CHF_NOPLAYACTIVE)
    TNT1 A 0 A_FaceTarget
    AGON A 1 A_Chase ("Melee", "", CHF_DONTMOVE | CHF_NOPLAYACTIVE)
    TNT1 A 0 A_Stop
    Goto See
  Melee:
    TNT1 A 0 ThrustThing(angle*256/360, 2, 0, 0)
    AGON C 3 A_FaceTarget
    TNT1 A 0 ThrustThing(angle*256/360, 2, 0, 0)
    AGON D 3 A_FaceTarget
    TNT1 A 0 ThrustThing(angle*256/360, 2, 0, 0)
    AGON E 3 A_CustomMeleeAttack (10 * random(1, 10), "rlmonsters/bite", "", "Melee")
    TNT1 A 0 A_Stop
    AGON BB 2 A_Chase ("", "")
    Goto See
	
  MissileProper:
    TNT1 A 0 A_Jump (40, "ElementalSpawn")
    AGON CD 5 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory("RLAgonyElementalProjectiles", 1, "CounterAttack")
    TNT1 A 0 A_FaceTarget
    AGON E 1 Bright A_SpawnItemEx ("RLLostSoulAgonySpawner", 80, -30, 24, 0, 0, 0, 0, SXF_SETMASTER | SXF_TRANSFERPOINTERS)
    AGON E 1 Bright A_FaceTarget
    AGON E 1 Bright A_SpawnItemEx ("RLLostSoulAgonySpawner", 80, 30, 24, 0, 0, 0, 0, SXF_SETMASTER | SXF_TRANSFERPOINTERS)
    AGON E 1 Bright A_FaceTarget
    AGON E 1 Bright A_SpawnItemEx ("RLLostSoulAgonySpawner", 80, 0, 24, 0, 0, 0, 0, SXF_SETMASTER | SXF_TRANSFERPOINTERS)
    AGON BB 2 A_Chase ("", "")
    Goto See
	
  ElementalSpawn:
    AGON CD 5 A_FaceTarget
    AGON E 4 Bright A_FaceTarget
    AGON E 1 Bright A_SpawnItemEx ("RLPainElementalAgony", 90, 0, 24, 0, 0, 0, 0, SXF_SETMASTER)
    AGON BB 2 A_Chase ("", "")
    Goto See
	
  CounterAttack:
    TNT1 A 0 ACS_NamedExecuteAlways("DRLA_BossPainCheck", 0)
    AGON F 2
    TNT1 A 0 ThrustThingZ (0, 20, 0, 1)
    AGON F 8 A_Pain
    TNT1 A 0 A_Playsound("agonyelemental/sight", CHAN_VOICE)
    AGON F 8
    AGON CD 2 A_FaceTarget
    TNT1 A 0 A_FaceTarget
    TNT1 A 0 A_Jump (128, "ExplosiveCounterAttack")
  NormalCounterAttack:
    TNT1 A 0 A_Playsound("lordoftheabyss/attack", CHAN_WEAPON, 1, 0, 0.8)
    TNT1 A 0 A_CustomMissile ("RLLostSoulProjectile", 56, -30, frandom(-5,5), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_CustomMissile ("RLLostSoulProjectile", 56, 30, frandom(-5,5), CMF_OFFSETPITCH, frandom(-1,1))
    AGON E 3 Bright A_CustomMissile ("RLLostSoulProjectile", 56, 0, frandom(-5,5), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_Playsound("lordoftheabyss/attack", 7, 1, 0, 0.8)
    TNT1 A 0 A_CustomMissile ("RLLostSoulProjectile", 56, -30, frandom(-5,5), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_CustomMissile ("RLLostSoulProjectile", 56, 30, frandom(-5,5), CMF_OFFSETPITCH, frandom(-1,1))
    AGON E 3 Bright A_CustomMissile ("RLLostSoulProjectile", 56, 0, frandom(-5,5), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_Playsound("lordoftheabyss/attack", 6, 1, 0, 0.8)
    TNT1 A 0 A_CustomMissile ("RLLostSoulProjectile", 56, -30, frandom(-5,5), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_CustomMissile ("RLLostSoulProjectile", 56, 30, frandom(-5,5), CMF_OFFSETPITCH, frandom(-1,1))
    AGON E 3 Bright A_CustomMissile ("RLLostSoulProjectile", 56, 0, frandom(-5,5), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_JumpIfInventory("RLAgonyElementalProjectiles", 1, "NormalCounterAttack")
    Goto See
  ExplosiveCounterAttack:
    TNT1 A 0 A_Playsound("lordoftheabyss/attack", CHAN_WEAPON, 1, 0, 0.8)
    TNT1 A 0 A_CustomMissile ("RLLostSoulProjectile2", 56, -30, frandom(-15,15), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_CustomMissile ("RLLostSoulProjectile2", 56, 30, frandom(-15,15), CMF_OFFSETPITCH, frandom(-1,1))
    AGON E 3 Bright A_CustomMissile ("RLLostSoulProjectile2", 56, 0, frandom(-15,15), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_Playsound("lordoftheabyss/attack", 7, 1, 0, 0.8)
    TNT1 A 0 A_CustomMissile ("RLLostSoulProjectile2", 56, -30, frandom(-15,15), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_CustomMissile ("RLLostSoulProjectile2", 56, 30, frandom(-15,15), CMF_OFFSETPITCH, frandom(-1,1))
    AGON E 3 Bright A_CustomMissile ("RLLostSoulProjectile2", 56, 0, frandom(-15,15), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_Playsound("lordoftheabyss/attack", 6, 1, 0, 0.8)
    TNT1 A 0 A_CustomMissile ("RLLostSoulProjectile2", 56, -30, frandom(-15,15), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_CustomMissile ("RLLostSoulProjectile2", 56, 30, frandom(-15,15), CMF_OFFSETPITCH, frandom(-1,1))
    AGON E 3 Bright A_CustomMissile ("RLLostSoulProjectile2", 56, 0, frandom(-15,15), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_JumpIfInventory("RLAgonyElementalProjectiles", 1, "ExplosiveCounterAttack")
    Goto See
	
  PainMain:
    TNT1 A 0 A_Stop
    TNT1 A 0 ACS_NamedExecuteAlways("DRLA_BossPainCheck", 0)
    AGON F 6
    AGON F 6 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLAgonyElementalKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    AGON F 8
    AGON G 8 A_Scream
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    AGON HI 8 Bright
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_Playsound("rlmonsters/largeexp", 6)
    TNT1 A 0 A_CustomMissile("RLAgonyElementalExplosion",32,0)
    AGON J 8 Bright
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLLostSoulDeathAgonySpawner", random(-30,30), random(-30,30), random(16,56), 0, 0, 0, 0, SXF_SETMASTER | SXF_TRANSFERPOINTERS | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLLostSoulDeathAgonySpawner", random(-30,30), random(-30,30), random(16,56), 0, 0, 0, 0, SXF_SETMASTER | SXF_TRANSFERPOINTERS | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLLostSoulDeathAgonySpawner", random(-30,30), random(-30,30), random(16,56), 0, 0, 0, 0, SXF_SETMASTER | SXF_TRANSFERPOINTERS | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLLostSoulDeathAgonySpawner", random(-30,30), random(-30,30), random(16,56), 0, 0, 0, 0, SXF_SETMASTER | SXF_TRANSFERPOINTERS | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLLostSoulDeathAgonySpawner", random(-30,30), random(-30,30), random(16,56), 0, 0, 0, 0, SXF_SETMASTER | SXF_TRANSFERPOINTERS | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLLostSoulDeathAgonySpawner", random(-30,30), random(-30,30), random(16,56), 0, 0, 0, 0, SXF_SETMASTER | SXF_TRANSFERPOINTERS | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_Playsound("rlmonsters/largeexp", 5)
    AGON K 8 Bright
    TNT1 A 0 A_SpawnItemEx ("RLPainElementalAgony", 90, 0, 24, 0, 0, 0, 0, SXF_SETMASTER | SXF_NOCHECKPOSITION)
    AGON L 8 Bright
    TNT1 A 0 A_SpawnItemEx ("RLPainElementalAgony", -90, 0, 24, 0, 0, 0, 0, SXF_SETMASTER | SXF_NOCHECKPOSITION)
    AGON M 8 Bright A_BossDeath
	TNT1 A 0
    "####" "#" 0 A_Jump(256, "DestroyedEnd")
    Goto DestroyedEnd
  DeathFrame:
    TNT1 A 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DestroyedEnd")
    Goto DestroyedEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLAgonyElementalKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
    Stop
	
  CrushDRLA:
    TNT1 A 30 A_SpawnItemEx("RLCrushedLarge",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 T 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 T 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  XDeath.RigelBlast:
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 10000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLAgonyElementalKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_Stop
    TNT1 A 0 A_PlaySound("weapons/dn2gunbigexplosion", 7, 1, 0, 0.3)
    TNT1 A 0 A_NoBlocking
	TNT1 A 0 A_BossDeath
    TNT1 A 0 A_SetUserVar("user_dn2bossexplosiontimer", 80)
  DN2BossExplosionLoop:
    TNT1 A 0 A_JumpIf (user_dn2bossexplosiontimer <= 0, "DN2BossExplosionFinish")
    TNT1 A 0 A_Jump(190, 2)
    TNT1 A 0 A_RadiusGive ("RLDN2BossFlash", 768, RGF_PLAYERS, 1)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(4, 2, 0, 768, "")
    AGON F 1 Bright
    TNT1 A 0 A_Jump(150, 2)
    TNT1 A 0 A_PlaySound("weapons/dn2gunbigexplosion", 7, 1, 0, 0.3)
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RandomExplosion", frandom(-64,64),frandom(-64,64),frandom(4,90), 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 1
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RandomExplosion", frandom(-64,64),frandom(-64,64),frandom(4,90), 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SetUserVar("user_dn2bossexplosiontimer", user_dn2bossexplosiontimer - 1)
    Goto DN2BossExplosionLoop
  DN2BossExplosionFinish:
    TNT1 A 0 A_RadiusGive ("RLDN2BossFlash2", 1560, RGF_PLAYERS, 1)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(9, 15, 0, 1560, "")
    TNT1 A 0 A_FaceTarget
    TNT1 A 0 A_PlaySound("weapons/dn2gunbigexplosion", 7, 1, 0, 0)
//    TNT1 A 0 A_SpawnItemEx ("RLDuke2BossExplosion", 0,0,48, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2ShockwaveLeft", 0,12,48, 0,14,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2ShockwaveRight", 0,-12,48, 0,-14,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
	Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    AGON F 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		AGON F 0 A_SpawnItemEx("Midas_Statue_Cyberdemon", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		AGON F 0 A_SpawnItemEx("Midas_Statue_Cyberdemon", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		AGON F 0 A_SpawnItemEx("Midas_Statue_Cyberdemon", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		AGON F 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		AGON F 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		AGON F 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
		
		// Overwrite these for monsters that do not leave corpses behind
	//Dreadful
	Death.Tiberium:
		"####" "#" 0 A_Jump(256, "Death")
		Goto Death
	Death.BlueTiberium:
		"####" "#" 0 A_Jump(256, "Death")
		Goto Death
	//Fire and Lightning
	Death.Fire:
		"####" "#" 0 A_Jump(256,"Death")
		Goto Death
  }
}

ACTOR RLLostSoulAgonySpawner : RLLostSoul
{
  -COUNTKILL
  States
  {
  Spawn:
    TNT1 A 0
    TNT1 A 0 A_PainAttack ("RLLostSoulAgony", 0, PAF_AIMFACING)
    TNT1 A 0 A_Die
	Stop
  Death:
    TNT1 A 0
    Stop
  }
}

ACTOR RLLostSoulDeathAgonySpawner : RLLostSoul
{
  -COUNTKILL
  States
  {
  Spawn:
    TNT1 A 0
    TNT1 A 0 A_JumpIfTargetInLOS ("NotInTheFuckingVoid", 0)
	Stop
  NotInTheFuckingVoid:
    TNT1 A 0 A_PainAttack ("RLLostSoulAgony", 0, PAF_AIMFACING)
    TNT1 A 0 A_Die
	Stop
  Death:
    TNT1 A 0
    Stop
  }
}

ACTOR RLLostSoulProjectile : FastProjectile
{
  Radius 12
  Height 12
  Speed 35
  Damage (15)
  DamageType "Plasma"
  Scale 0.75
  +MTHRUSPECIES
  +THRUGHOST
  +NOTIMEFREEZE
  +BLOODSPLATTER
  Decal ""
  SeeSound "skull/melee"
  DeathSound "skull/death"
  RenderStyle SoulTrans
  States
  {
  Spawn:
    AESK AB 2 Bright
    Loop
  Death:
    PEXP AB 3 Bright
    PEXP CD 2 Bright
    PEXP EF 1 Bright
    Stop
  }
}

ACTOR RLLostSoulProjectile2 : RLLostSoulProjectile
{
  Speed 25
  Damage (25)
  DamageType "Fire"
  PainType "Explosion"
  DeathType "Explosion"
  States
  {
  Spawn:
    AESK CD 2 Bright
    Loop
  Death:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 3)
    TNT1 A 0 A_Quake (1, 8, 0, 512, "")
    TNT1 A 0 A_Quake (3, 8, 0, 256, "")
    TNT1 A 0 A_PlaySound ("weapons/rocklx", 7, 1, 0, 0.8)
    TNT1 A 0 A_PlaySound("weapons/rocklx", CHAN_ITEM, 0.05, 0, 0.05)
    TNT1 A 0 A_Explode (64, 96, 0)
    MEXP AB 3 Bright
    MEXP CD 2 Bright
    MEXP EF 1 Bright
    Stop
  }
}

ACTOR RLAgonyElementalExplosion : Rocket
{
   Radius 1
   Height 1
   +THRUGHOST
   -RANDOMIZE
   -DEHEXPLOSION
   -ROCKETTRAIL
   DamageType "Fire"
   PainType "Explosion"
   DeathType "Explosion"
   Speed 0
   Damage 0
   SeeSound ""
   DeathSound ""
   Obituary "$OB_BARREL" // "%o went boom."
  States
  {
  Spawn:
    TNT1 A 0 NoDelay A_Explode (128, 128)
    TNT1 A 8
    Stop
  }
}

ACTOR RLAgonyElementalCounterAttack : CustomInventory
{
  -COUNTITEM
  +INVENTORY.ALWAYSPICKUP
  Inventory.PickupMessage ""
  Inventory.PickupSound ""
  States
  {
  Spawn:
    TNT1 A 1
    Stop
  Pickup:
    TNT1 A 0 
    TNT1 A 0 A_JumpIf(CheckClass("RLAgonyElemental", AAPTR_DEFAULT, TRUE), "TimeForFun")
    Stop
  TimeForFun:
    TNT1 A 0 A_TakeInventory ("RLAgonyElementalProjectiles", 1)
    TNT1 A 0 A_GiveInventory ("RLAgonyElementalProjectiles", 1)
    Stop
  }
}

ACTOR RLAgonyElementalProjectiles : Powerup
{
	Powerup.Duration -1
}

ACTOR RLCCAgonyElemental : RLAgonyElemental
{
  +TOUCHY
  States
  {
  See:
    AGON AABB 3
    Loop
  Melee:
    Goto See
  Missile:
    AGON CD 5
    AGON E 4 Bright
    AGON E 1 Bright
    Goto See
  Death:
    AGON F 8
    AGON G 8
    AGON HI 8 Bright
    AGON J 8 Bright
    AGON K 8 Bright
    AGON L 8 Bright
    AGON M 8 Bright
    Stop
  }
}

//==============================================================================
//							MONSTER'S ITEM POOL

ACTOR RLAgonyElementalDrop : RLEnemyWeaponDrop
{
	States
	{
	WeaponDrop: // Drops for DRLA Arsenal + Monsterpack
		TNT1 AAAAA 0 A_SpawnItemEx("RLRandomSkullSpawner",0,0,0, 0,0,0, 0,SXF_NOCHECKPOSITION, 128)
		Stop
	WeaponDropNoArsenal: // Drops for Monsterpack
		TNT1 A 0
		Stop
	WeaponDropVanilla: // Drops for Monsterpack if vanilla drops option is enabled
		TNT1 A 0
		Stop
	DonutstealDrop: // Drops for Demonsteele
		TNT1 A 0
		Stop
	}
}
