
// NIGHTMARE MANCUBUS
//
ACTOR RLNightmareMancubus : RLMancubusBase 16531
{
  Health 800
  GibHealth -100
  BloodColor "Dark Red"
  
  DamageFactor "Fire", 1.2
  DamageFactor "Ice", 0.7
  DamageFactor "Plasma", 0.75
  
  SeeSound "nightmaremancubus/sight"
  PainSound "nightmaremancubus/pain"
  DeathSound "nightmaremancubus/death"
  ActiveSound "eliteformer/active"
  
  Obituary "%o was brought down by a Nightmare Mancubus."
  Tag "Nightmare Mancubus"
    //$category "MP Nightmare"
  
	// Guncaster compatibility
	DropItem "Amber"
	DropItem "Emerald"
  States
  {
  Spawn:
    NMAN CF Random(14,15) A_Look
    Loop
	
  See:
    NMAN AABBCCDDEEFF 4 A_Chase ("", "Missile")
    Loop
	
  MissileProper:
    TNT1 A 0 A_JumpIfInventory ("RLNightmareMancubusHomingTarget", 1, 2, AAPTR_TARGET)
    TNT1 A 0 A_JumpIfCloser(1000, 1)
	Goto HomingMissile
    TNT1 A 0 A_PlaySound("nightmaremancubus/attack", CHAN_VOICE)
    NMAN G 20 A_FaceTarget
  RepeatProper:
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    TNT1 AA 0 A_CustomMissile("RLNightmareMancubusPlasmaball2", 20, 28, frandom(-2,2), CMF_OFFSETPITCH, frandom(-2,2))
    NMAN U 8 Bright A_CustomMissile("RLNightmareMancubusPlasmaball", 20, 28, 0)
    NMAN IG 3 A_FaceTarget
    TNT1 AA 0 A_CustomMissile("RLNightmareMancubusPlasmaball2", 20, -31, frandom(-2,2), CMF_OFFSETPITCH, frandom(-2,2))
    NMAN V 8 Bright A_CustomMissile("RLNightmareMancubusPlasmaball", 20, -31, 0)
    NMAN I 3 A_FaceTarget
    NMAN G 3 A_MonsterRefire(200, "See")
    Goto RepeatFriendlyCheck
	
  HomingMissile:
    TNT1 A 0 A_PlaySound("nightmaremancubus/attack", CHAN_VOICE)
    NMAN G 20 A_FaceTarget
    TNT1 A 0 A_GiveInventory ("RLNightmareMancubusHomingTarget", 1, AAPTR_TARGET)
    TNT1 A 0 A_CustomMissile("RLNightmareMancubusHomingPlasmaball", 20, -31, 0)
    NMAN H 10 Bright A_CustomMissile("RLNightmareMancubusHomingPlasmaball", 20, 28, 0)
    NMAN IG 5 A_FaceTarget
    Goto See
	
  SummonMissile:
    TNT1 AA 0 A_CustomMissile("RLSummonNightmareMancubusPlasmaball2", 20, 28, frandom(-2,2), CMF_OFFSETPITCH, frandom(-2,2))
    NMAN U 8 Bright A_CustomMissile("RLSummonNightmareMancubusPlasmaball", 20, 28, 0)
    NMAN IG 3 A_FaceTarget
    TNT1 AA 0 A_CustomMissile("RLSummonNightmareMancubusPlasmaball2", 20, -31, frandom(-2,2), CMF_OFFSETPITCH, frandom(-2,2))
    NMAN V 8 Bright A_CustomMissile("RLSummonNightmareMancubusPlasmaball", 20, -31, 0)
    NMAN I 3 A_FaceTarget
    NMAN G 3 A_MonsterRefire(200, "See")
    Goto RepeatFriendlyCheck
	
  PainMain:
    NMAN J 3
    NMAN J 3 A_Pain
    Goto See
	
  XDeathMain:
  DeathMain:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLNightmareMancubusKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    NMAN K 6
    NMAN L 6 A_Scream
    NMAN M 6 A_NoBlocking
    NMAN N 6
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    NMAN OPQRS 6
    NMAN T 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLNightmareMancubusKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    NMAN K 6
    NMAN L 6 A_Scream
    NMAN M 6 A_NoBlocking
    NMAN N 6
    NMAN OPQRS 6
    NMAN T 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    NMAN T 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLNightmareMancubusKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    NMAN T 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    NMAN RQPONMLK 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    Goto RaiseContinue
	
  CrushDRLA:
    "####" "#" 0 A_BossDeath
    TNT1 A 0 A_SpawnItemEx("RLCrushedMedium",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 P 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 P 2 Bright
    Goto See
  Pain.CyberDisruptor:
    TNT1 A 0
    Goto Pain.LightningBlue
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 2000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLNightmareMancubusKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2AdvancedEnemyExplosions", 0,0,32, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 2000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLNightmareMancubusKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2AdvancedEnemyExplosions", 0,0,32, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMissileAttack:
    TNT1 A 0 A_PlaySound("nightmaremancubus/attack", CHAN_VOICE)
    NMAN G 20 A_FaceTarget
  ShadowAuraRepeatAttack:
    NMAN UUUU 2 Bright A_CustomMissile("RLNightmareMancubusPlasmaball", 20, 28, frandom(4,-4))
    NMAN IG 3 A_FaceTarget
    NMAN VVVV 2 Bright A_CustomMissile("RLNightmareMancubusPlasmaball", 20, -31, frandom(4,-4))
    NMAN I 3 A_FaceTarget
    NMAN G 3 A_MonsterRefire(80, "See")
    Goto RepeatFriendlyCheck
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    NMAN J 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		NMAN J 0 A_SpawnItemEx("Midas_Statue_Fatality", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		NMAN J 0 A_SpawnItemEx("Midas_Statue_Fatality", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		NMAN J 0 A_SpawnItemEx("Midas_Statue_Fatality", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		NMAN J 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		NMAN J 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		NMAN J 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

ACTOR RLNightmareMancubusPlasmaball : BFGBall
{
  Radius 8
  Height 6
  Speed 26
  Damage (18)
  DamageType "Plasma"
  Projectile
  +NOTIMEFREEZE
  +RANDOMIZE
  +THRUGHOST
  +BLOODSPLATTER
  RenderStyle Add
  Alpha 0.98
  Scale 0.25
  Decal "Scorch"
  SeeSound "nightmaremancubus/fire"
  DeathSound "weapons/plasmax"
  States
  {
  Spawn:
    NMBX ABCDEFGH 1 Bright A_SpawnItemEx("RLNightmareMancubusPlasmaballTrail", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    Goto Spawn
  Death:
    TNT1 A 0 A_SetScale (1)
    NMBZ EFGHI 2 Bright
    Stop
  }
}

ACTOR RLNightmareMancubusPlasmaball2 : RLNightmareMancubusPlasmaball
{
  SeeSound ""
}

ACTOR RLNightmareMancubusHomingPlasmaball : RLNightmareMancubusPlasmaball
{
  Radius 13
  Height 8
  Speed 18
  Damage (25)
  +SEEKERMISSILE
  Scale 0.65
  SeeSound "nightmaremancubus/homingfire"
  States
  {
  Spawn:
	TNT1 A 0
	TNT1 A 0 A_PlaySound("nightmaremancubus/homingloop", 7, 0.6, 1, 0.75)
	TNT1 A 0 A_SpawnItemEx("RLNightmareMancubusHomingPlasmaballTrail", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    NMBZ A 1 Bright A_SeekerMissile (2,2, SMF_PRECISE)
	TNT1 A 0 A_SpawnItemEx("RLNightmareMancubusHomingPlasmaballTrail", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    NMBZ B 1 Bright A_SeekerMissile (2,2, SMF_PRECISE)
	TNT1 A 0 A_SpawnItemEx("RLNightmareMancubusHomingPlasmaballTrail", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    NMBZ C 1 Bright A_SeekerMissile (2,2, SMF_PRECISE)
	TNT1 A 0 A_SpawnItemEx("RLNightmareMancubusHomingPlasmaballTrail", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    NMBZ D 1 Bright A_SeekerMissile (2,2, SMF_PRECISE)
	TNT1 A 0 A_SpawnItemEx("RLNightmareMancubusHomingPlasmaballTrail", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    NMBZ E 1 Bright A_SeekerMissile (2,2, SMF_PRECISE)
	TNT1 A 0 A_TakeInventory ("RLNightmareMancubusHomingTarget", 1, 0, AAPTR_TRACER)
	TNT1 A 0 A_GiveInventory ("RLNightmareMancubusHomingTarget", 1, AAPTR_TRACER)
    Goto Spawn
  Death:
	TNT1 A 0 A_TakeInventory ("RLNightmareMancubusHomingTarget", 1, 0, AAPTR_TRACER)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 3)
    TNT1 A 0 A_Quake (1, 15, 0, 512, "")
    TNT1 A 0 A_Quake (2, 4, 0, 128, "")
    TNT1 A 0 A_PlaySound ("nightmaremancubus/explode", 7, 1, 0, 0.6)
    TNT1 A 0 A_PlaySound("nightmaremancubus/explode", CHAN_ITEM, 0.05, 0, 0.15)
    TNT1 A 0 A_SetScale (0.3,1.2)
    TNT1 A 0 A_Explode (16, 96, 0)
    NMBX I 6 Bright
    NMBX J 5 Bright
    NMBX K 4 Bright
    NMBX L 3 Bright
    NMBX M 2 Bright
    NMBX N 1 Bright
    Stop
  }
}

ACTOR RLNightmareMancubusPlasmaballTrail
{   
   Radius 2
   Height 2
   Renderstyle Add
   Alpha 0.35
   Scale 0.25
   +NOINTERACTION
   +NOTIMEFREEZE
   States
   {
   Spawn:
      TNT1 A 0
      NMBZ FGHI 1 Bright
      Stop 
   }
}

ACTOR RLNightmareMancubusHomingPlasmaballTrail : RLNightmareMancubusPlasmaballTrail
{   
   Alpha 0.15
   Scale 0.55
   States
   {
   Spawn:
      TNT1 A 0
      TNT1 A 0 A_SetScale (frandom(0.54,0.56))
      RSHK ABCDEFGHIJKLMNOPQR 1 Bright
      Stop 
   }
}

ACTOR RLNightmareMancubusHomingTarget : Powerup
{
	Powerup.Duration 10
}

ACTOR RLSummonNightmareMancubusPlasmaball : RLNightmareMancubusPlasmaball
{
   +MTHRUSPECIES
}

ACTOR RLSummonNightmareMancubusPlasmaball2 : RLNightmareMancubusPlasmaball2
{
   +MTHRUSPECIES
}

ACTOR RLNightmareMancubusReborn : RLNightmareMancubus
{
  +LOOKALLAROUND
  +NOPAIN
  States
  {
  Spawn:
    TNT1 A 0 NoDelay A_JumpIfInventory("RLResurrectionComplete", 1, "SpawnNormal")
    NMAN RQPONMLK 5
    TNT1 A 0 A_ChangeFlag("NOPAIN", 0)
    TNT1 A 0 A_GiveInventory("RLResurrectionComplete", 1)
  SpawnNormal:
    NMAN CF 15 A_Look
    Loop
  }
}

ACTOR RLDRPGSummonedNightmareMancubus : RLNightmareMancubus
{
  -COUNTKILL
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCNightmareMancubus : RLNightmareMancubus
{
  +TOUCHY
  States
  {
  Missile:
    NMAN G 20
    NMAN U 8 Bright
    NMAN IG 3
    NMAN V 8 Bright
    NMAN IG 3
    NMAN H 10 Bright
    NMAN IG 5
    Goto See
  Melee:
    Stop
  Death:
    NMAN K 6
    NMAN L 6 A_Scream
    NMAN M 6 A_NoBlocking
    NMAN N 6
    NMAN OPQRS 6
    NMAN T -1 A_BossDeath
    Stop
  }
}
