
// ELITE FORMER HUMAN SERGEANT
//
ACTOR RLEliteSergeantPlasmaShotgun : RLShotgunGuyBase 16518
{
  Health 60
  GibHealth -40
  
  DamageFactor "Bullet", 0.85
  
  SeeSound "eliteformer/sight"
  PainSound "eliteformer/pain"
  DeathSound "eliteformer/death"
  ActiveSound "eliteformer/active"
  
  Obituary "%o found himself on the wrong end of a Elite Human Sergeant's plasma shotgun."
  Tag "Elite Sergeant [Plasma Shotgun]"
    //$category "MP Nightmare"
  
	DropItem "RLEliteSergeantPlasmaShotgunDrop"
	// Guncaster compatibility
	DropItem "Dosh5", 192
	DropItem "Dosh5", 192
	DropItem "Dosh10"
	DropItem "Dosh10"
  States
  {
  Spawn:
    ESPS AB Random(9,10) A_Look
    Loop
	
  See:
    TNT1 A 0 A_JumpIfInventory ("RLEliteSergeantPlasmaShotgunShotCounter", 10, "RetreatReload")
    ESPS AABBCCDD 3 A_Chase ("", "Missile")
    Loop
  RetreatReload:
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 1)
    ESPS AA 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    ESPS BB 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    ESPS CC 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    ESPS DD 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    TNT1 A 0
    Goto RetreatReload+1
	
  MissileProper:
    ESPS EE 5 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLEliteSergeantPlasmaShotgunShotCounter", 10, "RetreatReload")
    TNT1 A 0 A_GiveInventory ("RLEliteSergeantPlasmaShotgunShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/plasmashotgun", CHAN_WEAPON, 1.0, 0, 0.9)
    TNT1 A 0 A_PlaySound("rlmonsters/plasmashotgun", 7, 1.0, 0, 0.6)
    TNT1 AAAA 0 A_CustomMissile ("RLEliteSergeantPlasmaShotgunBallSilent", 30, 13, frandom(12,-12), CMF_OFFSETPITCH, frandom(5,-5))
    TNT1 AA 0 A_CustomMissile ("RLEliteSergeantPlasmaShotgunBall", 30, 13, frandom(12,-12), CMF_OFFSETPITCH, frandom(5,-5))
    ESPS F 10 Bright A_CustomMissile ("RLEliteSergeantPlasmaShotgunBall", 30, 13, frandom(12,-12), CMF_OFFSETPITCH, frandom(5,-5))
    ESPS EEE 5 A_FaceTarget
    Goto See
	
  Reload:
    ESPS EE 2 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/plasmapistolunload", 7)
    ESPS E 23
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_TakeInventory ("RLEliteSergeantPlasmaShotgunShotCounter", 10)
    TNT1 A 0 A_PlaySound("rlmonsters/plasmapistolload", 7)
    ESPS E 4
    TNT1 A 0 A_PlaySound("weapons/plasmashotgunpump", 6)
    ESPS E 7
    TNT1 A 0 A_PlaySound("weapons/plasmashotgunspark", 7)
    ESPS EEEEEE 3 A_FaceTarget
    Goto See
	
  PainMain:
    ESPS G 3
    ESPS G 3 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteSergeantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    ESPS H 5
    ESPS I 5 A_Scream
    ESPS J 5 A_NoBlocking
    ESPS K 5
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    ESPS L 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    ESPS L 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteSergeantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    ESPS M 5
    ZHRF N 5 A_XScream
    ZHRF O 5 A_NoBlocking
    ZHRF PQ 5
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    ZHRF RST 5
    ZHRF U 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLEliteSergeantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    ESPS M 5
    ZHRF N 5 A_XScream
    ZHRF O 5 A_NoBlocking
    ZHRF PQ 5
    ZHRF RST 5
    ZHRF U 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLEliteSergeantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    ESPS L 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, 2)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_TakeInventory ("RLEliteSergeantPlasmaShotgunShotCounter", 10)
    ESPS K 5
    ESPS J 5
    ESPS I 5
    ESPS H 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_ChangeFlag ("ALWAYSFAST", 1)
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1) 
    TNT1 A 0 A_ChangeFlag ("SEEINVISIBLE", 1)
    TNT1 A 0 A_ChangeFlag ("MISSILEMORE", 1)
    Goto RaiseContinue
	
  CrushDRLA:
    TNT1 A 0 A_SpawnItemEx("RLCrushedSmall",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  ArsenalMissileCheck:
    "####" "#" 0 A_JumpIfInventory("DRPGShadowAuraToken", 1, "ShadowAuraMissileAttack") // DRPG Shadow Aura
    "####" "#" 0 A_JumpIfInventory("LDLegendaryMonsterTransformed", 1, "LegendaryMissileAttack") // LegenDoom legendary monster
    "####" "#" 0 A_Jump(256, "MissileProper")
	Goto MissileProper
	
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 Y 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 Y 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 800, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLEliteSergeantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 800, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLEliteSergeantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMissileAttack:
    ESPS EEE 5 A_FaceTarget
  ShadowAuraRepeatAttack:
    TNT1 AAAA 0 A_CustomMissile ("RLEliteSergeantPlasmaShotgunBallSilent", 30, 13, frandom(12,-12), CMF_OFFSETPITCH, frandom(5,-5))
    TNT1 AA 0 A_CustomMissile ("RLEliteSergeantPlasmaShotgunBall", 30, 13, frandom(12,-12), CMF_OFFSETPITCH, frandom(5,-5))
    ESPS F 10 Bright A_CustomMissile ("RLEliteSergeantPlasmaShotgunBall", 30, 13, frandom(12,-12), CMF_OFFSETPITCH, frandom(5,-5))
    ESPS EEE 5 A_FaceTarget
    TNT1 A 0 A_MonsterRefire (0, "See")
    Goto RepeatSpecialAttackCheck
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MinorManaPod",-1,54)
    ESPS G 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		ESPS G 0 A_SpawnItemEx("Midas_Statue_ShotgunGuy", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		ESPS G 0 A_SpawnItemEx("Midas_Statue_ShotgunGuy", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		ESPS G 0 A_SpawnItemEx("Midas_Statue_ShotgunGuy", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		ESPS G 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		ESPS G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		ESPS G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

ACTOR RLEliteSergeantPlasmaShotgunBall : PlasmaBall
{
  Radius 4
  Height 2
  Alpha 0.85
  Scale 0.25
  Speed 20
  +THRUGHOST
  +NOTIMEFREEZE
  +BLOODSPLATTER
  Damage 2
  Decal "RailScorch"
  Damagetype "Plasma"
  SeeSound ""
  States
  {
  Spawn:
    PLSS AB 6 Bright
    Goto Spawn
  Death:
    PLSE ABCDE 4 Bright
    Stop
  }
}

ACTOR RLEliteSergeantPlasmaShotgunBallSilent : RLEliteSergeantPlasmaShotgunBall
{
  DeathSound ""
}

Actor RLEliteSergeantPlasmaShotgunShotCounter : Inventory
{
inventory.maxamount 10
}

ACTOR RLCCEliteSergeantPlasmaShotgun : RLEliteSergeantPlasmaShotgun
{
  +TOUCHY
  States
  {
  See:
    ESPS AABBCCDD 3
    Loop
  Missile:
    ESPS E 10
    ESPS F 10 Bright
    ESPS E 15
    Goto See
  Melee:
    Stop
  Death:
    ESPS H 5
    ESPS I 5 A_Scream
    ESPS J 5 A_NoBlocking
    ESPS K 5
    ESPS L -1
    Stop
  }
}

//==============================================================================
//							MONSTER'S ITEM POOL

ACTOR RLEliteSergeantPlasmaShotgunDrop : RLEnemyWeaponDrop
{
	States
	{
	WeaponDrop: // Drops for DRLA Arsenal + Monsterpack
		TNT1 A 0 A_DropItem("RLPlasmaShotgunPickup", 1, 30)
		TNT1 AA 0 A_DropItem("RLCell")
		Stop
	WeaponDropNoArsenal: // Drops for Monsterpack
		TNT1 AA 0 A_DropItem("Cell")
		Stop
	WeaponDropVanilla: // Drops for Monsterpack if vanilla drops option is enabled
		TNT1 A 0 A_DropItem("Shotgun")
		Stop
	DonutstealDrop: // Drops for Demonsteele
		TNT1 A 0 A_DropItem("Cell")
		Stop
	}
}
