
// CYBRUISER
//
ACTOR RLCyberneticHellKnight : RLHellKnightBase 16543
{
  Health 1000
  GibHealth -150
  Mass 2000
  BloodType "RLNashGore_CyberBlood", "RLMNullActor", "RLNashGore_SlashBlood"
  Bloodcolor "DarkGreen"
  
  PainChance 50
  
  +MISSILEMORE
  
  SeeSound "cybruiser/sight" 
  PainSound "technolord/pain" 
  ActiveSound "technolord/active" 
  DeathSound "cybruiser/death"
  
  Obituary "%o was blown away by a Cybruiser."
  HitObituary "%o was smashed by a Cybruiser."
  Tag "Cybruiser"
    //$category "MP Technophobia"
  
	// Guncaster compatibility
	DropItem "Ruby"
	DropItem "Amber"
	DropItem "Amber"
  States
  {
  Spawn: 
    CKNI BD Random(9,10) A_Look 
    Goto Spawn
	
  See:
    TNT1 A 0 A_Playsound("cybruiser/walk", 7, 1, 0, 1.25)
    CKNI AA 3 A_Chase
    CKNI BB 3 A_Chase
    TNT1 A 0 A_Playsound("cybruiser/walk", 7, 1, 0, 1.25)
    CKNI CC 3 A_Chase 
    CKNI DD 3 A_Chase
    Loop
	
  MissileHatredOnUniqueEffect: // [incoherent tantrum sounds]
    "####" "#" 0 A_PlaySound ("cybruiser/sight", CHAN_VOICE)
    "####" "#" 0 A_Jump (256, "MissileHatredOnUniqueDone")
	Goto MissileHatredOnUniqueDone
  MeleeHatredOnUniqueEffect: // [incoherent tantrum sounds]
    "####" "#" 0 A_PlaySound ("cybruiser/sight", CHAN_VOICE)
    "####" "#" 0 A_Jump (256, "MeleeHatredOnUniqueDone")
	Goto MeleeHatredOnUniqueDone
	
  MissileProper:
    CKNI EE 8 A_FaceTarget 
    TNT1 A 0 A_FaceTarget
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    CKNI F 12 Bright A_CustomMissile("RLBruiserMissile",38,15,0,0)
    CKNI E 12 A_FaceTarget
    TNT1 A 0 A_FaceTarget
    CKNI F 12 Bright A_CustomMissile("RLBruiserMissile",38,15,0,0)
    CKNI E 12 A_FaceTarget
    TNT1 A 0 A_FaceTarget
    CKNI F 12 Bright A_CustomMissile("RLBruiserMissile",38,15,0,0)
    CKNI E 6 A_FaceTarget
    Goto See
	
  SummonMissile:
    CKNI F 12 Bright A_CustomMissile("RLSummonBruiserMissile",38,15,0,0)
    CKNI E 12 A_FaceTarget
    TNT1 A 0 A_FaceTarget
    CKNI F 12 Bright A_CustomMissile("RLSummonBruiserMissile",38,15,0,0)
    CKNI E 12 A_FaceTarget
    TNT1 A 0 A_FaceTarget
    CKNI F 12 Bright A_CustomMissile("RLSummonBruiserMissile",38,15,0,0)
    CKNI E 6 A_FaceTarget
    Goto See
	
  MeleeProper:
    CKNI GH 8 A_FaceTarget
    CKNI I 8 A_CustomMeleeAttack (8 * random(1, 8), "baron/melee", "rlmonsters/meleeswing", "Melee")
    Goto See
	
  PainMain: 
    CKNI J 2 
    CKNI J 2 A_Pain 
    Goto See

  XDeathMain:
  DeathMain: 
    TNT1 A 0 A_GiveInventory ("RLCyberneticHellKnightKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    CKNI K 6 Bright A_Scream
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 3)
    TNT1 A 0 A_Quake(1, 18, 0, 512, "")
    TNT1 A 0 A_Quake(5, 12, 0, 256, "")
    TNT1 A 0 A_SpawnItemEx ("RLReducedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    CKNI LMN 6 Bright
    CKNI O 6 Bright A_NoBlocking
    CKNI QR 6 Bright
    CKNI S 6
    CKNI T 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLCyberneticHellKnightKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    CKNI K 6 Bright A_Scream
    CKNI LMN 6 Bright
    CKNI O 6 Bright A_NoBlocking
    CKNI QR 6 Bright
    CKNI S 6
    CKNI T 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    CKNI T 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLCyberneticHellKnightKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    CKNI T 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    CKNI SRQONML 8
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    Goto RaiseContinue
	
  CrushDRLA:
    TNT1 A 30 A_SpawnItemEx("RLCrushedMediumGreen",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F2 K 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F2 K 2 Bright
    Goto See
  Pain.CyberDisruptor:
    TNT1 A 0
    Goto Pain.LightningBlue
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLCyberneticHellKnightKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLCyberneticHellKnightKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2Gibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMissileAttack:
    CKNI EE 8 A_FaceTarget 
    TNT1 A 0 A_FaceTarget
    CKNI F 6 Bright A_CustomMissile("RLCyberdemonMkIIDrunkRocket", 38, 15)
    CKNI E 3 A_FaceTarget
    TNT1 A 0 A_FaceTarget
    CKNI F 6 Bright A_CustomMissile("RLCyberdemonMkIIDrunkRocket", 38, 15)
    CKNI E 3 A_FaceTarget
    TNT1 A 0 A_FaceTarget
    CKNI F 6 Bright A_CustomMissile("RLCyberdemonMkIIDrunkRocket", 38, 15)
    CKNI E 3 A_FaceTarget
    TNT1 A 0 A_FaceTarget
    CKNI F 6 Bright A_CustomMissile("RLCyberdemonMkIIDrunkRocket", 38, 15)
    CKNI E 3 A_FaceTarget
    TNT1 A 0 A_FaceTarget
    CKNI F 6 Bright A_CustomMissile("RLCyberdemonMkIIDrunkRocket", 38, 15)
    CKNI E 3 A_FaceTarget
    TNT1 A 0 A_FaceTarget
    CKNI F 6 Bright A_CustomMissile("RLCyberdemonMkIIDrunkRocket", 38, 15)
    CKNI E 6 A_FaceTarget
    Goto See
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    CKNI J 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		CKNI J 0 A_SpawnItemEx("Midas_Statue_Hellknight", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		CKNI J 0 A_SpawnItemEx("Midas_Statue_Hellknight", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		CKNI J 0 A_SpawnItemEx("Midas_Statue_Hellknight", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		CKNI J 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		CKNI J 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		CKNI J 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

Actor RLBruiserMissile
{
  Radius 8
  Height 12
  Speed 14
  Damage 10
  DamageType "Fire"
  PainType "Explosion"
  DeathType "Explosion"
  Scale 1.0
  Projectile
  RenderStyle Normal
  +NOTIMEFREEZE
  +THRUGHOST
  +BLOODSPLATTER
  SeeSound "cybruiser/fire"
  DeathSound "rlmonsters/smallexp"
  Decal "Scorch"
  States
  {
  Spawn:
    FBRS A 1 Bright
    FBRS A 1 Bright A_SpawnItemEx("RLBruiserTrail",0,0,0,0,0,0,0,128)
    Goto Spawn
  Death:
    TNT1 A 0 A_SetTranslucent(0.67,1)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 3)
    TNT1 A 0 A_Quake(1, 12, 0, 256, "")
    TNT1 A 0 A_Quake(4, 6, 0, 128, "")
    BAL3 C 6 Bright
    BAL3 D 6 Bright A_Explode(32,64,0)
    BAL3 E 6 Bright
    Stop
  }
}

Actor RLTechnoLordMissile : RLBruiserMissile
{
  Speed 30
}

Actor RLSummonBruiserMissile : RLBruiserMissile
{
  +MTHRUSPECIES
}

Actor RLBruiserTrail
{   
  Radius 3
  Height 3
  RenderStyle Translucent
  Alpha 0.67
  Projectile
  +NOTIMEFREEZE
  States
  {
  Spawn:
    TNT1 A 3 Bright
    PUFF ABCD 4 BRIGHT
    Stop 
  }
}

ACTOR RLCyberneticHellKnightReborn : RLCyberneticHellKnight
{
  +LOOKALLAROUND
  +NOPAIN
  States
  {
  Spawn:
    TNT1 A 0 NoDelay A_JumpIfInventory("RLResurrectionComplete", 1, "SpawnNormal")
    CKNI SQRONML 8
    TNT1 A 0 A_ChangeFlag("NOPAIN", 0)
    TNT1 A 0 A_GiveInventory("RLResurrectionComplete", 1)
  SpawnNormal:
    CKNI BD 10 A_Look 
    Loop
  }
}

ACTOR RLDRPGSummonedCyberneticHellKnight : RLCyberneticHellKnight
{
  -COUNTKILL
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCCyberneticHellKnight : RLCyberneticHellKnight
{
  +TOUCHY
  States
  {
  Spawn: 
    CKNI BD 10 A_Look 
    Loop 
  See:
    CKNI AABBCCDD 3
    Loop
  Missile:
    CKNI E 8
    CKNI F 12 Bright
    CKNI E 12
    CKNI F 12 Bright
    CKNI E 12
    CKNI F 12 Bright
    Goto See
  Melee:
    CKNI GH 8 A_FaceTarget
    CKNI I 8 A_MeleeAttack
    Goto See
  Death: 
    CKNI K 6 Bright A_Scream
    CKNI LMN 6 Bright
    CKNI O 6 Bright A_NoBlocking
    CKNI QR 6 Bright
    CKNI S 6
    CKNI T -1
    Stop
  }
}
