
// VOLACUBUS
//
ACTOR RLCyberneticMancubus : RLMancubusBase 16548
{
  Health 600
  GibHealth -100
  Radius 44
  Height 60
  Speed 16
  
  DamageFactor "Fire", 1.2
  DamageFactor "Ice", 0.7
  
  DeathSound "volacubus/death1"
  
  +NOGRAVITY
  +FLOAT
  +FLOATBOB
  +MISSILEMORE
  +DONTCORPSE
  -FLOORCLIP
  
  Obituary "%o was not expecting a visit from a Volacubus."
  Tag "Volacubus"
    //$category "MP Technophobia"
  
	// Guncaster compatibility
	DropItem "Amber"
	DropItem "Emerald"
  States
  {
  Spawn:
    TNT1 A 0 A_PlaySound("volacubus/jetloop", 7, 1)
    CMAN ABABABABCDCDCDCD Random(3,4) A_Look
    Loop
	
  See:
    TNT1 A 0 A_PlaySound("volacubus/jetloop", 7, 1)
    CMAN ABABABABCDCDCDCD Random(3,4) A_Chase ("", "Missile")
    Loop
	
  MissileProper:
    TNT1 A 0 A_PlaySound("volacubus/jetloop", 7, 1)
    TNT1 A 0 A_PlaySound("fatso/raiseguns", CHAN_VOICE)
    CMAN F 20 A_FaceTarget
  RepeatProper:
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    TNT1 A 0 A_CustomMissile("RLVolacbusPlasmaBall", 34, 32, random(-7,4))
    CMAN H 5 Bright A_CustomMissile("RLVolacbusPlasmaBall", 34, -32, random(-4,7))
    CMAN I 5
    CMAN FG 5 A_FaceTarget
    TNT1 A 0 A_CustomMissile("RLVolacbusPlasmaBall", 34, 32, random(-7,4))
    CMAN H 5 Bright A_CustomMissile("RLVolacbusPlasmaBall", 34, -32, random(-4,7))
    CMAN I 5
    CMAN FG 5 A_FaceTarget
    TNT1 A 0 A_CustomMissile("RLVolacbusPlasmaBall", 34, 32, random(-7,4))
    CMAN H 5 Bright A_CustomMissile("RLVolacbusPlasmaBall", 34, -32, random(-4,7))
    CMAN I 5
    CMAN FG 5
    TNT1 A 0 A_MonsterRefire(128, "See")
    TNT1 A 0 A_Jump(64, 1)
    Goto See
    TNT1 A 0
    Goto RepeatFriendlyCheck
	
  SummonMissile:
    TNT1 A 0 A_CustomMissile("RLSummonVolacbusPlasmaBall", 34, 32, random(-7,4))
    CMAN H 5 Bright A_CustomMissile("RLSummonVolacbusPlasmaBall", 34, -32, random(-4,7))
    CMAN I 5
    CMAN FG 5 A_FaceTarget
    TNT1 A 0 A_CustomMissile("RLSummonVolacbusPlasmaBall", 34, 32, random(-7,4))
    CMAN H 5 Bright A_CustomMissile("RLSummonVolacbusPlasmaBall", 34, -32, random(-4,7))
    CMAN I 5
    CMAN FG 5 A_FaceTarget
    TNT1 A 0 A_CustomMissile("RLSummonVolacbusPlasmaBall", 34, 32, random(-7,4))
    CMAN H 5 Bright A_CustomMissile("RLSummonVolacbusPlasmaBall", 34, -32, random(-4,7))
    CMAN I 5
    CMAN FG 5
    Goto See
	
  PainMain:
    CMAN J 3
    CMAN J 3 A_Pain
    Goto See
	
  XDeathMain:
  DeathMain:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLCyberneticMancubusKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_ChangeFlag("FLOATBOB", 0)
    CMAN K 6
    CMAN L 6 A_Scream
    CMAN M 6 A_NoBlocking
    TNT1 A 0 A_PlaySound("volacubus/jetoff", 7)
    CMAN N 6
    TNT1 A 0 A_ChangeFlag ("CORPSE", 1)
    TNT1 A 0 A_ChangeFlag ("DONTCORPSE", 0)
  DeathFall:
    CMAN N 1
	Loop
  Crash:
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    TNT1 A 0 A_PlaySound("volacubus/death2", CHAN_VOICE)
    CMAN OPQRS 6
    TNT1 A 0 A_SetFloorClip
    CMAN T 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLCyberneticMancubusKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_ChangeFlag("FLOATBOB", 0)
    CMAN K 6
    CMAN L 6 A_Scream
    CMAN M 6 A_NoBlocking
    CMAN N 6
    TNT1 A 0 A_ChangeFlag ("CORPSE", 1)
    TNT1 A 0 A_ChangeFlag ("DONTCORPSE", 0)
    CMAN OPQRS 6
    TNT1 A 0 A_SetFloorClip
    CMAN T 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    TNT1 A 0 A_ChangeFlag("FLOATBOB", 0)
    TNT1 A 0 A_BossDeath
    CMAN T 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLCyberneticMancubusKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    CMAN T 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_UnSetFloorClip
    TNT1 A 0 A_ChangeFlag ("CORPSE", 0)
    TNT1 A 0 A_ChangeFlag ("DONTCORPSE", 1)
    TNT1 A 0 A_PlaySound("volacubus/jeton", 7)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag("FLOATBOB", 1)
    CMAN RQPONMLK 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    Goto RaiseContinue
	
  CrushDRLA:
    TNT1 A 30 A_SpawnItemEx("RLCrushedMedium",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_ChangeFlag("FLOATBOB", 0)
    "####" "#" 0 A_ChangeFlag ("CORPSE", 1)
    "####" "#" 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F2 N 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F2 N 2 Bright
    Goto See
  Pain.CyberDisruptor:
    TNT1 A 0
    Goto Pain.LightningBlue
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1200, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLCyberneticMancubusKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2AdvancedEnemyExplosions", 0,0,32, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1200, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLCyberneticMancubusKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2AdvancedEnemyExplosions", 0,0,32, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================

//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    CMAN J 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		CMAN J 0 A_SpawnItemEx("Midas_Statue_Fatality", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		CMAN J 0 A_SpawnItemEx("Midas_Statue_Fatality", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		CMAN J 0 A_SpawnItemEx("Midas_Statue_Fatality", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		CMAN J 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		CMAN J 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		CMAN J 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

ACTOR RLVolacbusPlasmaBall : BFGBall
{
  Radius 13
  Height 8
  Speed 25
  Damage (random(2,4) * 10)
  DamageType "Plasma"
  Projectile
  +RANDOMIZE
  +THRUGHOST
  +NOTIMEFREEZE
  +BLOODSPLATTER
  RenderStyle Add
  Alpha 0.85
  Decal "EnemyBlueBFGLightning"
  SeeSound "volacubus/fire"
  DeathSound "weapons/bfgx"
  States
  {
  Spawn:
    WPLZ AB 4 Bright
    Goto Spawn
  Death:
    WPLZ CDE 4 Bright
    Stop
  }
}

ACTOR RLSummonVolacbusPlasmaBall : RLVolacbusPlasmaBall
{
  +MTHRUSPECIES
}

ACTOR RLCyberneticMancubusReborn : RLCyberneticMancubus
{
  +LOOKALLAROUND
  +NOPAIN
  States
  {
  Spawn:
    TNT1 A 0 NoDelay A_JumpIfInventory("RLResurrectionComplete", 1, "SpawnNormal")
    TNT1 A 0 A_PlaySound("volacubus/jeton", 7)
    CMAN RQPONMLK 5
    TNT1 A 0 A_ChangeFlag(FLOATBOB, 1)
    TNT1 A 0 A_ChangeFlag("NOPAIN", 0)
    TNT1 A 0 A_GiveInventory("RLResurrectionComplete", 1)
  SpawnNormal:
    TNT1 A 0 A_PlaySound("volacubus/jetloop", 7, 1)
    CMAN ABABCDCD 4 A_Look
    Loop
  }
}

ACTOR RLDRPGSummonedCyberneticMancubus : RLCyberneticMancubus
{
  -COUNTKILL
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCCyberneticMancubus : RLCyberneticMancubus
{
  +TOUCHY
  DeathSound "fatso/death"
  States
  {
  See:
    CMAN ABABCDCD 4
    Loop
  Missile:
    CMAN F 20
    CMAN H 5 Bright
    CMAN I 5
    CMAN FG 5
    CMAN H 5 Bright
    CMAN I 5
    CMAN FG 5
    CMAN H 5 Bright
    CMAN I 5
    CMAN FG 5
    Goto See
  Melee:
    Stop
  Death:
    CMAN K 6
    CMAN L 6 A_Scream
    CMAN M 6 A_NoBlocking
    CMAN N 6
    CMAN OPQRS 6
    CMAN T -1 A_BossDeath
    Stop
  }
}
