
// ELITE FORMER HUMAN SERGEANT
//
ACTOR RLEliteSergeantAssaultShotgun : RLShotgunGuyBase 16517
{
  Health 60
  GibHealth -40
  
  DamageFactor "Bullet", 0.85
  
  SeeSound "eliteformer/sight"
  PainSound "eliteformer/pain"
  DeathSound "eliteformer/death"
  ActiveSound "eliteformer/active"
  
  Obituary "%o was assaulted by an Elite Human Sergeant."
  Tag "Elite Sergeant [Assault Shotgun]"
    //$category "MP Nightmare"
  
	DropItem "RLEliteSergeantAssaultShotgunDrop"
	// Guncaster compatibility
	DropItem "Dosh5", 192
	DropItem "Dosh5", 192
	DropItem "Dosh10"
	DropItem "Dosh10"
  States
  {
  Spawn:
    EASS AB Random(9,10) A_Look
    Loop
	
  See:
    TNT1 A 0 A_JumpIfInventory ("RLEliteSergeantAssaultShotgunShotCounter", 6, "RetreatReload")
    EASS AABBCCDD 3 A_Chase ("", "Missile")
    Loop
  RetreatReload:
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 1)
    EASS AA 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    EASS BB 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    EASS CC 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    EASS DD 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    TNT1 A 0
    Goto RetreatReload+1
	
  MissileProper:
    EASS EE 5 A_FaceTarget
  RepeatProper:
    TNT1 A 0 A_JumpIfInventory ("RLEliteSergeantAssaultShotgunShotCounter", 6, "RetreatReload")
    TNT1 A 0 A_GiveInventory ("RLEliteSergeantAssaultShotgunShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/assaultshotgun", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/assaultshotgun", CHAN_ITEM, 0.05, 0, 0.20)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    EASS F 10 Bright A_CustomBulletAttack (22.5, 0, 3, random(1,5)*2, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    EASS E 5 A_FaceTarget
    EASS E 5 A_MonsterRefire(10, "See")
    Goto RepeatSpecialAttackCheck
	
  SummonMissile:
    EASS F 10 Bright A_CustomBulletAttack (4.5, 1, 7, random(1,2)*5, "RLEnemySummonBulletPuff", 0, CBAF_NORANDOM)
    EASS E 5 A_FaceTarget
    EASS E 5 A_MonsterRefire(10, "See")
    Goto RepeatSpecialAttackCheck
	
  Reload:
    EASS EEE 4 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/pistolreloadout", 7)
    EASS E 53
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_TakeInventory ("RLEliteSergeantAssaultShotgunShotCounter", 6)
    TNT1 A 0 A_PlaySound("rlmonsters/chaingunload", 7)
    EASS EEEE 3 A_FaceTarget
    Goto See
	
  PainMain:
    EASS G 3
    EASS G 3 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteSergeantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    EASS H 5
    EASS I 5 A_Scream
    EASS J 5 A_NoBlocking
    EASS K 5
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    EASS L 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    EASS L 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteSergeantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    EASS M 5
    ZHRF N 5 A_XScream
    ZHRF O 5 A_NoBlocking
    ZHRF PQ 5
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    ZHRF RST 5
    ZHRF U 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteSergeantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    EASS M 5
    ZHRF N 5 A_XScream
    ZHRF O 5 A_NoBlocking
    ZHRF PQ 5
    ZHRF RST 5
    ZHRF U 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLEliteSergeantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    EASS L 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, 2)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_TakeInventory ("RLEliteSergeantAssaultShotgunShotCounter", 6)
    EASS K 5
    EASS J 5
    EASS I 5
    EASS H 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_ChangeFlag ("ALWAYSFAST", 1)
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1) 
    TNT1 A 0 A_ChangeFlag ("SEEINVISIBLE", 1)
    TNT1 A 0 A_ChangeFlag ("MISSILEMORE", 1)
    Goto RaiseContinue
	
  CrushDRLA:
    TNT1 A 0 A_SpawnItemEx("RLCrushedSmall",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
	
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 X 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 X 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 800, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLEliteSergeantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 800, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLEliteSergeantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  Duke2LaserAttack:
    EASS EE 5 A_FaceTarget
    TNT1 A 0 A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-16,-14), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(14,16), CMF_OFFSETPITCH, frandom(-1,1))
    EASS F 10 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-1,1), CMF_OFFSETPITCH, frandom(-1,1))
    EASS E 10
    TNT1 A 0 A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-16,-14), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(14,16), CMF_OFFSETPITCH, frandom(-1,1))
    EASS F 10 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-1,1), CMF_OFFSETPITCH, frandom(-1,1))
    EASS E 10
    TNT1 A 0 A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-16,-14), CMF_OFFSETPITCH, frandom(-1,1))
    TNT1 A 0 A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(14,16), CMF_OFFSETPITCH, frandom(-1,1))
    EASS F 10 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-1,1), CMF_OFFSETPITCH, frandom(-1,1))
    EASS E 10
    Goto See
	
  ShadowAuraMissileAttack:
    EASS EEE 5 A_FaceTarget
  ShadowAuraRepeatAttack:
    TNT1 A 0 A_PlaySound("rlmonsters/assaultshotgun", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/assaultshotgun", CHAN_ITEM, 0.05, 0, 0.20)
    EASS F 10 Bright A_CustomBulletAttack (22.5, 0, 3, random(1,5)*2, "RLEnemyPiercingPuff", 0, CBAF_NORANDOM)
    EASS E 5 A_FaceTarget
    EASS E 5 A_MonsterRefire(150, "See")
    Goto RepeatSpecialAttackCheck
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MinorManaPod",-1,54)
    EASS G 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		EASS G 0 A_SpawnItemEx("Midas_Statue_ShotgunGuy", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		EASS G 0 A_SpawnItemEx("Midas_Statue_ShotgunGuy", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		EASS G 0 A_SpawnItemEx("Midas_Statue_ShotgunGuy", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		EASS G 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		EASS G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		EASS G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

Actor RLEliteSergeantAssaultShotgunShotCounter : Inventory
{
inventory.maxamount 6
}

ACTOR RLDRPGSummonedEliteSergeant : RLEliteSergeantAssaultShotgun
{
  -COUNTKILL
  +AVOIDMELEE
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCEliteSergeantAssaultShotgun : RLEliteSergeantAssaultShotgun
{
  +TOUCHY
  States
  {
  See:
    EASS AABBCCDD 3
    Loop
  Missile:
    EASS E 10
    EASS F 7 Bright
    EASS E 5
    EASS F 7 Bright
    EASS E 5
    EASS F 7 Bright
    EASS E 10
    Goto See
  Melee:
    Stop
  Death:
    EASS H 5
    EASS I 5 A_Scream
    EASS J 5 A_NoBlocking
    EASS K 5
    EASS L -1
    Stop
  }
}

//==============================================================================
//							MONSTER'S ITEM POOL

ACTOR RLEliteSergeantAssaultShotgunDrop : RLEnemyWeaponDrop
{
	States
	{
	WeaponDrop: // Drops for DRLA Arsenal + Monsterpack
		TNT1 A 0 A_DropItem("RLAssaultShotgunPickup", 1, 30)
		TNT1 A 0 A_DropItem("RLShellBox")
		Stop
	WeaponDropNoArsenal: // Drops for Monsterpack
		TNT1 A 0 A_DropItem("ShellBox")
		Stop
	WeaponDropVanilla: // Drops for Monsterpack if vanilla drops option is enabled
		TNT1 A 0 A_DropItem("Shotgun")
		Stop
	DonutstealDrop: // Drops for Demonsteele
		TNT1 A 0 A_DropItem("Shell")
		Stop
	}
}
