
// NIGHTMARE ARACHNOTRON
//
ACTOR RLNightmareArachnotron : RLArachnotronBase 16528
{
  Health 750
  GibHealth -60
  Radius 58
  Height 56
  
  DamageFactor "Melee", 1.25
  DamageFactor "Ice", 0.9
  
  SeeSound "nightmarearachnotron/sight"
  ActiveSound "nightmarearachnotron/active"
  PainSound "arachnotron/pain"
  DeathSound "nightmarearachnotron/death"
  
  Obituary "%o couldn't evade a Nightmare Arachnotron."
  Tag "Nightmare Arachnotron"
    //$category "MP Nightmare"
  
	// Guncaster compatibility
	DropItem "Amber", 192
	DropItem "Emerald"
  States
  {
  Spawn:
    TNT1 A 0 A_JumpIfInventory("DRPGGreenAuraToken", 1, 2)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_TakeInventory ("RLNightmareArachnotronChargeToken", 1)
  SpawnLoop:
    NARA ACDF Random(9,10) A_Look
    Goto SpawnLoop
	
  ClearTarget:
    TNT1 A 0 A_ClearTarget
    TNT1 A 0 A_LookEx (LOF_NOSEESOUND, 0, 0, 0, 360, "SeeLoop")
    Goto SeeLoop
	
  See:
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_TakeInventory ("RLNightmareArachnotronChargeToken", 1)
    NARA A 20
  SeeLoop:
    TNT1 A 0 A_PlaySound("nightmarearachnotron/walk", CHAN_BODY, 1, 0, 1.25)
    NARA AABBCC 3 A_Chase ("", "Missile")
    TNT1 A 0 A_PlaySound("nightmarearachnotron/walk", CHAN_BODY, 1, 0, 1.25)
    NARA DDEEFF 3 A_Chase ("", "Missile")
    Goto SeeLoop
	
  MissileProper:
    NARA GGGG 5 A_FaceTarget
    TNT1 A 0 A_Jump (128, "RepeatProper")
    TNT1 A 0 A_JumpIfCloser (1024, "RepeatProper")
    Goto Charge
  RepeatProper:
    TNT1 A 0 A_JumpIfInventory("DRPGGreenAuraToken", 1, 2)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    NARA H 3 Bright A_CustomMissile("RLNightmareArachnotronPlasmaBall", 24, 0, frandom(2,-2))
    NARA G 2 A_FaceTarget
    NARA G 1 A_SpidRefire
    Goto RepeatFriendlyCheck
	
  MissileSpray:
    TNT1 A 0 A_JumpIfInventory("DRPGGreenAuraToken", 1, 2)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissileSpray") // Friendly monsters do not harm you
    NARA H 2 Bright A_CustomMissile("RLNightmareArachnotronPlasmaBall", 24, 0, -20)
    NARA G 1 A_FaceTarget
    NARA H 2 Bright A_CustomMissile("RLNightmareArachnotronPlasmaBall", 24, 0, -15)
    NARA G 1 A_FaceTarget
    NARA H 2 Bright A_CustomMissile("RLNightmareArachnotronPlasmaBall", 24, 0, -10)
    NARA G 1 A_FaceTarget
    NARA H 2 Bright A_CustomMissile("RLNightmareArachnotronPlasmaBall", 24, 0, -5)
    NARA G 1 A_FaceTarget
    NARA H 2 Bright A_CustomMissile("RLNightmareArachnotronPlasmaBall", 24, 0, 0)
    NARA G 1 A_FaceTarget
    NARA H 2 Bright A_CustomMissile("RLNightmareArachnotronPlasmaBall", 24, 0, 5)
    NARA G 1 A_FaceTarget
    NARA H 2 Bright A_CustomMissile("RLNightmareArachnotronPlasmaBall", 24, 0, 10)
    NARA G 1 A_FaceTarget
    NARA H 2 Bright A_CustomMissile("RLNightmareArachnotronPlasmaBall", 24, 0, 15)
    NARA G 1 A_FaceTarget
    NARA H 2 Bright A_CustomMissile("RLNightmareArachnotronPlasmaBall", 24, 0, 20)
    NARA GGG 5 A_FaceTarget
    NARA G 1 A_SpidRefire
    Goto RepeatFriendlyCheck
	
  Charge:
    TNT1 A 0 A_PlaySound("rlmonsters/thruster", 6, 1, 0, 0.8)
    TNT1 A 0 A_GiveInventory ("RLNightmareArachnotronChargeToken", 1)
  ChargeLoop:
    TNT1 A 0 A_JumpIfCloser (256, "MissileSpray")
    TNT1 A 0 A_PlaySound("rlmonsters/thrusterloop", 7, 1, 1)
    TNT1 A 0 A_FaceTarget
    TNT1 A 0 A_SpawnItemEx ("RLEnemyMeleeWeaponPuff", 16, 32, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLEnemyMeleeWeaponPuff", 16, -32, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    NARA G 2 ThrustThing(angle*256/360, 2, 0, 0)
    NARA G 1 A_SpidRefire
    Goto ChargeLoop
	
  SummonMissile:
    NARA H 3 Bright A_CustomMissile("RLSummonNightmareArachnotronPlasmaBall", 24, 0, frandom(2,-2))
    NARA G 2 A_FaceTarget
    NARA G 1 A_SpidRefire
    Goto RepeatFriendlyCheck
  SummonMissileSpray:
    NARA H 2 Bright A_CustomMissile("RLSummonNightmareArachnotronPlasmaBall", 24, 0, -20)
    NARA G 1 A_FaceTarget
    NARA H 2 Bright A_CustomMissile("RLSummonNightmareArachnotronPlasmaBall", 24, 0, -15)
    NARA G 1 A_FaceTarget
    NARA H 2 Bright A_CustomMissile("RLSummonNightmareArachnotronPlasmaBall", 24, 0, -10)
    NARA G 1 A_FaceTarget
    NARA H 2 Bright A_CustomMissile("RLSummonNightmareArachnotronPlasmaBall", 24, 0, -5)
    NARA G 1 A_FaceTarget
    NARA H 2 Bright A_CustomMissile("RLSummonNightmareArachnotronPlasmaBall", 24, 0, 0)
    NARA G 1 A_FaceTarget
    NARA H 2 Bright A_CustomMissile("RLSummonNightmareArachnotronPlasmaBall", 24, 0, 5)
    NARA G 1 A_FaceTarget
    NARA H 2 Bright A_CustomMissile("RLSummonNightmareArachnotronPlasmaBall", 24, 0, 10)
    NARA G 1 A_FaceTarget
    NARA H 2 Bright A_CustomMissile("RLSummonNightmareArachnotronPlasmaBall", 24, 0, 15)
    NARA G 1 A_FaceTarget
    NARA H 2 Bright A_CustomMissile("RLSummonNightmareArachnotronPlasmaBall", 24, 0, 20)
    NARA GGG 5 A_FaceTarget
    NARA G 1 A_SpidRefire
    Goto RepeatFriendlyCheck
	
  PainMain:
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_JumpIfInventory ("RLNightmareArachnotronChargeToken", 1, "Paintrap")
    NARA I 3
    NARA I 3 A_Pain
    Goto SeeLoop
  Paintrap:
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    TNT1 A 0 A_TakeInventory ("RLNightmareArachnotronChargeToken", 1)
    TNT1 A 0 A_Pain
    Goto MissileSpray
	
  XDeathMain:
  DeathMain:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLNightmareArachnotronKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLReducedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_TakeInventory ("RLNightmareArachnotronChargeToken", 1)
    NARA J 20 A_Scream
    NARA K 7 A_NoBlocking
    NARA LMNO 7
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    NARA P 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLNightmareArachnotronKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_TakeInventory ("RLNightmareArachnotronChargeToken", 1)
    NARA J 20 A_Scream
    NARA K 7 A_NoBlocking
    NARA LMNO 7
    NARA P 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    TNT1 A 0 A_StopSound(7)
    NARA P 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLNightmareArachnotronKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    NARA P 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_JumpIfInventory("DRPGGreenAuraToken", 1, 2)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    NARA PONMLKJ 5
    Goto SeeLoop
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    Goto RaiseContinue
	
  CrushDRLA:
    "####" "#" 0 A_BossDeath
    TNT1 A 0 A_SpawnItemEx("RLCrushedMedium",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 M 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 M 2 Bright
    Goto See
  Pain.CyberDisruptor:
    TNT1 A 0
    Goto Pain.LightningBlue
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLNightmareArachnotronKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLNightmareArachnotronKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMissileAttack:
    TNT1 A 0 A_StopSound(7)
  ShadowAuraRepeatAttack:
    TNT1 A 0 A_JumpIfCloser (768, "ShadowAuraMissileAttackSpray")
    NARA H 3 Bright A_CustomMissile("RLNightmareArachnotronShadowPulse", 24, 0, 0)
    NARA G 8 A_FaceTarget
    NARA G 0 A_MonsterRefire (0, "SeeLoop")
    Goto RepeatFriendlyCheck
  ShadowAuraMissileAttackSpray:
    NARA H 2 Bright A_CustomMissile("RLNightmareArachnotronShadowPulse", 24, 0, frandom(-12,12), CMF_OFFSETPITCH, frandom(-4,4))
    NARA G 1 A_FaceTarget
    NARA G 0 A_MonsterRefire (0, "SeeLoop")
    Goto RepeatFriendlyCheck
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    NARA I 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		NARA I 0 A_SpawnItemEx("Midas_Statue_Arach", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		NARA I 0 A_SpawnItemEx("Midas_Statue_Arach", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		NARA I 0 A_SpawnItemEx("Midas_Statue_Arach", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		NARA I 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		NARA I 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		NARA I 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

Actor RLNightmareArachnotronChargeToken : Inventory
{
inventory.maxamount 1
}

ACTOR RLNightmareArachnotronPlasmaBall : ArachnotronPlasma
{
   +NOTIMEFREEZE
   +THRUGHOST
   +BLOODSPLATTER
   Alpha 0.85
   Scale 0.4
   Decal "BFGLightning"
   Damage 8
   DamageType "Plasma"
   SeeSound "rlmonsters/highpowerplasma"
   States
   {
   Spawn:
      PPCS CD 4 Bright
      Goto Spawn
   Death:
      BBB2 ABCDE 5 Bright
      Stop
   }
}

ACTOR RLNightmareArachnotronShadowPulse : FastProjectile
{
    Radius 6
    Height 6
    Speed 48
    Damage 4
	DamageType "Plasma"
    Decal "Scorch"
    RenderStyle Add
    Alpha 0.95
    Projectile
    +THRUGHOST
	+NOTIMEFREEZE
    +BLOODSPLATTER
    SeeSound "rlmonsters/plasmamarksman"
    DeathSound "weapons/plasmax"
    States
    {
    Spawn:
        TNT1 A 1
		TNT1 A 0 A_SpawnItemEx("RLNightmareArachnotronShadowPulseTrail",(0.01*momx)/-35.0, -(0.01*momy)/-35.0, 2+(0.01*momz)/-35.0, 0, 0, 0, 0, SXF_ABSOLUTEANGLE | SXF_NOCHECKPOSITION)
        TNT1 A 0 A_SpawnItemEx("RLNightmareArachnotronShadowPulseTrail",(0.5*momx)/-35.0, -(0.5*momy)/-35.0, 2+(0.5*momz)/-35.0, 0, 0, 0, 0, SXF_ABSOLUTEANGLE | SXF_NOCHECKPOSITION)
        TNT1 A 0 A_SpawnItemEx("RLNightmareArachnotronShadowPulseTrail", (1 *momx)/-35.0, -(1 *momy)/-35.0, 2+(1 *momz)/-35.0, 0, 0, 0, 0, SXF_ABSOLUTEANGLE | SXF_NOCHECKPOSITION)
        TNT1 A 0 A_SpawnItemEx("RLNightmareArachnotronShadowPulseTrail",(1.5*momx)/-35.0, -(1.5*momy)/-35.0, 2+(1.5*momz)/-35.0, 0, 0, 0, 0, SXF_ABSOLUTEANGLE | SXF_NOCHECKPOSITION)
        TNT1 A 0 A_SpawnItemEx("RLNightmareArachnotronShadowPulseTrail", (2 *momx)/-35.0, -(2 *momy)/-35.0, 2+(2 *momz)/-35.0, 0, 0, 0, 0, SXF_ABSOLUTEANGLE | SXF_NOCHECKPOSITION)
        TNT1 A 0 A_SpawnItemEx("RLNightmareArachnotronShadowPulseTrail",(2.5*momx)/-35.0, -(2.5*momy)/-35.0, 2+(2.5*momz)/-35.0, 0, 0, 0, 0, SXF_ABSOLUTEANGLE | SXF_NOCHECKPOSITION)
        TNT1 A 0 A_SpawnItemEx("RLNightmareArachnotronShadowPulseTrail", (3 *momx)/-35.0, -(3 *momy)/-35.0, 2+(3 *momz)/-35.0, 0, 0, 0, 0, SXF_ABSOLUTEANGLE | SXF_NOCHECKPOSITION)
        TNT1 A 0 A_SpawnItemEx("RLNightmareArachnotronShadowPulseTrail",(3.5*momx)/-35.0, -(3.5*momy)/-35.0, 2+(3.5*momz)/-35.0, 0, 0, 0, 0, SXF_ABSOLUTEANGLE | SXF_NOCHECKPOSITION)
        TNT1 A 0 A_SpawnItemEx("RLNightmareArachnotronShadowPulseTrail", (4 *momx)/-35.0, -(4 *momy)/-35.0, 2+(4 *momz)/-35.0, 0, 0, 0, 0, SXF_ABSOLUTEANGLE | SXF_NOCHECKPOSITION)
        TNT1 A 0 A_SpawnItemEx("RLNightmareArachnotronShadowPulseTrail",(4.5*momx)/-35.0, -(4.5*momy)/-35.0, 2+(4.5*momz)/-35.0, 0, 0, 0, 0, SXF_ABSOLUTEANGLE | SXF_NOCHECKPOSITION)
        TNT1 A 0 A_SpawnItemEx("RLNightmareArachnotronShadowPulseTrail", (5 *momx)/-35.0, -(5 *momy)/-35.0, 2+(5 *momz)/-35.0, 0, 0, 0, 0, SXF_ABSOLUTEANGLE | SXF_NOCHECKPOSITION)
        TNT1 A 0 A_SpawnItemEx("RLNightmareArachnotronShadowPulseTrail",(5.5*momx)/-35.0, -(5.5*momy)/-35.0, 2+(5.5*momz)/-35.0, 0, 0, 0, 0, SXF_ABSOLUTEANGLE | SXF_NOCHECKPOSITION)
        TNT1 A 0 A_SpawnItemEx("RLNightmareArachnotronShadowPulseTrail", (6 *momx)/-35.0, -(6 *momy)/-35.0, 2+(6 *momz)/-35.0, 0, 0, 0, 0, SXF_ABSOLUTEANGLE | SXF_NOCHECKPOSITION)
        TNT1 A 0 A_SpawnItemEx("RLNightmareArachnotronShadowPulseTrail",(6.5*momx)/-35.0, -(6.5*momy)/-35.0, 2+(6.5*momz)/-35.0, 0, 0, 0, 0, SXF_ABSOLUTEANGLE | SXF_NOCHECKPOSITION)
        TNT1 A 0 A_SpawnItemEx("RLNightmareArachnotronShadowPulseTrail", (7 *momx)/-35.0, -(7 *momy)/-35.0, 2+(7 *momz)/-35.0, 0, 0, 0, 0, SXF_ABSOLUTEANGLE | SXF_NOCHECKPOSITION)
        TNT1 A 0 A_SpawnItemEx("RLNightmareArachnotronShadowPulseTrail",(7.5*momx)/-35.0, -(7.5*momy)/-35.0, 2+(7.5*momz)/-35.0, 0, 0, 0, 0, SXF_ABSOLUTEANGLE | SXF_NOCHECKPOSITION)
        TNT1 A 0 A_SpawnItemEx("RLNightmareArachnotronShadowPulseTrail", (8 *momx)/-35.0, -(8 *momy)/-35.0, 2+(8 *momz)/-35.0, 0, 0, 0, 0, SXF_ABSOLUTEANGLE | SXF_NOCHECKPOSITION)
		Loop
    Death:
        BBB2 ABCDE 3 Bright
        stop
    }
}

actor RLNightmareArachnotronShadowPulseTrail
{
    Scale 0.25
    RenderStyle Add
    Alpha 0.95
    +NOINTERACTION
	+NOTIMEFREEZE
    States
    {
    Spawn:
        NALP A 2 Bright
        stop
    }
}

ACTOR RLSummonNightmareArachnotronPlasmaBall : RLNightmareArachnotronPlasmaBall
{
   +MTHRUSPECIES
}

ACTOR RLNightmareArachnotronReborn : RLNightmareArachnotron
{
  +LOOKALLAROUND
  +NOPAIN
  States
  {
  Spawn:
    TNT1 A 0 NoDelay A_JumpIfInventory("RLResurrectionComplete", 1, "SpawnNormal")
    NARA PONMLKJ 5
    TNT1 A 0 A_ChangeFlag("NOPAIN", 0)
    TNT1 A 0 A_GiveInventory("RLResurrectionComplete", 1)
  SpawnNormal:
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_TakeInventory ("RLNightmareArachnotronChargeToken", 1)
    NARA ACDF 10 A_Look
    Loop
  }
}

ACTOR RLDRPGSummonedNightmareArachnotron : RLNightmareArachnotron
{
  -COUNTKILL
  +AVOIDMELEE
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCNightmareArachnotron : RLNightmareArachnotron
{
  +TOUCHY
  States
  {
  See:
    NARA A 20
    NARA AABBCC 3
    NARA DDEEFF 3
    Goto See+1
  Missile:
    NARA G 20
    NARA H 3 Bright
    NARA G 3
    Goto Missile+1
  Melee:
    Stop
  Death:
    NARA J 20 A_Scream
    NARA K 7 A_NoBlocking
    NARA LMNO 7
    NARA P -1 A_BossDeath
    Stop
  }
}
