
// BARON OF NIGHTMARES
//
ACTOR RLNightmareBaronOfHell : RLBaronOfHellBase 16527
{
  Health 1250
  GibHealth -90
  Mass 1800
  Bloodcolor "DarkGreen"
  
  DamageFactor "Plasma", 0.75
  
  +MISSILEMORE
  
  SeeSound "nightmarebaron/sight"
  ActiveSound "nightmarebaron/active"
  PainSound "nightmarebaron/pain"
  DeathSound "nightmarebaron/death"
  
  Obituary "%o was eradicated by a Baron of Nightmares."
  HitObituary "%o was smashed apart by a Baron of Nightmares."
  Tag "Baron of Nightmares"
    //$category "MP Nightmare"
  
	// Guncaster compatibility
	DropItem "Emerald"
	DropItem "Emerald"
  States
  {
  Spawn:
    NBAR BD Random(9,10) A_Look
    Goto Spawn
	
  See:
    NBAR AABBCCDD 3 A_Chase
    Loop
	
  MissileHatredOnUniqueEffect: // [incoherent tantrum sounds]
    "####" "#" 0 A_PlaySound ("nightmarebaron/sight", CHAN_VOICE)
    "####" "#" 0 A_Jump (256, "MissileHatredOnUniqueDone")
	Goto MissileHatredOnUniqueDone
  MeleeHatredOnUniqueEffect: // [incoherent tantrum sounds]
    "####" "#" 0 A_PlaySound ("nightmarebaron/sight", CHAN_VOICE)
    "####" "#" 0 A_Jump (256, "MeleeHatredOnUniqueDone")
	Goto MeleeHatredOnUniqueDone
	
  MeleeProper:
  MissileProper:
    TNT1 A 0 A_Jump (100, "ExplodoMissile")
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 2) // Friendly monsters do not use commands
    TNT1 A 0 A_Jump (48, "Command")
    NBAR EF 8 A_FaceTarget
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    NBAR G 8 A_CustomComboAttack("RLNightmareBaronOfHellPlasmaBall", 32, 24 * random(1, 4), "baron/melee")
    Goto See
	
  ExplodoMissile:
    NBAR E 4 A_FaceTarget
    NBAR EEF 10 A_FaceTarget
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonExplodoMissile") // Friendly monsters do not harm you
    NBAR G 20 A_CustomComboAttack("RLNightmareBaronOfHellExplodingBall", 32, 38 * random(1, 4), "baron/melee")
    Goto See
	
  Command:
    NBAR E 4 A_FaceTarget
    TNT1 A 0 A_PlaySound("nightmarebaron/sight", CHAN_VOICE)
    NBAR E 4 A_FaceTarget
    TNT1 A 0 A_RadiusGive ("PowerRLNightmareBaronCommand", 1024, RGF_MONSTERS | RGF_GIVESELF, 1)
    Goto CommandMissile
  CommandMissile:
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, 1)
    Goto CommandMissile1
    NBAR E 1 A_FaceTarget
    Goto CommandMissile
  CommandMissile1:
    NBAR EF 4 A_FaceTarget
    NBAR G 4 A_CustomMissile("RLNightmareBaronOfHellPlasmaBall",32,0,frandom(0, 4))
    TNT1 A 0 A_MonsterRefire (0, "See")
    Goto CommandMissile1
	
  SummonMissile:
    NBAR G 8 A_CustomComboAttack("RLSummonNightmareBaronOfHellPlasmaBall", 32, 24 * random(1, 4), "baron/melee")
    Goto See
  SummonExplodoMissile:
    NBAR G 20 A_CustomComboAttack("RLSummonNightmareBaronOfHellExplodingBall", 32, 38 * random(1, 4), "baron/melee")
    Goto See
	
  PainMain:
    NBAR H 2
    NBAR H 2 A_Pain
    Goto See

  //Fire
  Pain.Meteorfist:
	"####" "#" 0 A_FaceTarget
	"####" "#" 0 A_ChangeVelocity(frandom(-13.0,-17.0),0,frandom(9.0,11.0),CVF_RELATIVE)
	"####" "#" 0 A_Jump(256,"Pain")
	Goto Pain
  Pain.Fire:
	"####" "#" 0 A_Jump(256,"Pain")
	Goto Pain
	
  XDeathMain:
  DeathMain:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLNightmareBaronOfHellKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    NBAR H 2
    NBAR H 28 A_Scream
    TNT1 A 0 A_SpawnItemEx ("RLNightmareBaronExplosion", random(-12, 12), random(-12, 12), random(5, 60), 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    NBAR H 4 Bright
    TNT1 AA 0 A_SpawnItemEx ("RLNightmareBaronExplosion", random(-12, 12), random(-12, 12), random(5, 60), 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    NBAR H 4 Bright A_NoBlocking
    TNT1 AAA 0 A_SpawnItemEx ("RLNightmareBaronExplosion", random(-12, 12), random(-12, 12), random(5, 60), 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    NBAR H 3 Bright
    TNT1 AA 0 A_SpawnItemEx ("RLNightmareBaronExplosion", random(-12, 12), random(-12, 12), random(5, 60), 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    NBAR H 3 Bright
    TNT1 A 0 A_SpawnItemEx ("RLNightmareBaronExplosion", random(-12, 12), random(-12, 12), random(5, 60), 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    NBAR H 3 Bright
    TNT1 AA 0 A_SpawnItemEx ("RLNightmareBaronExplosion", random(-12, 12), random(-12, 12), random(5, 60), 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    NBAR H 3 Bright
    TNT1 AA 0 A_SpawnItemEx ("RLNightmareBaronExplosion", random(-12, 12), random(-12, 12), random(5, 60), 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    NBAR H 3 Bright
    TNT1 A 0 A_SpawnItemEx ("RLNightmareBaronExplosion", random(-12, 12), random(-12, 12), random(5, 60), 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    NBAR H 8 Bright
    TNT1 A 0 A_SpawnItemEx ("RLNightmareBaronFlames", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 AAAAAA 0 A_SpawnItemEx ("RLNightmareBaronFlames2", random(-6, 6), random(-6, 6), 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLNightmareBaronExplosion2", 0, 0, 32, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0
    "####" "#" 0 A_Jump(256, "DestroyedEnd")
    Goto DestroyedEnd
  SimpleXDeathMain:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLNightmareBaronOfHellKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    NBAR H 28 A_Scream
    NBAR H 4 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLNightmareBaronFlames", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0
    "####" "#" 0 A_Jump(256, "DestroyedEnd")
    Goto DestroyedEnd
  DeathFrame:
    TNT1 A 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DestroyedEnd")
    Goto DestroyedEnd
	
  //Fire
  Death.Meteorfist:
	"####" "#" 0 A_FaceTarget
	"####" "#" 0 A_ChangeVelocity(frandom(-15.0,-20.0),0,frandom(10.0,15.0),CVF_RELATIVE)
	"####" "#" 0 A_Jump(256,"Death")
	Goto Death
  Death.Lightning:
  Death.LightningBlue:
  Death.Fire:
	"####" "#" 0 A_Jump(256,"Death")
	Goto Death
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLNightmareBaronOfHellKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
    Stop
	
  CrushDRLA:
    "####" "#" 0 A_BossDeath
    TNT1 A 0 A_SpawnItemEx("RLCrushedMediumGreen",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 U 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 U 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 2000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLNightmareBaronOfHellKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 2000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLNightmareBaronOfHellKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2Gibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMissileAttack:
    NBAR EF 8 A_FaceTarget
    TNT1 A 0 A_CustomMissile("RLNightmareBaronOfHellPlasmaBall", 32, 0, 8)
    TNT1 A 0 A_CustomMissile("RLNightmareBaronOfHellPlasmaBall", 32, 0, -8)
    NBAR G 8 A_CustomComboAttack("RLNightmareBaronOfHellPlasmaBall", 32, 38 * random(1, 4), "baron/melee")
    Goto See
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    NBAR H 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		NBAR H 0 A_SpawnItemEx("Midas_Statue_BaronOfHell", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		NBAR H 0 A_SpawnItemEx("Midas_Statue_BaronOfHell", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		NBAR H 0 A_SpawnItemEx("Midas_Statue_BaronOfHell", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		NBAR H 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		NBAR H 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		NBAR H 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

ACTOR RLNightmareBaronFlames
{
  +NOBLOCKMAP
  +NOGRAVITY
  +NOTONAUTOMAP
  +NOTIMEFREEZE
  RenderStyle Add
  Alpha 0.98
  Scale 1.6
  States
  {
  Spawn:
    TNT1 A 0 NoDelay A_PlaySound("vile/firecrkl", 7)
    NBFR ABCDEFGH 3 Bright
    Stop
  }
}

ACTOR RLNightmareBaronFlames2 : RLNightmareBaronFlames
{
  Scale 1.2
  States
  {
  Spawn:
    NBFR ABCDEFGH 2 Bright
    Stop
  }
}

ACTOR RLNightmareBaronExplosion
{
  +NOTIMEFREEZE
  +NOBLOCKMAP
  +NOGRAVITY
  +BLOODSPLATTER
  RenderStyle Add
  Alpha 0.98
  Scale 0.6
  DamageType "Plasma"
  PainType "HellNobleFire"
  DeathType "HellNobleFire"
  States
  {
  Spawn:
    TNT1 A 0
    TNT1 A 0 A_PlaySound("rlmonsters/smallexp", 5)
    TNT1 A 0 A_Explode (20, 64)
    NBAB CDE 3 Bright
    Stop
  }
}

ACTOR RLNightmareBaronExplosion2 : RLNightmareBaronExplosion
{
  Scale 1.4
  States
  {
  Spawn:
    TNT1 A 0
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 3)
    TNT1 A 0 A_Quake (1, 8, 0, 512, "")
    TNT1 A 0 A_Quake (5, 8, 0, 256, "")
    TNT1 A 0 A_PlaySound ("rlmonsters/largeexp", 7, 1, 0, 0.5)
    TNT1 A 0 A_PlaySound("rlmonsters/largeexp", CHAN_ITEM, 0.05, 0, 0.12)
    TNT1 A 0 A_Explode (60, 128)
    NBAB C 8 Bright
    NBAB D 6 Bright
    NBAB E 4 Bright
    Stop
  }
}

ACTOR RLNightmareBaronOfHellPlasmaBall : BaronBall
{
   +NOTIMEFREEZE
   +THRUGHOST
   +BLOODSPLATTER
   Decal "Scorch"
   DamageType "Plasma"
   PainType "HellNobleFire"
   DeathType "HellNobleFire"
   Damage (30 * random(1, 3))
   Speed 20
   FastSpeed 30
   Scale 0.6
   SeeSound "rlmonsters/baronball"
   DeathSound "rlmonsters/baronballhit"
  States
  {
  Spawn:
    NBAB AB 4 Bright
    Goto Spawn
  Death:
    NBAB B 8 Bright
    NBAB C 6 Bright
    NBAB D 4 Bright
    Stop
  }
}

ACTOR RLSummonNightmareBaronOfHellPlasmaBall : RLNightmareBaronOfHellPlasmaBall
{
   +MTHRUSPECIES
}

ACTOR RLNightmareBaronOfHellExplodingBall : BaronBall
{
   +NOTIMEFREEZE
   +THRUGHOST
   +RIPPER
   +BLOODLESSIMPACT
   Decal "BFGLightning"
   DamageType "Plasma"
   PainType "HellNobleFire"
   DeathType "HellNobleFire"
   Damage (1)
   Speed 15
   FastSpeed 25
   SeeSound "rlmonsters/baronball"
   DeathSound ""
  States
  {
  Spawn:
    TNT1 A 1 A_SpawnItemEx ("RLNightmareBaronExplosion", frandom(-8,8), frandom(-8,8), frandom(-4,4), 0, 0, 0, 0, SXF_TRANSFERPOINTERS | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_Jump (20, 1)
    Goto Spawn
    TNT1 A 0 A_SpawnItemEx ("RLNightmareBaronExplosion2", frandom(-3,3), frandom(-3,3), frandom(-1,1), 0, 0, 0, 0, SXF_TRANSFERPOINTERS | SXF_NOCHECKPOSITION)
    Goto Spawn
  Death:
    TNT1 A 0
    Stop
  }
}

ACTOR RLSummonNightmareBaronOfHellExplodingBall : RLNightmareBaronOfHellExplodingBall
{
   +MTHRUSPECIES
}

ACTOR PowerRLNightmareBaronCommand : Powerup
{
	Powerup.Duration -2
   +INVENTORY.UNTOSSABLE
}

ACTOR RLNightmareBaronOfHellReborn : RLNightmareBaronOfHell
{
  +LOOKALLAROUND
  +NOPAIN
  States
  {
  Spawn:
    TNT1 A 0 NoDelay A_JumpIfInventory("RLResurrectionComplete", 1, "SpawnNormal")
    TNT1 A 0 A_GiveInventory ("RLHellNobleToken", 1)
    BARO ONMLKJI 5
    TNT1 A 0 A_SpawnItemEx ("RLNightmareBaronFlames", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_ChangeFlag("NOPAIN", 0)
    TNT1 A 0 A_GiveInventory("RLResurrectionComplete", 1)
  SpawnNormal:
    NBAR AB 10 A_Look
    Loop
  }
}

ACTOR RLDRPGSummonedNightmareBaronOfHell : RLNightmareBaronOfHell
{
  -COUNTKILL
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCNightmareBaronOfHell : RLNightmareBaronOfHell
{
  +TOUCHY
  States
  {
  Spawn:
    NBAR BD 10 A_Look
    Loop
  See:
    NBAR AABBCCDD 3
    Loop
  Melee:
    Stop
  Missile:
    NBAR EF 8
    NBAR G 8
    Goto See
  Death:
    NBAR H 2
    NBAR H 1 A_Scream
    NBAR H 1 A_NoBlocking
    NBAR H 8
    NBFR ABCDEFGH 3 Bright
    Stop
  }
}
