
// NIGHTMARE IMP
//
ACTOR RLNightmareImp : RLImpBase 16521
{
  Health 75
  GibHealth -40
  
  DamageFactor "Fire", 0.50
  
  SeeSound "nightmareimp/sight"
  ActiveSound "nightmareimp/active"
  PainSound "imp/pain"
  DeathSound "nightmareimp/death"
  
  Obituary "%o was taken down by a Nightmare Imp."
  HitObituary "%o was lacerated by a Nightmare Imp."
  Tag "Nightmare Imp"
    //$category "MP Nightmare"
  
	// Guncaster compatibility
	DropItem "Dosh5", 192
	DropItem "Dosh35"
  States
  {
  Spawn:
    TNT1 A 0 A_FadeTo (1, 1, 0)
    TNT1 A 0 A_Look
    NIMP A 4 A_Wander
    TNT1 A 0 A_Look
    NIMP A 4 A_Wander
    TNT1 A 0 A_Look
    NIMP B 4 A_Wander
    TNT1 A 0 A_Look
    NIMP B 4 A_Wander
    TNT1 A 0 A_Look
    NIMP C 4 A_Wander
    TNT1 A 0 A_Look
    NIMP C 4 A_Wander
    TNT1 A 0 A_Look
    NIMP D 4 A_Wander
    TNT1 A 0 A_Look
    NIMP D 4 A_Wander
    Loop
	
  See:
    TNT1 A 0 A_CheckSight ("InvisibleSeeA")
    TNT1 A 0 A_FadeTo (1, 0.1, 0)
    NIMP AA 3 A_Chase
    Goto SeeB
  SeeB:
    TNT1 A 0 A_CheckSight ("InvisibleSeeB")
    TNT1 A 0 A_FadeTo (1, 0.1, 0)
    NIMP BB 3 A_Chase
    Goto SeeC
  SeeC:
    TNT1 A 0 A_CheckSight ("InvisibleSeeC")
    TNT1 A 0 A_FadeTo (1, 0.1, 0)
    NIMP CC 3 A_Chase
    Goto SeeD
  SeeD:
    TNT1 A 0 A_CheckSight ("InvisibleSeeD")
    TNT1 A 0 A_FadeTo (1, 0.1, 0)
    NIMP DD 3 A_Chase
    Goto See
  InvisibleSeeA:
    NIMP AA 4 A_Chase
    TNT1 A 0 A_FadeTo (0.1, 0.1, 0)
    TNT1 A 0 A_CheckSight ("InvisibleSeeB")
    Goto SeeB
  InvisibleSeeB:
    NIMP BB 4 A_Chase
    TNT1 A 0 A_FadeTo (0.1, 0.1, 0)
    TNT1 A 0 A_CheckSight ("InvisibleSeeC")
    Goto SeeC
  InvisibleSeeC:
    NIMP CC 4 A_Chase
    TNT1 A 0 A_FadeTo (0.1, 0.1, 0)
    TNT1 A 0 A_CheckSight ("InvisibleSeeD")
    Goto SeeD
  InvisibleSeeD:
    NIMP DD 4 A_Chase
    TNT1 A 0 A_FadeTo (0.1, 0.1, 0)
    TNT1 A 0 A_CheckSight ("InvisibleSeeA")
    Goto See
	
  MeleeProper:
    TNT1 A 0 A_FadeTo (1, 1, 0)
    NIMP WX 8 A_FaceTarget
    NIMP Y 6 A_CustomMeleeAttack (3 * random(1, 8), "imp/melee", "", "Melee")
    Goto See
	
  MissileProper:
    TNT1 A 0 A_FadeTo (1, 1, 0)
    NIMP EF 8 A_FaceTarget
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    NIMP G 6 A_CustomMissile("RLNightmareImpFireball", 32)
    Goto See
  SummonMissile:
    NIMP G 6 A_CustomMissile("RLSummonNightmareImpFireball", 32)
    Goto See
	
  PainMain:
    TNT1 A 0 A_FadeTo (1, 1, 0)
    NIMP H 2
    NIMP H 2 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLNightmareImpKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_FadeTo (1, 1, 0)
    NIMP I 8
    NIMP J 8 A_Scream
    NIMP K 6
    NIMP L 6 A_NoBlocking
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    NIMP M 6
    NIMP N 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    NIMP N 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLNightmareImpKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_FadeTo (1, 1, 0)
    NIMP O 5
    NIMP P 5 A_XScream
    NIMP Q 5
    NIMP R 5 A_NoBlocking
    NIMP S 5
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    NIMP TU 5
    NIMP V 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLNightmareImpKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_FadeTo (1, 1, 0)
    NIMP O 5
    NIMP P 5 A_XScream
    NIMP Q 5
    NIMP R 5 A_NoBlocking
    NIMP S 5
    NIMP TU 5
    NIMP V 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLNightmareImpKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    NIMP N 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    NIMP MLKJI 8
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    Goto RaiseContinue
	
  CrushDRLA:
    TNT1 A 0 A_SpawnItemEx("RLCrushedSmall",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F2 B 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F2 B 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLNightmareImpKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLNightmareImpKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMissileAttack:
//    TNT1 A 0 A_FadeTo (1, 1, 0)
    NIMP EF 8 A_FaceTarget
    TNT1 A 0 A_CustomMissile("RLNightmareImpFireball", 32, 0, 15+frandom(-8,8), CMF_OFFSETPITCH, frandom(-2,2))
    TNT1 A 0 A_CustomMissile("RLNightmareImpFireball", 32, 0, -15+frandom(-8,8), CMF_OFFSETPITCH, frandom(-2,2))
    NIMP G 4 Bright A_CustomMissile("RLNightmareImpFireball", 32, 0, frandom(-8,8), CMF_OFFSETPITCH, frandom(-2,2))
    NIMP FE 4 A_FaceTarget
    Goto See
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MinorManaPod",-1,54)
    NIMP H 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		NIMP H 0 A_SpawnItemEx("Midas_Statue_Pimp", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		NIMP H 0 A_SpawnItemEx("Midas_Statue_Pimp", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		NIMP H 0 A_SpawnItemEx("Midas_Statue_Pimp", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		NIMP H 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		NIMP H 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		NIMP H 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

ACTOR RLNightmareImpFireball : BaronBall
{
   +NOTIMEFREEZE
   +THRUGHOST
   +BLOODSPLATTER
   Scale 0.8
   DamageType "Fire"
   PainType "SmallFireball"
   DeathType "SmallFireball"
   Damage 5
   States
   {
   Spawn:
    NIMB AB 4 Bright
    Goto Spawn
   Death:
    NIMB CDE 6 Bright
    Stop
   }
}

ACTOR RLSummonNightmareImpFireball : RLNightmareImpFireball
{
   +MTHRUSPECIES
}

ACTOR RLNightmareImpShadowball : BaronBall
{
   +THRUGHOST
   +RIPPER
   +BLOODLESSIMPACT
   Speed 10
   FastSpeed 10
   Decal "BaronScorch"
   DamageType "Plasma"
   Damage (1)
   RenderStyle Fuzzy
   Alpha 0.5
   States
   {
   Spawn:
    SMK2 ABCDEFGHIJKLMNOPQ 1 
    Goto Death
   Death:
    TNT1 A 0
    Stop
   }
}

ACTOR RLNightmareImpReborn : RLNightmareImp
{
  +LOOKALLAROUND
  +NOPAIN
  States
  {
  Spawn:
    TNT1 A 0 NoDelay A_JumpIfInventory("RLResurrectionComplete", 1, "SpawnNormal")
    NIMP MLKJI 8
    TNT1 A 0 A_ChangeFlag("NOPAIN", 0)
    TNT1 A 0 A_GiveInventory("RLResurrectionComplete", 1)
  SpawnNormal:
    TNT1 A 0 A_FadeTo (1, 1, 0)
    TNT1 A 0 A_Look
    NIMP A 4 A_Wander
    TNT1 A 0 A_Look
    NIMP A 4 A_Wander
    TNT1 A 0 A_Look
    NIMP B 4 A_Wander
    TNT1 A 0 A_Look
    NIMP B 4 A_Wander
    TNT1 A 0 A_Look
    NIMP C 4 A_Wander
    TNT1 A 0 A_Look
    NIMP C 4 A_Wander
    TNT1 A 0 A_Look
    NIMP D 4 A_Wander
    TNT1 A 0 A_Look
    NIMP D 4 A_Wander
    Loop
  }
}

ACTOR RLDRPGSummonedNightmareImp : RLNightmareImp
{
  -COUNTKILL
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCNightmareImp : RLNightmareImp
{
  +TOUCHY
  States
  {
  Spawn:
    NIMP AB 4
    Loop
  See:
    NIMP AABBCCDD 3
    Loop
  Melee:
    NIMP WX 8
    NIMP Y 6
    Goto See
  Missile:
    NIMP EF 8
    NIMP G 6
    Goto See
  Death:
    NIMP I 8
    NIMP J 8 A_Scream
    NIMP K 6
    NIMP L 6 A_NoBlocking
    NIMP M 6
    NIMP N -1
    Stop
  }
}
