
// ELITE FORMER HUMAN
//
ACTOR RLEliteHumanCombatPistol : RLZombiemanBase 16512
{
  Health 40
  GibHealth -40
  
  DamageFactor "Bullet", 0.85
  
  SeeSound "eliteformer/sight"
  PainSound "eliteformer/pain"
  DeathSound "eliteformer/death"
  ActiveSound "eliteformer/active"
  
  Obituary "%o was dealt with by an Elite Former Human."
  Tag "Former Elite [CombatPistol]"
    //$category "MP Nightmare"
  
	DropItem "RLEliteHumanCombatPistolDrop"
	// Guncaster compatibility
	DropItem "Dosh1"
	DropItem "Dosh1"
	DropItem "Dosh1"
	DropItem "Dosh1", 192
	DropItem "Dosh1", 192
	DropItem "Dosh5", 128
  States
  {
  Spawn:
    ZHPI AB Random(9,10) A_Look
    Loop
	
  See:
    TNT1 A 0 A_JumpIfInventory ("RLEliteHumanCombatPistolShotCounter", 15, "RetreatReload")
    ZHPI AABBCCDD 3 A_Chase ("", "Missile")
    Loop
  RetreatReload:
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 1)
    ZHPI AA 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (32, "Reload")
    ZHPI BB 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (32, "Reload")
    ZHPI CC 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (32, "Reload")
    ZHPI DD 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (32, "Reload")
    TNT1 A 0
    Goto RetreatReload+1
	
  MissileProper:
    ZHPI E 5 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLEliteHumanCombatPistolShotCounter", 15, "RetreatReload")
    TNT1 A 0 A_GiveInventory ("RLEliteHumanCombatPistolShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/combatpistol", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/combatpistol", CHAN_ITEM, 0.05, 0, 0.20)
    ZHPI F 6 Bright A_CustomBulletAttack (22.5, 0, 1, random(1,5) * 5, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ZHPI E 4 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLEliteHumanCombatPistolShotCounter", 15, "MissileEnd")
    TNT1 A 0 A_GiveInventory ("RLEliteHumanCombatPistolShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/combatpistol", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/combatpistol", CHAN_ITEM, 0.05, 0, 0.20)
    ZHPI F 6 Bright A_CustomBulletAttack (22.5, 0, 1, random(1,5) * 5, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ZHPI E 4 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLEliteHumanCombatPistolShotCounter", 15, "MissileEnd")
    TNT1 A 0 A_GiveInventory ("RLEliteHumanCombatPistolShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/combatpistol", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/combatpistol", CHAN_ITEM, 0.05, 0, 0.20)
    ZHPI F 6 Bright A_CustomBulletAttack (22.5, 0, 1, random(1,5) * 5, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ZHPI E 4 A_FaceTarget
  MissileEnd:
    ZHPI E 7 A_FaceTarget
    Goto See
	
  Reload:
    TNT1 A 0 A_PlaySound("rlmonsters/pistolreloadout", 7)
    ZHPI EEEEE 3 A_FaceTarget
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_PlaySound("rlmonsters/pistolreloadin", 7)
    TNT1 A 0 A_TakeInventory ("RLEliteHumanCombatPistolShotCounter", 15)
    ZHPI E 3 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/pistolcock", 7)
    ZHPI EEE 4 A_FaceTarget
    Goto See
	
  PainMain:
    ZHPI G 3
    ZHPI G 3 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    ZHPI H 5
    ZHRF I 5 A_Scream
    ZHRF J 5 A_NoBlocking
    ZHRF K 5
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    ZHRF L 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    ZHRF L 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    ZHPI M 5
    ZHRF N 5 A_XScream
    ZHRF O 5 A_NoBlocking
    ZHRF PQ 5
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    ZHRF RST 5
    ZHRF U 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    ZHPI M 5
    ZHRF N 5 A_XScream
    ZHRF O 5 A_NoBlocking
    ZHRF PQ 5
    ZHRF RST 5
    ZHRF U 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    ZHRF L 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, 2)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_TakeInventory ("RLEliteHumanCombatPistolShotCounter", 15)
    ZHRF K 5
    ZHRF J 5
    ZHRF I 5
    ZHPI H 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_ChangeFlag ("ALWAYSFAST", 1)
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1) 
    TNT1 A 0 A_ChangeFlag ("SEEINVISIBLE", 1)
    TNT1 A 0 A_ChangeFlag ("MISSILEMORE", 1)
    Goto RaiseContinue
	
  CrushDRLA:
    TNT1 A 0 A_SpawnItemEx("RLCrushedSmall",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
	
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 A 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 A 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLNeuralStunStars", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION | SXF_SETMASTER)
    TNT1 A 0 A_Stop
    TNT1 A 0 ThrustThingZ (0, 20, 0, 0)
    CKD1 A -1
    Stop
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLEliteHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  Duke2LaserAttack:
    ZHPI E 10 A_FaceTarget
    ZHPI F 4 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 42, 2, frandom(-3,3), CMF_OFFSETPITCH, frandom(-3,3))
    ZHPI E 12
    Goto See
	
  ShadowAuraMissileAttack:
    ZHPI E 15 A_FaceTarget
  ShadowAuraRepeatAttack:
    TNT1 A 0 A_JumpIfInventory ("RLEliteHumanCombatPistolShotCounter", 22, "MissileEnd")
    TNT1 A 0 A_GiveInventory ("RLEliteHumanCombatPistolShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/stormpistol", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/stormpistol", CHAN_ITEM, 0.05, 0, 0.20)
    ZHPI F 6 Bright A_CustomBulletAttack (16.5, 0, 2, random(1,5) * 5, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ZHPI E 4 A_FaceTarget
    ZHPI E 7 A_MonsterRefire (0, "See")
    Goto RepeatSpecialAttackCheck
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MinorManaPod",-1,54)
    ZHPI G 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		ZHPI G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		ZHPI G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		ZHPI G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		ZHPI G 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		ZHPI G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		ZHPI G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

Actor RLEliteHumanCombatPistolShotCounter : Inventory
{
inventory.maxamount 22
}

ACTOR RLCCEliteHumanCombatPistol : RLEliteHumanCombatPistol
{
  +TOUCHY
  States
  {
  See:
    ZHPI AABBCCDD 4
    Loop
  Missile:
    ZHPI E 5
    ZHPI F 6 Bright
    ZHPI E 4
    ZHPI F 6 Bright
    ZHPI E 4
    ZHPI F 6 Bright
    ZHPI E 9
    Goto See
  Melee:
    Stop
  Death:
    ZHPI H 5
    ZHRF I 5 A_Scream
    ZHRF J 5 A_NoBlocking
    ZHRF K 5
    ZHRF L -1
    Stop
  }
}

//==============================================================================
//							MONSTER'S ITEM POOL

ACTOR RLEliteHumanCombatPistolDrop : RLEnemyWeaponDrop
{
	States
	{
	WeaponDrop: // Drops for DRLA Arsenal + Monsterpack
		TNT1 A 0 A_DropItem("RLCombatPistolPickup", 1, 30)
		TNT1 A 0 A_DropItem("RLClip")
		Stop
	WeaponDropNoArsenal: // Drops for Monsterpack
		TNT1 A 0 A_DropItem("Clip")
		Stop
	WeaponDropVanilla: // Drops for Monsterpack if vanilla drops option is enabled
		TNT1 A 0 A_DropItem("Clip")
		Stop
	DonutstealDrop: // Drops for Demonsteele
		TNT1 A 0 A_DropItem("Clip")
		Stop
	}
}
