
// ELITE FORMER HUMAN CAPTAIN
//
ACTOR RLEliteCaptainTristarBlaster : RLChaingunguyBase 16520
{
  Health 200
  GibHealth -70
  
  DamageFactor "Plasma", 0.8
  
  SeeSound "eliteformer/sight"
  PainSound "eliteformer/pain"
  DeathSound "eliteformer/death"
  ActiveSound "eliteformer/active"
  
  Obituary "%o was right in the middle of the Elite Captain's killzone."
  Tag "Elite Captain [Tristar Blaster]"
    //$category "MP Nightmare"
  
	DropItem "RLEliteCaptainTristarBlasterDrop"
	// Guncaster compatibility
	DropItem "Dosh25", 192
	DropItem "Ruby"
  States
  {
  Spawn:
    ETRI AB Random(9,10) A_Look
    Loop
	
  See:
    TNT1 A 0 A_JumpIfInventory ("RLEliteCaptainTristarBlasterShotCounter", 3, "RetreatReload")
    ETRI AABBCCDD 3 A_Chase ("", "Missile")
    Loop
  RetreatReload:
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 1)
    ETRI AA 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    ETRI BB 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    ETRI CC 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    ETRI DD 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    TNT1 A 0
    Goto RetreatReload+1
	
  MissileProper:
    ETRI EEEE 5 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLEliteCaptainTristarBlasterShotCounter", 3, "RetreatReload")
    TNT1 A 0 A_GiveInventory ("RLEliteCaptainTristarBlasterShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/tristarblaster", CHAN_WEAPON)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    TNT1 A 0 A_CustomMissile ("RLEliteCaptainTristarBlasterBall", 30, 13, -15)
    TNT1 A 0 A_CustomMissile ("RLEliteCaptainTristarBlasterBall", 30, 13, 15)
    ETRI F 10 Bright A_CustomMissile ("RLEliteCaptainTristarBlasterBall", 30, 13, 0)
    ETRI EEE 5 A_FaceTarget
    Goto See
	
  SummonMissile:
    TNT1 A 0 A_CustomMissile ("RLSummonEliteCaptainTristarBlasterBall", 30, 13, -15)
    TNT1 A 0 A_CustomMissile ("RLSummonEliteCaptainTristarBlasterBall", 30, 13, 15)
    ETRI F 10 Bright A_CustomMissile ("RLSummonEliteCaptainTristarBlasterBall", 30, 13, 0)
    ETRI EEE 5 A_FaceTarget
    Goto See
	
  Reload:
    ETRI EEEEEEEE 3 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/bfg9000unload", 7)
    ETRI E 15
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_TakeInventory ("RLEliteCaptainTristarBlasterShotCounter", 3)
    TNT1 A 0 A_PlaySound("rlmonsters/bfg9000load", 7)
    ETRI EEEEEEEEEE 3 A_FaceTarget
    Goto See
	
  PainMain:
    ETRI G 3
    ETRI G 3 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteCaptainKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    ETRI H 5
    ETRI I 5 A_Scream
    ETRI J 5 A_NoBlocking
    ETRI K 5
    ETRI L 5
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    ETRI M 5
    ETRI N 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    ETRI N 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteCaptainKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    ETRI O 5
    ETRI P 5 A_XScream
    ETRI Q 5 A_NoBlocking
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    ETRI R 5
    ETRI S 5
    ETRI T 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteCaptainKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    ETRI O 5
    ETRI P 5 A_XScream
    ETRI Q 5 A_NoBlocking
    ETRI R 5
    ETRI S 5
    ETRI T 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLEliteCaptainKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    ETRI N 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, 2)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_TakeInventory ("RLEliteCaptainTristarBlasterShotCounter", 3)
    ETRI N 5
    ETRI M 5
    ETRI L 5
    ETRI K 5
    ETRI J 5
    ETRI I 5
    ETRI H 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_ChangeFlag ("ALWAYSFAST", 1)
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1) 
    TNT1 A 0 A_ChangeFlag ("SEEINVISIBLE", 1)
    TNT1 A 0 A_ChangeFlag ("MISSILEMORE", 1)
    Goto RaiseContinue
	
  CrushDRLA:
    TNT1 A 0 A_SpawnItemEx("RLCrushedSmall",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  ArsenalMissileCheck:
    "####" "#" 0 A_JumpIfInventory("DRPGShadowAuraToken", 1, "ShadowAuraMissileAttack") // DRPG Shadow Aura
    "####" "#" 0 A_JumpIfInventory("LDLegendaryMonsterTransformed", 1, "LegendaryMissileAttack") // LegenDoom legendary monster
    "####" "#" 0 A_Jump(256, "MissileProper")
	Goto MissileProper
	
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F2 A 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F2 A 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLEliteCaptainKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLEliteCaptainKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMissileAttack:
    ETRI EEEE 5 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/tristarblaster", CHAN_WEAPON)
    TNT1 A 0 A_CustomMissile ("RLEliteCaptainTristarBlasterBall", 30, 13, -15)
    TNT1 A 0 A_CustomMissile ("RLEliteCaptainTristarBlasterBall", 30, 13, 15)
    ETRI F 6 Bright A_CustomMissile ("RLEliteCaptainTristarBlasterBall", 30, 13, 0)
    ETRI EE 2 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/tristarblaster", CHAN_WEAPON)
    TNT1 A 0 A_CustomMissile ("RLEliteCaptainTristarBlasterBall", 30, 13, -15)
    TNT1 A 0 A_CustomMissile ("RLEliteCaptainTristarBlasterBall", 30, 13, 15)
    ETRI F 6 Bright A_CustomMissile ("RLEliteCaptainTristarBlasterBall", 30, 13, 0)
    ETRI EE 2 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/tristarblaster", CHAN_WEAPON)
    TNT1 A 0 A_CustomMissile ("RLEliteCaptainTristarBlasterBall", 30, 13, -15)
    TNT1 A 0 A_CustomMissile ("RLEliteCaptainTristarBlasterBall", 30, 13, 15)
    ETRI F 6 Bright A_CustomMissile ("RLEliteCaptainTristarBlasterBall", 30, 13, 0)
    ETRI E 18 A_FaceTarget
    Goto See
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MinorManaPod",-1,54)
    ETRI G 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		ETRI G 0 A_SpawnItemEx("Midas_Statue_ChaingunGuy", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		ETRI G 0 A_SpawnItemEx("Midas_Statue_ChaingunGuy", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		ETRI G 0 A_SpawnItemEx("Midas_Statue_ChaingunGuy", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		ETRI G 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		ETRI G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		ETRI G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

ACTOR RLEliteCaptainTristarBlasterBall : PlasmaBall
{
  +NOTIMEFREEZE
  +THRUGHOST
  +BLOODSPLATTER
  Radius 13
  Height 8
  Alpha 0.85
  Scale 0.25
  Speed 20
  Decal "EnemyBlueBFGLightning"
  Damage 8
  Damagetype "Plasma"
  PainType "PlasmaExplosion"
  DeathType "PlasmaExplosion"
  SeeSound ""
  DeathSound ""
  States
  {
  Spawn:
    PULS CDEFED 2 Bright
    Goto Spawn
  Death:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 3)
    TNT1 A 0 A_Quake (1, 8, 0, 512, "")
    TNT1 A 0 A_Quake (5, 8, 0, 256, "")
    TNT1 A 0 A_PlaySound ("rlmonsters/tristarblasterhit", 7, 1, 0, 0.6)
    TNT1 A 0 A_PlaySound("rlmonsters/tristarblasterhit", CHAN_ITEM, 0.05, 0, 0.15)
	TNT1 A 0 A_SetScale(1)
	TNT1 A 0 A_Explode (32,96, 0)
    PEXP AB 4 Bright
    PEXP CD 3 Bright
    PEXP EF 2 Bright
    Stop
  }
}

ACTOR RLSummonEliteCaptainTristarBlasterBall : RLEliteCaptainTristarBlasterBall
{
  +MTHRUSPECIES
}

Actor RLEliteCaptainTristarBlasterShotCounter : Inventory
{
inventory.maxamount 3
}

ACTOR RLDRPGSummonedEliteCaptain2 : RLEliteCaptainTristarBlaster
{
  -COUNTKILL
  +AVOIDMELEE
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCEliteCaptainTristarBlaster : RLEliteCaptainTristarBlaster
{
  +TOUCHY
  States
  {
  See:
    ETRI AABBCCDD 3
    Loop
  Missile:
    ETRI E 20
    ETRI F 10 Bright
    ETRI E 15
    Goto See
  Melee:
    Stop
  Death:
    ETRI H 5
    ETRI I 5 A_Scream
    ETRI J 5 A_NoBlocking
    ETRI K 5
    ETRI L 5
    ETRI M 5
    ETRI N -1
    Stop
  }
}

//==============================================================================
//							MONSTER'S ITEM POOL

ACTOR RLEliteCaptainTristarBlasterDrop : RLEnemyWeaponDrop
{
	States
	{
	WeaponDrop: // Drops for DRLA Arsenal + Monsterpack
		TNT1 A 0 A_DropItem("RLTristarBlasterPickup", 1, 10)
		TNT1 A 0 A_DropItem("RLCellPack")
		Stop
	WeaponDropNoArsenal: // Drops for Monsterpack
		TNT1 A 0 A_DropItem("RLCellPack")
		Stop
	WeaponDropVanilla: // Drops for Monsterpack if vanilla drops option is enabled
		TNT1 A 0 A_DropItem("Chaingun")
		Stop
	DonutstealDrop: // Drops for Demonsteele
		TNT1 A 0 A_DropItem("RLCellPack")
		Stop
	}
}
