
// ELITE FORMER HUMAN COMMANDO
//
ACTOR RLEliteCommandoMinigun : RLChaingunguyBase 16519
{
  Health 150
  GibHealth -50
  
  DamageFactor "Plasma", 0.8
  
  SeeSound "eliteformer/sight"
  PainSound "eliteformer/pain"
  DeathSound "eliteformer/death"
  ActiveSound "eliteformer/active"
  
  Obituary "%o was torn asunder by the hailstorm from an Elite Former Human Commando."
  Tag "Elite Commando [Minigun]"
    //$category "MP Nightmare"
  
	DropItem "RLEliteCommandoMinigunDrop"
	// Guncaster compatibility
	DropItem "Dosh35", 192
	DropItem "Dosh35"
  States
  {
  Spawn:
    TNT1 A 0 A_StopSound(7)
    ECMI AB Random(9,10) A_Look
    Loop
	
  See:
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_JumpIfInventory ("RLEliteCommandoMinigunShotCounter", 200, "RetreatReload")
    ECMI AABBCCDD 4 A_Chase ("", "Missile")
    Loop
  RetreatReload:
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 1)
    ECMI AA 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    ECMI BB 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    ECMI CC 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    ECMI DD 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    TNT1 A 0
    Goto RetreatReload+1
	
  Overwatch:
    TNT1 A 0 A_JumpIfInventory ("RLEliteCommandoMinigunShotCounter", 200, "RetreatReload")
    TNT1 A 0 A_PlaySound("rlmonsters/chaingunspin", 7, 1, 1, 1.2)
    ECMI P 0 A_Chase ("", "MissileRestartFire", CHF_DONTMOVE)
    ECMI P 4 A_FaceTarget
    ECMI P 0 A_Chase ("", "MissileRestartFire", CHF_DONTMOVE)
    ECMI P 4 A_FaceTarget
    TNT1 A 0 A_Jump (8, "MissileEnd")
    Loop
  MissileRestartFire:
    ECMI P 4 A_FaceTarget
    TNT1 A 0 A_Jump (256, 1,2,3,4,5,6)
    ECMI PPPPPP 4 A_FaceTarget
    Goto RepeatSpecialAttackCheck
	
  MissileProper:
    ECMI P 8 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/chaingunwindup", 7)
    ECMI PPPPPP 4 A_FaceTarget
  RepeatProper:
    TNT1 A 0 A_JumpIfInventory ("RLEliteCommandoMinigunShotCounter", 200, "MissileEnd")
    TNT1 A 0 A_GiveInventory ("RLEliteCommandoMinigunShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/minigun", CHAN_WEAPON, 1, 0, 0.5)
    TNT1 A 0 A_PlaySound("rlmonsters/minigun", CHAN_ITEM, 0.05, 0, 0.20)
    TNT1 A 0 A_JumpIfInventory ("RLEliteCommandoMinigunStateCounter", 1, "MissileAlt")
    TNT1 A 0 A_GiveInventory ("RLEliteCommandoMinigunStateCounter", 1)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    ECMI F 1 Bright A_CustomBulletAttack (30, 5, 1, random(1,5) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ECMI P 0 A_MonsterRefire(2, "Overwatch")
    Goto RepeatSpecialAttackCheck
  MissileAlt:
    TNT1 A 0 A_TakeInventory ("RLEliteCommandoMinigunStateCounter", 1)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissileAlt") // Friendly monsters do not harm you
    ECMI E 1 Bright A_CustomBulletAttack (30, 5, 1, random(1,5) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ECMI P 0 A_MonsterRefire(2, "Overwatch")
    Goto RepeatSpecialAttackCheck
  MissileEnd:
    TNT1 A 0 A_PlaySound("rlmonsters/chaingunwinddown", 7)
    ECMI PPPPP 4
    ECMI P 2
    Goto See
	
  SummonMissile:
    ECMI F 1 Bright A_CustomBulletAttack (6, 2, 1, random(1,3) * 5, "RLEnemySummonBulletPuff", 0, CBAF_NORANDOM)
    ECMI P 0 A_MonsterRefire(2, "Overwatch")
    Goto RepeatSpecialAttackCheck
  SummonMissileAlt:
    ECMI E 1 Bright A_CustomBulletAttack (6, 2, 1, random(1,3) * 5, "RLEnemySummonBulletPuff", 0, CBAF_NORANDOM)
    ECMI P 0 A_MonsterRefire(2, "Overwatch")
    Goto RepeatSpecialAttackCheck
	
  Reload:
    ECMI PPPPPP 5 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/pistolreloadout", 7)
    ECMI PP 5 A_FaceTarget
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_PlaySound("rlmonsters/chaingunload", 7)
    TNT1 A 0 A_TakeInventory ("RLEliteCommandoMinigunShotCounter", 200)
    ECMI PPPPPPPP 4 A_FaceTarget
    ECMI P 2 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/chaingunwinddown", 7)
    ECMI PPPPP 4 A_FaceTarget
    ECMI P 2 A_FaceTarget
    Goto See
	
  PainMain:
    TNT1 A 0 A_StopSound(7)
    ECMI G 3
    ECMI G 3 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteCommandoKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_StopSound(7)
    ECMI H 4
    ECMI I 4 A_Scream
    ECMI J 4 A_NoBlocking
    ECMI K 4
    ECMI L 4
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    ECMI M 4
    ECMI N 4
    ECMI O 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    ECMI O 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteCommandoKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_StopSound(7)
    ECMI Q 5
    ECMI R 5 A_XScream
    ECMI S 5 A_NoBlocking
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    ECMI T 5
    ECMI U 5
    ECMI V 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteCommandoKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_StopSound(7)
    ECMI Q 5
    ECMI R 5 A_XScream
    ECMI S 5 A_NoBlocking
    ECMI T 5
    ECMI U 5
    ECMI V 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLEliteCommandoKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    ECMI N 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, 2)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_TakeInventory ("RLEliteCommandoMinigunShotCounter", 200)
    ECMI M 5
    ECMI L 5
    ECMI K 5
    ECMI J 5
    ECMI I 5
    ECMI H 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_ChangeFlag ("ALWAYSFAST", 1)
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1) 
    TNT1 A 0 A_ChangeFlag ("SEEINVISIBLE", 1)
    TNT1 A 0 A_ChangeFlag ("MISSILEMORE", 1)
    Goto RaiseContinue
	
  CrushDRLA:
    TNT1 A 0 A_SpawnItemEx("RLCrushedSmall",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
	
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 Z 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 Z 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLEliteCommandoKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLEliteCommandoKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  Duke2LaserAttack:
    ECMI P 10 A_FaceTarget
  Duke2LaserRepeat:
    ECMI FE 1 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-12,12), CMF_OFFSETPITCH, frandom(-5,5))
	TNT1 A 0 A_MonsterRefire (100, "See")
    Goto RepeatSpecialAttackCheck
	
  ShadowAuraMissileAttack:
    ECMI P 8 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/chaingunwindup", 7)
    ECMI PPPPPP 4 A_FaceTarget
  ShadowAuraRepeatAttack:
    TNT1 A 0 A_PlaySound("rlmonsters/minigun", CHAN_WEAPON, 1, 0, 0.5)
    TNT1 A 0 A_PlaySound("rlmonsters/minigun", CHAN_ITEM, 0.05, 0, 0.20)
    TNT1 A 0 A_JumpIfInventory ("RLEliteCommandoMinigunStateCounter", 1, "DoorpegShadowAuraAttackAlt")
    TNT1 A 0 A_GiveInventory ("RLEliteCommandoMinigunStateCounter", 1)
    ECMI F 1 Bright A_CustomBulletAttack (30, 5, 1, random(1,5) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ECMI P 0 A_MonsterRefire(250, "MissileEnd")
    Goto RepeatSpecialAttackCheck
  DoorpegShadowAuraAttackAlt:
    TNT1 A 0 A_TakeInventory ("RLEliteCommandoMinigunStateCounter", 1)
    ECMI E 1 Bright A_CustomBulletAttack (30, 5, 1, random(1,5) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ECMI P 0 A_MonsterRefire(250, "MissileEnd")
    Goto RepeatSpecialAttackCheck
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MinorManaPod",-1,54)
    ECMI G 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		ECMI G 0 A_SpawnItemEx("Midas_Statue_ChaingunGuy", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		ECMI G 0 A_SpawnItemEx("Midas_Statue_ChaingunGuy", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		ECMI G 0 A_SpawnItemEx("Midas_Statue_ChaingunGuy", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		ECMI G 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		ECMI G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		ECMI G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

Actor RLEliteCommandoMinigunShotCounter : Inventory
{
inventory.maxamount 200
}

Actor RLEliteCommandoMinigunStateCounter : Inventory
{
inventory.maxamount 1
}

ACTOR RLDRPGSummonedEliteCommando : RLEliteCommandoMinigun
{
  -COUNTKILL
  +AVOIDMELEE
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCEliteCommandoMinigun : RLEliteCommandoMinigun
{
  +TOUCHY
  States
  {
  Spawn:
    ECMI AB 10
    Loop
  See:
    ECMI ABCD 8
    Loop
  Missile:
    ECMI P 1
    ECMI FE 1 Bright
    Loop
  Melee:
    Stop
  Death:
    ECMI H 4
    ECMI I 4 A_Scream
    ECMI J 4 A_NoBlocking
    ECMI K 4
    ECMI L 4
    ECMI M 4
    ECMI N 4
    ECMI O -1
    Stop
  }
}

//==============================================================================
//							MONSTER'S ITEM POOL

ACTOR RLEliteCommandoMinigunDrop : RLEnemyWeaponDrop
{
	States
	{
	WeaponDrop: // Drops for DRLA Arsenal + Monsterpack
		TNT1 A 0 A_DropItem("RLMinigunPickup", 1, 10)
		TNT1 A 0 A_DropItem("RLClipBox")
		Stop
	WeaponDropNoArsenal: // Drops for Monsterpack
		TNT1 A 0 A_DropItem("Chaingun")
		Stop
	WeaponDropVanilla: // Drops for Monsterpack if vanilla drops option is enabled
		TNT1 A 0 A_DropItem("Chaingun")
		Stop
	DonutstealDrop: // Drops for Demonsteele
		TNT1 A 0 A_DropItem("ClipBox")
		Stop
	}
}
