
// MACHINE ELEMENTAL
//
ACTOR RLCyberneticPainElemental : RLPainElementalBase 16546
{
  Health 900
  GibHealth -90
  
  MinMissileChance 4
  
  DamageFactor "Melee", 0.8
  DamageFactor "Bullet", 0.8
  DamageFactor "Plasma", 1.2
  DamageFactor "Neutron", 0.0 // Final Doomer Damagetype
  DamageFactor "Tachyon", 0.25 // Final Doomer Damagetype
  
  SeeSound "machineelemental/sight"
  ActiveSound "machineelemental/sight"
  PainSound "machineelemental/pain"
  DeathSound "machineelemental/death"
  CrushPainSound "techvile/smallzap"
  
  +NOBLOOD
  +QUICKTORETALIATE
  +LOOKALLAROUND
  +THRUSPECIES
  
  Species "RLHellmine"
  Obituary "%o was overwhelmed by the Machine Elemental's swarm."
  HitObituary "%o got ruined by a Machine Elemental."
  Tag "Machine Elemental"
    //$category "MP Technophobia"
  
	// Guncaster compatibility
	DropItem "Amber", 192
	DropItem "Ruby"
	DropItem "Ruby"
	DropItem "Emerald"
  States
  {
  Spawn:
    TNT1 A 0
    TNT1 A 0 A_PlaySound ("machineelemental/loop", 5, 1, 1, 1.6)
    CELE AB Random(9,10) A_Look
    Loop
	
  See:
    TNT1 A 0 A_PlaySound ("machineelemental/loop", 5, 1, 1, 1.6)
    TNT1 A 0 A_Stop
    TNT1 A 0 A_JumpIfInventory("PowerRLIThinkWeHaveEnoughGoddamnMines", 1, 2)
    TNT1 A 0 A_CheckSight ("SpawnMinefield")
  SeeMovement:
    CELE AABB 3 Fast A_Chase
    TNT1 A 0 A_JumpIfCloser (128, "MeleeCharge")
    CELE AABB 3 Fast A_Chase
    TNT1 A 0 A_JumpIfCloser (128, "MeleeCharge")
    CELE AABB 3 Fast A_Chase
    TNT1 A 0 A_JumpIfCloser (128, "MeleeCharge")
    CELE AABB 3 Fast A_Chase
    TNT1 A 0 A_JumpIfCloser (128, "MeleeCharge")
    CELE AABB 3 Fast A_Chase
    TNT1 A 0 A_JumpIfCloser (128, "MeleeCharge")
    CELE AABB 3 Fast A_Chase
    TNT1 A 0 A_JumpIfCloser (128, "MeleeCharge")
    CELE AABB 3 Fast A_Chase
    TNT1 A 0 A_JumpIfCloser (128, "MeleeCharge")
    Goto See
	
  SpawnMinefield:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_HellmineCheck") == 1, "MaybePossiblyStopMakingMinesIGuess")
    CELE C 4 Bright
    CELE D 4 Bright A_PainAttack ("RLCyberneticLostSoul", 0, PAF_NOSKULLATTACK | PAF_AIMFACING)
    CELE E 4 Bright
    Goto SeeMovement
  MaybePossiblyStopMakingMinesIGuess:
	TNT1 A 0 A_GiveInventory("PowerRLIThinkWeHaveEnoughGoddamnMines", 1)
    Goto SeeMovement
	
  MeleeCharge:
    TNT1 A 0 A_FaceTarget
    TNT1 A 0 ThrustThing(angle*256/360, 5, 0, 0)
    CELE A 1 A_Chase ("Melee", "", CHF_DONTMOVE | CHF_NOPLAYACTIVE)
    TNT1 A 0 A_FaceTarget
    CELE A 1 A_Chase ("Melee", "", CHF_DONTMOVE | CHF_NOPLAYACTIVE)
    TNT1 A 0 A_FaceTarget
    CELE A 1 A_Chase ("Melee", "", CHF_DONTMOVE | CHF_NOPLAYACTIVE)
    TNT1 A 0 A_FaceTarget
    CELE B 1 A_Chase ("Melee", "", CHF_DONTMOVE | CHF_NOPLAYACTIVE)
    TNT1 A 0 A_FaceTarget
    CELE B 1 A_Chase ("Melee", "", CHF_DONTMOVE | CHF_NOPLAYACTIVE)
    TNT1 A 0 A_FaceTarget
    CELE B 1 A_Chase ("Melee", "", CHF_DONTMOVE | CHF_NOPLAYACTIVE)
    TNT1 A 0 A_Stop
    Goto See
  MeleeProper:
    TNT1 A 0 ThrustThing(angle*256/360, 5, 0, 0)
    CELE C 3 A_FaceTarget
    TNT1 A 0 ThrustThing(angle*256/360, 5, 0, 0)
    CELE C 3 A_FaceTarget
    TNT1 A 0 ThrustThing(angle*256/360, 5, 0, 0)
    CELE C 3 A_FaceTarget
    TNT1 A 0 ThrustThing(angle*256/360, 5, 0, 0)
    CELE A 3 A_CustomMeleeAttack (10 * random(1, 10), "rlmonsters/bite", "", "Melee")
    CELE B 3 A_Chase ("", "")
    Goto See
	
  MissileProper:
    CELE CC 2 Bright A_FaceTarget
    TNT1 A 0 A_Jump(60, 2)
    CELE DD 2 Bright A_PainAttack ("RLCyberneticLostSoul", 0, PAF_NOSKULLATTACK | PAF_AIMFACING, 200)
    CELE D 2 Bright A_FaceTarget
    CELE E 4 Bright A_FaceTarget
    Goto See
	
  PainMain:
    TNT1 A 0 A_Stop
    CELE E 6
    CELE E 6 A_Pain
    Goto See

  //Fire
  Pain.Meteorfist:
	"####" "#" 0 A_FaceTarget
	"####" "#" 0 A_ChangeVelocity(frandom(-13.0,-17.0),0,frandom(9.0,11.0),CVF_RELATIVE)
	"####" "#" 0 A_Jump(256,"Pain")
	Goto Pain
  Pain.Fire:
	"####" "#" 0 A_Jump(256,"Pain")
	Goto Pain
	
  XDeathMain:
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLCyberneticPainElementalKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SetScale (2.5)
    TNT1 A 0 A_StopSound (5)
    TNT1 A 0 A_Scream
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 3)
    TNT1 A 0 A_Quake (1, 8, 0, 512, "")
    TNT1 A 0 A_Quake (5, 8, 0, 256, "")
    TNT1 A 0 A_PlaySound ("rlmonsters/mediumexp", 7, 1, 0, 0.6)
    TNT1 A 0 A_PlaySound("rlmonsters/mediumexp", CHAN_ITEM, 0.05, 0, 0.15)
    TNT1 A 0 A_CustomMissile("RLNightmareElementalExplosion",12,0)
	TNT1 A 0 A_JumpIf(CallACS("GnuCustardCheck"), "GuncasterImpact")
    CELE F 4 Bright A_Scream
    CELE G 4 Bright A_NoBlocking
    CELE HI 3 Bright
    CELE JK 2 Bright
	TNT1 A 0
    "####" "#" 0 A_Jump(256, "DestroyedEnd")
    Goto DestroyedEnd
  DeathFrame:
    TNT1 A 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  //Fire
  Death.Meteorfist:
  Death.Lightning:
  Death.LightningBlue:
  Death.Fire:
	"####" "#" 0 A_Jump(256,"Death")
	Goto Death
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLCyberneticPainElementalKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
    Stop
  Crush:
    TNT1 A 0
    Goto Death
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F2 E 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F2 E 2 Bright
    Goto See
  Pain.CyberDisruptor:
    TNT1 A 0
    Goto Pain.LightningBlue
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  XDeath.RigelBlast:
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 2000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLCyberneticPainElementalKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2AdvancedEnemyExplosions", 0,0,32, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMissileAttack:
    CELE CCD 2 Bright A_FaceTarget
    CELE DDDD 1 Bright A_PainAttack ("RLCyberneticLostSoul", frandom(-15,15), PAF_AIMFACING, 200)
    CELE DEE 2 Bright A_FaceTarget
    Goto See
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  Death.Maser:
  XDeath.Maser:
    "####" "#" 0 A_FaceTarget
    "####" "#" 0 A_ChangeVelocity (frandom(-5.0,-15.0), 0, 0, CVF_RELATIVE)
    "####" "#" 0 A_Jump(256, "XDeath")
	Goto XDeath
	
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    CELE E 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		CELE E 0 A_SpawnItemEx("Midas_Statue_Painis", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		CELE E 0 A_SpawnItemEx("Midas_Statue_Painis", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		CELE E 0 A_SpawnItemEx("Midas_Statue_Painis", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
    Death.Acid:    //So I did mention about meltdown death once...
        "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
        "####" "#" 0 A_DropItem("MinorManaPod",-1,24)
        "####" "#" 0 ACS_NamedExecuteAlways("Toxic Avenger")
        "####" "#" 0 A_NoBlocking
        "####" "#" 0 A_Scream
    AcidDeathLoop:
        "####" "#" 0 A_JumpIf(ScaleY <= 0, "DestroyedEnd")
        "####" "#" 0 A_FadeOut(0.03)
        CELE E 1 A_SetScale(ScaleX + 0.03, ScaleY - 0.03)
        Loop
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		CELE E 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		CELE E 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
		
		// Overwrite these for monsters that do not leave corpses behind
	//Dreadful
	Death.Tiberium:
		"####" "#" 0 A_Jump(256, "Death")
		Goto Death
	Death.BlueTiberium:
		"####" "#" 0 A_Jump(256, "Death")
		Goto Death
	//Fire and Lightning
	Death.Fire:
		"####" "#" 0 A_Jump(256,"Death")
		Goto Death
	  
  GuncasterImpact:
    TNT1 A 0 A_Scream
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_PlaySound("Matriarch/Hit", 5, 0.8)
    TNT1 A 0 A_PlaySound("Matriarch/Exp", 6, 1.0)
    TNT1 A 0 A_PlaySound("Matriarch/Exp", CHAN_ITEM, 0.05, 0, 0.05)
    TNT1 A 0 A_SpawnItemEx("RLGuncasterMonsterExplosionBig", 0,0,0, 0,0,0, 0, SXF_CLIENTSIDE | SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "DestroyedEnd")
    Goto DestroyedEnd
  }
}

ACTOR PowerRLIThinkWeHaveEnoughGoddamnMines : Powerup
{
	Powerup.Duration -30
}

ACTOR RLDRPGSummonedCyberneticPainElemental : RLCyberneticPainElemental
{
  -COUNTKILL
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCCyberneticPainElemental : RLCyberneticPainElemental
{
  DeathSound "rlmonsters/mediumexp"
  +TOUCHY
  States
  {
  See:
    CELE AB 6
    Loop
  Missile:
    CELE CDECDE 4 Bright
    Goto See
  Melee:
    Stop
  Death:
    CELE F 4 Bright A_Scream
    CELE G 4 Bright A_NoBlocking
    CELE HI 3 Bright
    CELE JK 2 Bright
    Stop
  }
}
