
// NIGHTMARE REVENANT
//
ACTOR RLNightmareRevenant : RLRevenantBase 16530
{
  Health 420
  GibHealth -50
  BloodColor "11 11 11"
  
  MeleeThreshold 96
  
  DamageFactor "Fire", 0.75
  DamageFactor "Ice", 0.8
  
  SeeSound "nightmarerevenant/sight"
  ActiveSound "nightmarerevenant/active"
  PainSound "revenant/pain"
  DeathSound "nightmarerevenant/death"
  
  +JUMPDOWN
  
  Obituary "%o was taken down by a Nightmare Revenant."
  HitObituary "%o had %p skull cracked open by a Nightmare Revenant."
  Tag "Nightmare Revenant"
    //$category "MP Nightmare"
  
	// Guncaster compatibility
	DropItem "Ruby"
	DropItem "Ruby"
  States
  {
  Spawn:
    NREV BE Random(9,10) A_Look
    Loop
	
  See:
    TNT1 A 0 A_Jump(254, 2)
    TNT1 A 0 A_CheckSightOrRange(1024, "DistantScream")
  SeeLoop:
    NREV AABBCCDDEEFF 2 A_Chase
    Goto See
  DistantScream:
    TNT1 A 0 A_PlaySound("nightmarerevenant/far", 7, 1, 0, 0.2)
    Goto SeeLoop
	
  MeleeProper:
    TNT1 A 0 A_JumpIfInventory("RLNightmareRevenantArmToken", 1, "Melee2")
    NREV G 1 A_FaceTarget
    TNT1 A 0 A_PlaySound("skeleton/swing", CHAN_VOICE)
    NREV G 6 A_FaceTarget
    NREV H 6 A_FaceTarget
    TNT1 A 0 A_GiveInventory("RLNightmareRevenantArmToken", 1)
    NREV I 6 A_CustomBulletAttack (0, 0, 1, (6 * random(1, 10)), "RLEnemyNightmareRevenantBluntMeleePuff", 50, CBAF_NORANDOM | CBAF_AIMFACING)
//    NREV I 6 A_CustomMeleeAttack (6 * random(1, 10), "nightmarerevenant/melee", "", "Melee")
    Goto See
  Melee2:
    NREV R 1 A_FaceTarget
    TNT1 A 0 A_PlaySound("skeleton/swing", CHAN_VOICE)
    NREV R 6 A_FaceTarget
    NREV S 6 A_FaceTarget
    TNT1 A 0 A_TakeInventory("RLNightmareRevenantArmToken", 1)
    NREV T 6 A_CustomBulletAttack (0, 0, 1, (6 * random(1, 10)), "RLEnemyNightmareRevenantBluntMeleePuff", 50, CBAF_NORANDOM | CBAF_AIMFACING)
//    NREV T 6 A_CustomMeleeAttack (6 * random(1, 10), "nightmarerevenant/melee", "", "Melee")
    Goto See
	
  MissileProper:
    TNT1 A 0 A_JumpIfCloser(280, "MissileClose")
    NREV J 8 Bright A_FaceTarget
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    TNT1 A 0 A_CustomMissile("RLNightmareRevenantPlasmaSkull", 52, 14, -5)
    TNT1 A 0 A_CustomMissile("RLNightmareRevenantPlasmaSkull", 52, -14, 5)
    NREV J 2 Bright A_FaceTarget
    NREV K 20
    Goto See
	
  MissileClose:
    TNT1 A 0 A_JumpIfInventory("RLNightmareRevenantArmToken", 1, "MissileClose2")
    NREV G 1 A_FaceTarget
    TNT1 A 0 A_Recoil(-30)
    TNT1 A 0 A_PlaySound("skeleton/swing", CHAN_VOICE)
    NREV G 6
    NREV H 6
    TNT1 A 0 A_GiveInventory("RLNightmareRevenantArmToken", 1)
    TNT1 A 0 A_Stop
    NREV I 6 A_CustomMissile("RLNightmareRevenantDashPunch", 32, 0, 0, CMF_AIMDIRECTION)
    Goto See
  MissileClose2:
    NREV R 1 A_FaceTarget
    TNT1 A 0 A_Recoil(-30)
    TNT1 A 0 A_PlaySound("skeleton/swing", CHAN_VOICE)
    NREV R 6
    NREV S 6
    TNT1 A 0 A_TakeInventory("RLNightmareRevenantArmToken", 1)
    TNT1 A 0 A_Stop
    NREV T 6 A_CustomMissile("RLNightmareRevenantDashPunch", 32, 0, 0, CMF_AIMDIRECTION)
    Goto See
	
  SummonMissile:
    TNT1 A 0 A_CustomMissile("RLNightmareRevenantPlasmaSkull", 52, 14, -5)
    TNT1 A 0 A_CustomMissile("RLNightmareRevenantPlasmaSkull", 52, -14, 5)
    NREV J 2 Bright A_FaceTarget
    NREV K 20
    Goto See
	
  PainMain:
    NREV L 5
    NREV L 5 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLNightmareRevenantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    NREV LM 7
    NREV N 7 A_Scream
    NREV O 7 A_NoBlocking
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    NREV P 7
    NREV Q 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    NREV Q 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLNightmareRevenantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Death.Plasma:
    TNT1 A 0
    "####" "#" 0 A_Jump(256, "XDeath")
    Goto XDeath
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLNightmareRevenantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_GiveInventory("RLNightmareRevenantExplodedToken", 1)
    NREX A 10 Bright A_Playsound("nightmarerevenant/explode", 6)
    NREX BC 5 Bright
    NREX D 5 Bright
    TNT1 A 0 A_RadiusGive ("PowerRLCorruptionContextEffect", 192, RGF_CORPSES, 1) // Resurrects and corrupts nearby player bodies, beware
    NREX D 0 Bright A_CustomMissile("RLNightmareRevenantDeathWave",32,0)
    NREX EFGHIJ 5 Bright
    TNT1 A 0 A_NoBlocking
    NREX K 0
    "####" "#" 0 A_Jump(256, "XDeathEndNoRevive")
    Goto XDeathEndNoRevive
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLNightmareRevenantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    NREV LM 7
    NREV N 7 A_Scream
    NREV O 7 A_NoBlocking
    NREV P 7
    NREV Q 0
    "####" "#" 0 A_Jump(256, "XDeathEndNoRevive")
    Goto XDeathEndNoRevive
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    NREV Q 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    NREV QPONML 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    Goto RaiseContinue
	
  CrushDRLA:
    TNT1 A 0 A_SpawnItemEx("RLCrushedSmallBlack",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 O 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 O 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  XDeath.RigelBlast:
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 800, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLNightmareRevenantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMissileAttack:
    NREV U 8 Bright A_FaceTarget
    TNT1 A 0 A_CustomMissile("RLNightmareRevenantPlasmaSkull2", 52, 14, -15)
    TNT1 A 0 A_CustomMissile("RLNightmareRevenantPlasmaSkull2", 52, -14, 15)
    TNT1 A 0 A_CustomMissile("RLNightmareRevenantPlasmaSkull2", 52, 14, -10)
    TNT1 A 0 A_CustomMissile("RLNightmareRevenantPlasmaSkull2", 52, -14, 10)
    TNT1 A 0 A_CustomMissile("RLNightmareRevenantPlasmaSkull2", 52, 14, -5)
    TNT1 A 0 A_CustomMissile("RLNightmareRevenantPlasmaSkull2", 52, -14, 5)
    NREV U 2 Bright A_FaceTarget
    NREV K 20
    Goto See
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  Death.Tachyon:
  Death.Neutron:
  Death.Pulse:
  Death.EnergyExplosive:
  Death.AlienExplosive:
  Death.AlienEnergy:
  Death.VendettaEnergy:
    "####" "#" 0 A_Jump(256, "XDeath")
    Goto XDeath
	
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    NREV L 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		NREV L 0 A_SpawnItemEx("Midas_Statue_Agitation", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		NREV L 0 A_SpawnItemEx("Midas_Statue_Agitation", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		NREV L 0 A_SpawnItemEx("Midas_Statue_Agitation", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		NREV L 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		NREV L 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		NREV L 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

ACTOR RLNightmareRevenantPlasmaSkull : RevenantTracer
{
   +NOTIMEFREEZE
   +THRUGHOST
   +BLOODSPLATTER
   Speed 9
   Scale 0.7
   Decal "Scorch"
   Damage 6
   DamageType "Plasma"
   PainType "Nightmare"
   DeathType "Nightmare"
   SeeSound "nightmarerevenant/fire"
   DeathSound "nightmarerevenant/impact"
  States
  {
  Spawn:
    TNT1 A 0
    NREB A 1 Bright A_SeekerMissile(0, 1, SMF_PRECISE | SMF_CURSPEED)
    NREB A 1 Bright A_ScaleVelocity(1.05)
    NREB A 1 Bright A_SeekerMissile(0, 1, SMF_PRECISE | SMF_CURSPEED)
    NREB A 1 Bright A_ScaleVelocity(1.05)
    NREB B 1 Bright A_SeekerMissile(0, 1, SMF_PRECISE | SMF_CURSPEED)
    NREB B 1 Bright A_ScaleVelocity(1.05)
    NREB B 1 Bright A_SeekerMissile(0, 1, SMF_PRECISE | SMF_CURSPEED)
    NREB B 1 Bright A_ScaleVelocity(1.05)
    Goto Spawn
  Death:
    NREB CDEFGHIJKL 3 Bright
    Stop
  }
}

ACTOR RLNightmareRevenantPlasmaSkull2 : RLNightmareRevenantPlasmaSkull
{
   Speed 12
}

ACTOR RLSummonNightmareRevenantPlasmaSkull : RLNightmareRevenantPlasmaSkull
{
   +MTHRUSPECIES
}

ACTOR RLSummonNightmareRevenantPlasmaSkull2 : RLNightmareRevenantPlasmaSkull2
{
   +MTHRUSPECIES
}

ACTOR RLNightmareRevenantDashPunch : BaronBall
{
   +MTHRUSPECIES
   +THRUGHOST
   +NOTIMEFREEZE
   +BLOODSPLATTER
   SeeSound ""
   DeathSound "nightmarerevenant/melee"
   Speed 60
   FastSpeed 60
   DamageType "Melee"
   PainType "BluntMelee"
   DeathType "BluntMelee"
   Damage (6 * random(1, 10))
   States
   {
   Spawn:
    TNT1 A 2
    Stop
   Death:
    TNT1 A 1
    Stop
   }
}

ACTOR RLLordOfTheAbyssLunge : RLNightmareRevenantDashPunch
{
   DeathSound "baron/melee"
   DamageType "Melee"
   PainType "Melee"
   DeathType "Melee"
   Damage (20 * random(2, 5))
   States
   {
   Spawn:
    TNT1 A 2
    Stop
   Death:
    TNT1 A 1
    Stop
   }
}

actor RLNightmareRevenantDeathWave
{
    Radius 0
    Height 0
    Speed 0
    Scale 7.0
    +MTHRUSPECIES
    +THRUGHOST
	+BLOODLESSIMPACT
    PROJECTILE
    RENDERSTYLE Add 
    ALPHA 0.27
	DamageType "MindRape"
    States
    {
    Spawn:
    TNT1 A 0
    TNT1 A 0 A_CheckFlag ("NOTIMEFREEZE", "DoorpegAntiTime", AAPTR_TARGET)
    TNT1 A 0 A_CheckFlag ("NOTIMEFREEZE", "DoorpegTimeRestore", AAPTR_DEFAULT)
    Goto SpawnAura
  DoorpegAntiTime: // If the firing monster has blue aura in DoomRPG, the projectile is not frozen in time.
    TNT1 A 0 A_CheckFlag ("NOTIMEFREEZE", "SpawnAura", AAPTR_DEFAULT)
    TNT1 A 0 A_ChangeFlag ("NOTIMEFREEZE", 1)
    Goto SpawnAura
  DoorpegTimeRestore: // If it suddenly loses the aura, the projectiles will freeze in time in midflight.
    TNT1 A 0 A_ChangeFlag ("NOTIMEFREEZE", 0)
    Goto SpawnAura
  SpawnAura: // Projectile animation
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 3)
    TNT1 A 0 A_Quake(9,12,0,768,"")
    TNT1 A 0 A_Playsound("rlmonsters/horror", 5)
    NRXP ABCDEF 1 Bright A_Explode(32, 128)
    Stop
    }
}

Actor RLNightmareRevenantArmToken : Inventory
{
inventory.maxamount 1
}

Actor RLNightmareRevenantExplodedToken : Inventory
{
inventory.maxamount 1
}

ACTOR RLNightmareRevenantReborn : RLNightmareRevenant
{
  +LOOKALLAROUND
  +NOPAIN
  States
  {
  Spawn:
    TNT1 A 0 NoDelay A_JumpIfInventory("RLResurrectionComplete", 1, "SpawnNormal")
    NREV QPONML 5
    TNT1 A 0 A_ChangeFlag("NOPAIN", 0)
    TNT1 A 0 A_GiveInventory("RLResurrectionComplete", 1)
  SpawnNormal:
    NREV BE 10 A_Look
    Loop
  }
}

ACTOR RLDRPGSummonedNightmareRevenant : RLNightmareRevenant
{
  -COUNTKILL
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCNightmareRevenant : RLNightmareRevenant
{
  +TOUCHY
  States
  {
  See:
    NREV AABBCCDDEEFF 2
    Loop
  Melee:
    NREV GHIRST 4
    Goto See
  Missile:
    NREV U 10 Bright
    NREV K 20
    Goto See
  Death:
    NREV LM 7
    NREV N 7 A_Scream
    NREV O 7 A_NoBlocking
    NREV P 7
    NREV Q -1
    Stop
  }
}
