
// ELITE FORMER HUMAN
//
ACTOR RLEliteHumanBattleRifle2 : RLZombiemanBase
{
  Health 40
  GibHealth -40
  
  DamageFactor "Bullet", 0.85
  
  SeeSound "femalezombie/sight"
  PainSound "femalezombie/pain"
  DeathSound "femalezombie/death"
  ActiveSound "femalezombie/active"
  
  Obituary "%o was eliminated by an Elite Former Human."
  Tag "Former Elite [Burst-fire Rifle]"
    //$category "MP Nightmare"
  
	DropItem "RLEliteHumanBattleRifleDrop"
	// Guncaster compatibility
	DropItem "Dosh1"
	DropItem "Dosh1"
	DropItem "Dosh1"
	DropItem "Dosh1", 192
	DropItem "Dosh1", 192
	DropItem "Dosh5", 128
	DropItem "Dosh10"
  States
  {
  Spawn:
    ERF2 AB Random(9,10) A_Look
    Loop
	
  See:
    TNT1 A 0 A_JumpIfInventory ("RLEliteHumanBattleRifleShotCounter", 40, "RetreatReload")
    ERF2 AABBCCDD 3 A_Chase ("", "Missile")
    Loop
  RetreatReload:
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 1)
    ERF2 AA 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (32, "Reload")
    ERF2 BB 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (32, "Reload")
    ERF2 CC 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (32, "Reload")
    ERF2 DD 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (32, "Reload")
    TNT1 A 0
    Goto RetreatReload+1
	
  MissileProper:
    ERF2 E 12 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLEliteHumanBattleRifleShotCounter", 40, "RetreatReload")
    TNT1 A 0 A_GiveInventory ("RLEliteHumanBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/burstbattlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/burstbattlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    ERF2 F 1 Bright A_CustomBulletAttack (16, 0, 1, random(1,5) * 4, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ERF2 E 1 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLEliteHumanBattleRifleShotCounter", 40, "MissileEnd")
    TNT1 A 0 A_GiveInventory ("RLEliteHumanBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/burstbattlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/burstbattlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    ERF2 F 1 Bright A_CustomBulletAttack (16, 0, 1, random(1,5) * 4, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ERF2 E 1 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLEliteHumanBattleRifleShotCounter", 40, "MissileEnd")
    TNT1 A 0 A_GiveInventory ("RLEliteHumanBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/burstbattlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/burstbattlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    ERF2 F 1 Bright A_CustomBulletAttack (16, 0, 1, random(1,5) * 4, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ERF2 E 1 A_FaceTarget
  MissileEnd:
    ERF2 E 8 A_FaceTarget
    Goto See
	
  Reload:
    ERF2 EE 4 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifleunload", 7)
    ERF2 EEEEEEEE 4 A_FaceTarget
    ERF2 E 2 A_FaceTarget
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifleload", 7)
    TNT1 A 0 A_TakeInventory ("RLEliteHumanBattleRifleShotCounter", 40)
    ERF2 EE 5 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/battleriflecock", 5)
    ERF2 E 6 A_FaceTarget
    Goto See
	
  PainMain:
    ERF2 G 3
    ERF2 G 3 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    ERF2 H 5
    ERF2 I 5 A_Scream
    ERF2 J 5 A_NoBlocking
    ERF2 K 5
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    ERF2 LM 5
    ERF2 N 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    ERF2 N 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    ERF2 O 5
    ERF2 P 5 A_XScream
    ERF2 Q 5 A_NoBlocking
    ERF2 RS 5
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    ERF2 TUV 5
    ERF2 W 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    ERF2 O 5
    ERF2 P 5 A_XScream
    ERF2 Q 5 A_NoBlocking
    ERF2 RS 5
    ERF2 TUV 5
    ERF2 W 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    ERF2 N 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, 2)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_TakeInventory ("RLEliteHumanBattleRifleShotCounter", 40)
    ERF2 M 5
    ERF2 L 5
    ERF2 K 5
    ERF2 J 5
    ERF2 I 5
    ERF2 H 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_ChangeFlag ("ALWAYSFAST", 1)
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1) 
    TNT1 A 0 A_ChangeFlag ("SEEINVISIBLE", 1)
    TNT1 A 0 A_ChangeFlag ("MISSILEMORE", 1)
    Goto RaiseContinue
	
  CrushDRLA:
    TNT1 A 0 A_SpawnItemEx("RLCrushedSmall",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
	
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 C 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 C 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  Duke2LaserAttack:
    ERF2 E 12 A_FaceTarget
    ERF2 F 1 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-3,3), CMF_OFFSETPITCH, frandom(-3,3))
    ERF2 E 1
    ERF2 F 1 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-3,3), CMF_OFFSETPITCH, frandom(-3,3))
    ERF2 E 1
    ERF2 F 1 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-3,3), CMF_OFFSETPITCH, frandom(-3,3))
    ERF2 E 9
    Goto See
	
  ShadowAuraMissileAttack:
    ERF2 E 15 A_FaceTarget
  ShadowAuraRepeatAttack:
    TNT1 A 0 A_JumpIfInventory ("RLEliteHumanBattleRifleShotCounter", 40, "RetreatReload")
    TNT1 A 0 A_GiveInventory ("RLEliteHumanBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/scopedrifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/scopedrifle", CHAN_ITEM, 0.05, 0, 0.20)
    ERF2 F 4 Bright A_CustomBulletAttack (16, 0, 1, random(1,5) * 12, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ERF2 EEEE 4 A_FaceTarget
    TNT1 A 0 A_MonsterRefire (0, "MissileEnd")
	Goto RepeatSpecialAttackCheck
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MinorManaPod",-1,54)
    ERF2 G 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		ERF2 G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		ERF2 G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		ERF2 G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		ERF2 G 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		ERF2 G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		ERF2 G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}
