
// CYBER-IMP
//
ACTOR RLCyberneticImp : RLImpBase 16538
{
  Health 95
  GibHealth -60
  BloodType "RLNashGore_CyberBlood", "RLMNullActor", "RLNashGore_SlashBlood"
  
  MeleeRange 48
  
  DamageFactor "Fire", 0.75
  
  SeeSound "cyberimp/sight"
  PainSound "cyberimp/pain"
  DeathSound "cyberimp/death"
  ActiveSound "cyberimp/active"
  
  Obituary "The Cyber-Imp showed %o his new arm."
  HitObituary "%o was zapped by a Cyber-Imp."
  Tag "Cyber-Imp"
    //$category "MP Technophobia"
  
	// Guncaster compatibility
	DropItem "Dosh5", 192
	DropItem "Dosh35"
  States
  {
  Spawn:
    CIMP AB Random(9,10) A_Look
    Loop
	
  See:
    CIMP AABBCCDD 3 A_Chase
    Loop
	
  MeleeProper:
    CIMP EF 8 A_FaceTarget
  MeleeZappin:
    CIMP G 1 Bright A_CustomMeleeAttack (1 * random(1, 3), "techvile/smallzap", "", "Plasma")
    CIMP F 1
    TNT1 A 0 A_Chase("MeleeZappin", "", CHF_DONTMOVE | CHF_NOPLAYACTIVE)
    Goto See
	
  MissileProper:
    CIMP EF 8 A_FaceTarget
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    CIMP G 6 Bright A_Custommissile("RLCyberImpPlasmaBall",36,4)
    Goto See
	
  SummonMissile:
    CIMP G 6 Bright A_Custommissile("RLSummonCyberImpPlasmaBall",36,4)
    Goto See
	
  PainMain:
    CIMP H 2
    CIMP H 2 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLCyberneticImpKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    CIMP I 8
    CIMP J 8 A_Scream
    CIMP K 6
    CIMP L 6 A_NoBlocking
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    CIMP M 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    CIMP M 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLCyberneticImpKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLCyberImpArm", 0,-10,32, VelX,VelY-4,VelZ, 270, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    CIMP N 5// A_CustomMissile("RLCyberImpArm",32,-10,270)
    CIMP O 5 A_XScream
    CIMP P 5
    CIMP Q 5 A_NoBlocking
    CIMP R 5
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    CIMP ST 5
    CIMP U 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLCyberneticImpKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    CIMP N 5
    CIMP O 5 A_XScream
    CIMP P 5
    CIMP Q 5 A_NoBlocking
    CIMP R 5
    CIMP ST 5
    CIMP U 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLCyberneticImpKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    CIMP M 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
  RaiseContinue:
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    CIMP MLKJI 8
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    Goto RaiseContinue
	
  CrushDRLA:
    TNT1 A 30 A_SpawnItemEx("RLCrushedSmall",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F2 H 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F2 H 2 Bright
    Goto See
  Pain.CyberDisruptor:
    TNT1 A 0
    Goto Pain.LightningBlue
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLCyberneticImpKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLCyberneticImpKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMissileAttack:
    CIMP EF 8 A_FaceTarget
    CIMP G 1 Bright A_Custommissile("RLFormerCaptainBurstPlasmaBall",36,4)
    CIMP G 1
    CIMP G 1 Bright A_Custommissile("RLFormerCaptainBurstPlasmaBall",36,4)
    CIMP G 1
    CIMP G 1 Bright A_Custommissile("RLFormerCaptainBurstPlasmaBall",36,4)
    CIMP GFEEEFG 2
    CIMP G 1 Bright A_Custommissile("RLFormerCaptainBurstPlasmaBall",36,4)
    CIMP G 1
    CIMP G 1 Bright A_Custommissile("RLFormerCaptainBurstPlasmaBall",36,4)
    CIMP G 1
    CIMP G 1 Bright A_Custommissile("RLFormerCaptainBurstPlasmaBall",36,4)
    CIMP G 1
    Goto See
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MinorManaPod",-1,54)
    CIMP H 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		CIMP H 0 A_SpawnItemEx("Midas_Statue_Pimp", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		CIMP H 0 A_SpawnItemEx("Midas_Statue_Pimp", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		CIMP H 0 A_SpawnItemEx("Midas_Statue_Pimp", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		CIMP H 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		CIMP H 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		CIMP H 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

ACTOR RLCyberImpPlasmaBall : PlasmaBall
{
   +NOTIMEFREEZE
   +THRUGHOST
   +BLOODSPLATTER
   Decal "PlasmaScorch"
   DamageType "Plasma"
   Damage 4
   Speed 18
  States
  {
  Spawn:
    PLSS AB 6 Bright
    Goto Spawn
//  Death:
//    PLSE ABCDE 4 Bright
//    Stop
  }
}

ACTOR RLSummonCyberImpPlasmaBall : RLCyberImpPlasmaBall
{
   +MTHRUSPECIES
}

ACTOR RLCyberneticImpReborn : RLCyberneticImp
{
  +LOOKALLAROUND
  +NOPAIN
  States
  {
  Spawn:
    TNT1 A 0 NoDelay A_JumpIfInventory("RLResurrectionComplete", 1, "SpawnNormal")
    CIMP MLKJI 8
    TNT1 A 0 A_ChangeFlag("NOPAIN", 0)
    TNT1 A 0 A_GiveInventory("RLResurrectionComplete", 1)
  SpawnNormal:
    CIMP AB 10 A_Look
    Loop
  }
}

ACTOR RLDRPGSummonedCyberneticImp : RLCyberneticImp
{
  -COUNTKILL
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCCyberneticImp : RLCyberneticImp
{
  +TOUCHY
  States
  {
  Melee:
    CIMP EF 8
    CIMP G 1 Bright
    CIMP F 1
    CIMP G 1 Bright
    CIMP F 1
    CIMP G 1 Bright
    CIMP F 1
    CIMP G 1 Bright
    CIMP F 1
    CIMP E 8
    Goto See
  Missile:
    CIMP EF 8
    CIMP G 6 Bright
    Goto See
  Death:
    CIMP I 8
    CIMP J 8 A_Scream
    CIMP K 6
    CIMP L 6 A_NoBlocking
    CIMP M -1
    Stop
  }
}
