
// ELITE FORMER HUMAN
//
ACTOR RLEliteHumanBattleRifle : RLZombiemanBase
{
  Health 40
  GibHealth -40
  
  DamageFactor "Bullet", 0.85
  
  SeeSound "eliteformer/sight"
  PainSound "eliteformer/pain"
  DeathSound "eliteformer/death"
  ActiveSound "eliteformer/active"
  
  Obituary "%o was eliminated by an Elite Former Human."
  Tag "Former Elite [Burst-fire Rifle]"
    //$category "MP Nightmare"
  
	DropItem "RLEliteHumanBattleRifleDrop"
	// Guncaster compatibility
	DropItem "Dosh1"
	DropItem "Dosh1"
	DropItem "Dosh1"
	DropItem "Dosh1", 192
	DropItem "Dosh1", 192
	DropItem "Dosh5", 128
	DropItem "Dosh10"
  States
  {
  Spawn:
    ERFL AB Random(9,10) A_Look
    Loop
	
  See:
    TNT1 A 0 A_JumpIfInventory ("RLEliteHumanBattleRifleShotCounter", 40, "RetreatReload")
    ERFL AABBCCDD 3 A_Chase ("", "Missile")
    Loop
  RetreatReload:
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 1)
    ERFL AA 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (32, "Reload")
    ERFL BB 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (32, "Reload")
    ERFL CC 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (32, "Reload")
    ERFL DD 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (32, "Reload")
    TNT1 A 0
    Goto RetreatReload+1
	
  MissileProper:
    ERFL E 12 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLEliteHumanBattleRifleShotCounter", 40, "RetreatReload")
    TNT1 A 0 A_GiveInventory ("RLEliteHumanBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/burstbattlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/burstbattlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    ERFL F 1 Bright A_CustomBulletAttack (16, 0, 1, random(1,5) * 4, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ERFL E 1 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLEliteHumanBattleRifleShotCounter", 40, "MissileEnd")
    TNT1 A 0 A_GiveInventory ("RLEliteHumanBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/burstbattlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/burstbattlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    ERFL F 1 Bright A_CustomBulletAttack (16, 0, 1, random(1,5) * 4, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ERFL E 1 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLEliteHumanBattleRifleShotCounter", 40, "MissileEnd")
    TNT1 A 0 A_GiveInventory ("RLEliteHumanBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/burstbattlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/burstbattlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    ERFL F 1 Bright A_CustomBulletAttack (16, 0, 1, random(1,5) * 4, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ERFL E 1 A_FaceTarget
	Goto MissileEnd
  MissileEnd:
    ERFL E 8 A_FaceTarget
    Goto See
	
  SummonMissile:
    ERFL F 1 Bright A_CustomBulletAttack (3, 1.5, 1, random(1,3) * 10, "RLEnemySummonBulletPuff", 0, CBAF_NORANDOM)
    ERFL E 1 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLEliteHumanBattleRifleShotCounter", 40, "MissileEnd")
    TNT1 A 0 A_GiveInventory ("RLEliteHumanBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/burstbattlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/burstbattlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    ERFL F 1 Bright A_CustomBulletAttack (3, 1.5, 1, random(1,3) * 10, "RLEnemySummonBulletPuff", 0, CBAF_NORANDOM)
    ERFL E 1 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLEliteHumanBattleRifleShotCounter", 40, "MissileEnd")
    TNT1 A 0 A_GiveInventory ("RLEliteHumanBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/burstbattlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/burstbattlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    ERFL F 1 Bright A_CustomBulletAttack (3, 1.5, 1, random(1,3) * 10, "RLEnemySummonBulletPuff", 0, CBAF_NORANDOM)
    ERFL E 1 A_FaceTarget
	Goto MissileEnd
	
  Reload:
    ERFL EE 4 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifleunload", 7)
    ERFL EEEEEEEE 4 A_FaceTarget
    ERFL E 2 A_FaceTarget
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifleload", 7)
    TNT1 A 0 A_TakeInventory ("RLEliteHumanBattleRifleShotCounter", 40)
    ERFL EE 5 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/battleriflecock", 5)
    ERFL E 6 A_FaceTarget
    Goto See
	
  PainMain:
    ERFL G 3
    ERFL G 3 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    ERFL H 5
    ERFL I 5 A_Scream
    ERFL J 5 A_NoBlocking
    ERFL K 5
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    ERFL L 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    ERFL L 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    ERFL M 5
    ERFL N 5 A_XScream
    ERFL O 5 A_NoBlocking
    ERFL PQ 5
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    ERFL RST 5
    ERFL U 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    ERFL M 5
    ERFL N 5 A_XScream
    ERFL O 5 A_NoBlocking
    ERFL PQ 5
    ERFL RST 5
    ERFL U 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    ERFL L 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, 2)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_TakeInventory ("RLEliteHumanBattleRifleShotCounter", 40)
    ERFL K 5
    ERFL J 5
    ERFL I 5
    ERFL H 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_ChangeFlag ("ALWAYSFAST", 1)
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1) 
    TNT1 A 0 A_ChangeFlag ("SEEINVISIBLE", 1)
    TNT1 A 0 A_ChangeFlag ("MISSILEMORE", 1)
    Goto RaiseContinue
	
  CrushDRLA:
    TNT1 A 0 A_SpawnItemEx("RLCrushedSmall",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
	
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 B 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 B 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  Duke2LaserAttack:
    ERFL E 12 A_FaceTarget
    ERFL F 1 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-3,3), CMF_OFFSETPITCH, frandom(-3,3))
    ERFL E 1
    ERFL F 1 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-3,3), CMF_OFFSETPITCH, frandom(-3,3))
    ERFL E 1
    ERFL F 1 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-3,3), CMF_OFFSETPITCH, frandom(-3,3))
    ERFL E 9
    Goto See
	
  ShadowAuraMissileAttack:
    ERFL E 15 A_FaceTarget
  ShadowAuraRepeatAttack:
    TNT1 A 0 A_JumpIfInventory ("RLEliteHumanBattleRifleShotCounter", 40, "RetreatReload")
    TNT1 A 0 A_GiveInventory ("RLEliteHumanBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/scopedrifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/scopedrifle", CHAN_ITEM, 0.05, 0, 0.20)
    ERFL F 4 Bright A_CustomBulletAttack (16, 0, 1, random(1,5) * 4, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ERFL EEEE 4 A_FaceTarget
    TNT1 A 0 A_MonsterRefire (0, "MissileEnd")
	Goto RepeatSpecialAttackCheck
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MinorManaPod",-1,54)
    ERFL G 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		ERFL G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		ERFL G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		ERFL G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		ERFL G 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		ERFL G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		ERFL G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

Actor RLEliteHumanBattleRifleShotCounter : Inventory
{
inventory.maxamount 40
}

ACTOR RLDRPGSummonedEliteHuman : RLEliteHumanBattleRifle
{
  -COUNTKILL
  +AVOIDMELEE
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCEliteHumanBattleRifle : RLEliteHumanBattleRifle
{
  +TOUCHY
  States
  {
  See:
    ERFL AABBCCDD 4
    Loop
  Missile:
    ERFL E 5
    ERFL F 1 Bright
    ERFL E 1
    ERFL F 1 Bright
    ERFL E 1
    ERFL F 1 Bright
    ERFL E 9
    Goto See
  Melee:
    Stop
  Death:
    ERFL H 5
    ERFL I 5 A_Scream
    ERFL J 5 A_NoBlocking
    ERFL K 5
    ERFL L -1
    Stop
  }
}

//==============================================================================
//							MONSTER'S ITEM POOL

ACTOR RLEliteHumanBattleRifleDrop : RLEnemyWeaponDrop
{
	States
	{
	WeaponDrop: // Drops for DRLA Arsenal + Monsterpack
		TNT1 A 0 A_DropItem("RLBattleRiflePickup")
		TNT1 A 0 A_DropItem("RLClip")
		Stop
	WeaponDropNoArsenal: // Drops for Monsterpack
		TNT1 A 0 A_DropItem("Clip")
		Stop
	WeaponDropVanilla: // Drops for Monsterpack if vanilla drops option is enabled
		TNT1 A 0 A_DropItem("Clip")
		Stop
	DonutstealDrop: // Drops for Demonsteele
		TNT1 A 0 A_DropItem("Clip")
		Stop
	}
}
