
// ARACHNOSENTINEL
//
ACTOR RLCyberneticArachnotron : RLArachnotronBase 16545
{
  Health 1100
  GibHealth -100
  Radius 58
  Height 56
  Speed 6
  Mass 3000
  
  MinMissileChance 1
  PainThreshold 22
  PainChance 70
  
  DamageFactor "Melee", 1.25
  DamageFactor "Ice", 0.7
  
  +QUICKTORETALIATE
  +MISSILEMORE
  +MISSILEEVENMORE
  +LOOKALLAROUND
  
  SeeSound "arachnosentinel/sight"
  PainSound "arachnotron/pain"
  DeathSound "arachnosentinel/death"
  
  Obituary "%o strolled into the Arachnosentinel's line of fire."
  Tag "Arachnosentinel"
    //$category "MP Technophobia"
  
	// Guncaster compatibility
	DropItem "Amber", 192
	DropItem "Emerald"
  States
  {
  Spawn:
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_StopSound(7)
  SpawnLoop:
    CARA A 8 A_Look
    Goto SpawnLoop
  ClearTargetWindDown:
    TNT1 A 0 A_ClearTarget
    TNT1 A 0 A_LookEx (LOF_NOSEESOUND, 0, 0, 0, 360, "See")
    Goto MissileEnd
	
  See:
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_PlaySound("baby/walk", CHAN_BODY, 1, 0, 1.25)
    CARA A 3 A_Chase ("", "Missile")
    TNT1 A 0 A_Jump (24, "Wary")
    CARA A 3 A_Chase ("", "Missile")
    TNT1 A 0 A_Jump (24, "Wary")
    CARA BBCC 3 A_Chase ("", "Missile")
    TNT1 A 0 A_PlaySound("baby/walk", CHAN_BODY, 1, 0, 1.25)
    CARA D 3 A_Chase ("", "Missile")
    TNT1 A 0 A_Jump (24, "Wary")
    CARA D 3 A_Chase ("", "Missile")
    TNT1 A 0 A_Jump (24, "Wary")
    CARA EEFF 3 A_Chase ("", "Missile")
    Goto See
  Wary:
    TNT1 A 0 A_Jump (256, "WaryFirst", "Wary2", "WaryNoTurn")
	Goto See
  WaryNoTurn:
    CARA A 1 A_JumpIfTargetInLOS ("MissileFast", 0, JLOSF_DEADNOJUMP)
    TNT1 A 0 A_Jump (254, "WaryNoTurn")
    Goto See
  WaryFirst:
    CARA A 1 A_SetAngle(angle + 1)
    TNT1 A 0 A_JumpIfTargetInLOS ("MissileFast", 0, JLOSF_DEADNOJUMP)
    TNT1 A 0 A_Jump (254, "WaryFirst")
    Goto WarySecond
  Wary2:
    CARA A 1 A_SetAngle(angle - 1)
    TNT1 A 0 A_JumpIfTargetInLOS ("MissileFast", 0, JLOSF_DEADNOJUMP)
    TNT1 A 0 A_Jump (254, "Wary2")
    Goto WarySecond
  WarySecond:
    TNT1 A 0 A_Jump (150, "See")
  Wary3:
    TNT1 A 0 A_Jump (128, "Wary4")
    CARA A 1 A_SetAngle(angle - 1)
    TNT1 A 0 A_JumpIfTargetInLOS ("MissileFast", 0, JLOSF_DEADNOJUMP)
    TNT1 A 0 A_Jump (254, "Wary3")
    Goto See
  Wary4:
    CARA A 1 A_SetAngle(angle + 1)
    TNT1 A 0 A_JumpIfTargetInLOS ("MissileFast", 0, JLOSF_DEADNOJUMP)
    TNT1 A 0 A_Jump (254, "Wary2")
    Goto See
	
  Overwatch:
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 5)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 4, AAPTR_TARGET)
    TNT1 A 0 A_JumpIf(CheckClass("Arachnotron", AAPTR_TARGET, TRUE), "ClearTarget")
    TNT1 A 0 A_JumpIf(CheckClass("Archvile", AAPTR_TARGET, TRUE), "ClearTarget")
    TNT1 A 0 A_JumpIf(CheckClass("SpiderMastermind", AAPTR_TARGET, TRUE), "ClearTarget")
    TNT1 A 0 A_PlaySound("rlmonsters/sentinelspin", 7, 1, 1, 1.2)
    TNT1 A 0 A_Chase ("", "MissileRestartFire", CHF_DONTMOVE)
    CARA Q 1 A_FaceTarget
    TNT1 A 0 A_Jump (1, "MissileEnd")
    Loop
  MissileRestartFire:
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 5)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 4, AAPTR_TARGET)
    TNT1 A 0 A_JumpIf(CheckClass("Arachnotron", AAPTR_TARGET, TRUE), "ClearTargetWindDown")
    TNT1 A 0 A_JumpIf(CheckClass("Archvile", AAPTR_TARGET, TRUE), "ClearTargetWindDown")
    TNT1 A 0 A_JumpIf(CheckClass("SpiderMastermind", AAPTR_TARGET, TRUE), "ClearTargetWindDown")
    CARA QQQ 1 A_FaceTarget
    TNT1 A 0 A_Jump (256, 4,8,12)
    CARA QQQQQQQQQQQQQQQQ 1 A_FaceTarget
    Goto RepeatFriendlyCheck
  MissileFast:
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 5)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 4, AAPTR_TARGET)
    TNT1 A 0 A_JumpIf(CheckClass("Arachnotron", AAPTR_TARGET, TRUE), "ClearTarget")
    TNT1 A 0 A_JumpIf(CheckClass("Archvile", AAPTR_TARGET, TRUE), "ClearTarget")
    TNT1 A 0 A_JumpIf(CheckClass("SpiderMastermind", AAPTR_TARGET, TRUE), "ClearTarget")
    TNT1 A 0 A_PlaySound("rlmonsters/sentinelwindup", 7)
    CARA Q 8 A_FaceTarget
    TNT1 A 0 A_GiveInventory ("RLArachnosentinelOverwatchToken", 1)
    TNT1 A 0 A_MonsterRefire(0, "Overwatch")
	Goto RepeatFriendlyCheck
	
  MissileProper:
    TNT1 A 0 A_PlaySound("rlmonsters/sentinelwindup", 7)
    CARA QQ 16 A_FaceTarget
    TNT1 A 0 A_GiveInventory ("RLArachnosentinelOverwatchToken", 1)
    TNT1 A 0 A_MonsterRefire(0, "Overwatch")
  RepeatProper:
  MissileFire:
    TNT1 A 0 A_PlaySound("rlmonsters/sentinelspin", 7, 1, 1, 1.2)
    TNT1 A 0 A_JumpIfInventory ("RLArachnosentinelStateCounter", 1, "MissileAlt")
    TNT1 A 0 A_GiveInventory ("RLArachnosentinelStateCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/bulletstormchaingun", CHAN_WEAPON, 1, 0, 0.8)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    CARA G 3 Bright A_CustomBulletAttack (30, 5, 1, random(1,5) * 3, "RLEnemyBulletPuffNoInfight", 0, CBAF_NORANDOM)
    CARA Q 1
    TNT1 A 0 A_MonsterRefire(164, "Overwatch")
    Goto RepeatFriendlyCheck
  MissileAlt:
    TNT1 A 0 A_TakeInventory ("RLArachnosentinelStateCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/bulletstormchaingun", CHAN_WEAPON, 1, 0, 0.8)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissileAlt") // Friendly monsters do not harm you
    CARA H 3 Bright A_CustomBulletAttack (30, 5, 1, random(1,5) * 3, "RLEnemyBulletPuffNoInfight", 0, CBAF_NORANDOM)
    CARA Q 1
    TNT1 A 0 A_MonsterRefire(164, "Overwatch")
    Goto RepeatFriendlyCheck
  MissileEnd:
    TNT1 A 0 A_TakeInventory ("RLArachnosentinelOverwatchToken", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/sentinelwinddown", 7)
    CARA Q 18
    Goto See
	
  SummonMissile:
    CARA G 3 Bright A_CustomBulletAttack (6, 2, 1, random(1,3) * 7, "RLEnemyBulletPuffNoInfight", 0, CBAF_NORANDOM)
    CARA Q 1
    TNT1 A 0 A_MonsterRefire(164, "Overwatch")
    Goto MissileFire
  SummonMissileAlt:
    CARA H 3 Bright A_CustomBulletAttack (6, 2, 1, random(1,3) * 7, "RLEnemyBulletPuffNoInfight", 0, CBAF_NORANDOM)
    CARA Q 1
    TNT1 A 0 A_MonsterRefire(164, "Overwatch")
    Goto MissileFire
	
  PainMain:
    CARA I 3
    CARA I 3 A_Pain
    TNT1 A 0 A_JumpIfInventory ("RLArachnosentinelOverwatchToken", 1, "MissileRestartFire")
    TNT1 A 0 A_StopSound(7)
    Goto See
	
  XDeathMain:
  DeathMain:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLCyberneticArachnotronKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLReducedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_StopSound(7)
    CARA J 20 A_Scream
    CARA K 7 A_NoBlocking
    CARA LMNO 7
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    CARA P 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLCyberneticArachnotronKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_StopSound(7)
    CARA J 20 A_Scream
    CARA K 7 A_NoBlocking
    CARA LMNO 7
    CARA P 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    CARA P 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLCyberneticArachnotronKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    CARA P 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    CARA PONMLKJ 5
    Goto See+1
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    Goto RaiseContinue
	
  CrushDRLA:
    TNT1 A 30 A_SpawnItemEx("RLCrushedMedium",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  ArsenalMissileCheck:
	"####" "#" 0 A_JumpIf(CallACS("DRLA_specialstarts") == 2, "Duke2LaserAttack")
    "####" "#" 0 A_JumpIfInventory("DRPGShadowAuraToken", 1, "ShadowAuraMissileAttack") // DRPG Shadow Aura
    "####" "#" 0 A_JumpIfInventory("LDLegendaryMonsterTransformed", 1, "LegendaryMissileAttack") // LegenDoom legendary monster
    "####" "#" 0 A_Jump(256, "MissileProper")
	Goto MissileProper
  ArsenalRepeatCheck:
	"####" "#" 0 A_JumpIf(CallACS("DRLA_specialstarts") == 2, "Duke2LaserAttack")
    "####" "#" 0 A_JumpIfInventory("DRPGShadowAuraToken", 1, "ShadowAuraRepeatAttack") // DRPG Shadow Aura
    "####" "#" 0 A_JumpIfInventory("LDLegendaryMonsterTransformed", 1, "LegendaryRepeatAttack") // LegenDoom legendary monster
    "####" "#" 0 A_Jump(256, "RepeatProper")
	Goto RepeatProper
	
  Pain.RigelBlast:
    TNT1 A 0 A_TakeInventory ("RLArachnosentinelOverwatchToken", 1)
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 M 2 Bright
    Goto See
  Pain.NeuralStun:
    TNT1 A 0 A_TakeInventory ("RLArachnosentinelOverwatchToken", 1)
    TNT1 A 0 A_StopSound(7)
    D2F1 M 2 Bright
    Goto See
  Pain.CyberDisruptor:
    TNT1 A 0 A_TakeInventory ("RLArachnosentinelOverwatchToken", 1)
    TNT1 A 0 A_StopSound(7)
    Goto Pain.LightningBlue
  Pain.CyberDisruptor:
    TNT1 A 0
    Goto Pain.LightningBlue
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 2500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLCyberneticArachnotronKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 2500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLCyberneticArachnotronKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMissileAttack:
    TNT1 A 0 A_PlaySound("rlmonsters/sentinelwindup", 7)
    CARA QQ 16 A_FaceTarget
    TNT1 A 0 A_GiveInventory ("RLArachnosentinelOverwatchToken", 1)
    TNT1 A 0 A_MonsterRefire(0, "Overwatch")
  ShadowAuraRepeatAttack:
    TNT1 A 0 A_PlaySound("rlmonsters/sentinelspin", 7, 1, 1, 1.2)
    TNT1 A 0 A_JumpIfInventory ("RLArachnosentinelStateCounter", 1, "ShadowAuraMissileAlt")
    TNT1 A 0 A_GiveInventory ("RLArachnosentinelStateCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/rcp90", CHAN_WEAPON, 1, 0, 0.8)
    CARA G 1 Bright A_CustomBulletAttack (30, 5, 1, random(1,5) * 3, "RLEnemyBulletPuffNoInfight", 0, CBAF_NORANDOM)
    CARA Q 1
    TNT1 A 0 A_MonsterRefire(240, "Overwatch")
    Goto RepeatFriendlyCheck
  ShadowAuraMissileAlt:
    TNT1 A 0 A_TakeInventory ("RLArachnosentinelStateCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/rcp90", CHAN_WEAPON, 1, 0, 0.8)
    CARA H 1 Bright A_CustomBulletAttack (30, 5, 1, random(1,5) * 3, "RLEnemyBulletPuffNoInfight", 0, CBAF_NORANDOM)
    CARA Q 1
    TNT1 A 0 A_MonsterRefire(240, "Overwatch")
    Goto RepeatFriendlyCheck

//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    CARA I 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		CARA I 0 A_SpawnItemEx("Midas_Statue_Arach", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		CARA I 0 A_SpawnItemEx("Midas_Statue_Arach", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		CARA I 0 A_SpawnItemEx("Midas_Statue_Arach", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		CARA I 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		CARA I 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		CARA I 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

Actor RLArachnosentinelOverwatchToken : Inventory
{
inventory.maxamount 1
}

Actor RLArachnosentinelStateCounter : Inventory
{
inventory.maxamount 1
}

ACTOR RLCyberneticArachnotronGuard : RLCyberneticArachnotron
{
  States
  {
  See:
    TNT1 A 0 A_JumpIfInventory ("DRPGDRLASummonedMonsterToken", 1, 2)
    TNT1 A 0 A_JumpIfInTargetInventory ("RLSpiderMindToken", 1, "ClearTarget")
    TNT1 A 0 A_StopSound(7)
    Goto Missile
  Overwatch:
    TNT1 A 0 A_JumpIfInventory ("DRPGDRLASummonedMonsterToken", 1, 2)
    TNT1 A 0 A_JumpIfInTargetInventory ("RLSpiderMindToken", 1, "ClearTarget")
    TNT1 A 0 A_PlaySound("rlmonsters/sentinelspin", 7, 1, 1, 1.2)
    TNT1 A 0 A_Chase ("", "MissileRestartFire", CHF_DONTMOVE)
    CARA Q 1 A_FaceTarget
    Loop
  MissileRestartFire:
    TNT1 A 0 A_JumpIfInventory ("DRPGDRLASummonedMonsterToken", 1, 2)
    TNT1 A 0 A_JumpIfInTargetInventory ("RLSpiderMindToken", 1, "ClearTargetWindDown")
    CARA QQQ 1 A_FaceTarget
    TNT1 A 0 A_Jump (256, 4,8,12)
    CARA QQQQQQQQQQQQQQQQ 1 A_FaceTarget
    Goto MissileFire
  Missile:
    TNT1 A 0 A_JumpIfInventory ("DRPGDRLASummonedMonsterToken", 1, 2)
    TNT1 A 0 A_JumpIfInTargetInventory ("RLSpiderMindToken", 1, "ClearTarget")
    TNT1 A 0 A_PlaySound("rlmonsters/sentinelwindup", 7)
    CARA QQ 16 A_FaceTarget
    TNT1 A 0 A_GiveInventory ("RLArachnosentinelOverwatchToken", 1)
    TNT1 A 0 A_MonsterRefire(0, "Overwatch")
	Goto MissileFire
  }
}

ACTOR RLCyberneticArachnotronReborn : RLCyberneticArachnotron
{
  +LOOKALLAROUND
  +NOPAIN
  States
  {
  Spawn:
    TNT1 A 0 NoDelay A_JumpIfInventory("RLResurrectionComplete", 1, "SpawnNormal")
    CARA PONMLKJ 5
    TNT1 A 0 A_ChangeFlag("NOPAIN", 0)
    TNT1 A 0 A_GiveInventory("RLResurrectionComplete", 1)
  SpawnNormal:
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_TakeInventory ("RLNightmareArachnotronChargeToken", 1)
    CARA ACDF 10 A_Look
    Loop
  }
}

ACTOR RLDRPGSummonedCyberneticArachnotron : RLCyberneticArachnotron
{
  -COUNTKILL
  +AVOIDMELEE
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCCyberneticArachnotron : RLCyberneticArachnotron
{
  +TOUCHY
  States
  {
  See:
    CARA AABBCC 3
    CARA DDEEFF 3
    Goto See
  Missile:
    CARA Q 4
    CARA G 3 Bright
    CARA Q 1
    CARA H 3 Bright
    CARA Q 1
    Goto Missile+1
  Melee:
    Stop
  Death:
    CARA J 20 A_Scream
    CARA K 7 A_NoBlocking
    CARA LMNO 7
    CARA P -1 A_BossDeath
    Stop
  }
}
