
// FORMER CYBORG
//
ACTOR RLFormerCyborgBattleRifle : RLZombiemanBase 16535
{
  Health 80
  GibHealth -40
  Speed 5
  BloodType "RLNashGore_CyberBlood", "RLMNullActor", "RLNashGore_SlashBlood"
  
  PainChance 160
  PainThreshold 8
  
  DamageFactor "Bullet", 0.85
  
  SeeSound "cyberformer/sight"
  PainSound "cyberformer/pain"
  DeathSound "cyberformer/death"
  ActiveSound "cyberformer/active"
  
  Obituary "%o couldn't topple a Former Cyborg."
  Tag "Former Cyborg [Battle Rifle]"
    //$category "MP Technophobia"
  
	DropItem "RLEliteHumanBattleRifleDrop"
	// Guncaster compatibility
	DropItem "Dosh1"
	DropItem "Dosh1"
	DropItem "Dosh1"
	DropItem "Dosh1", 192
	DropItem "Dosh1", 192
	DropItem "Dosh5", 128
	DropItem "Dosh10"
  States
  {
  Spawn:
    CRIF AB Random(9,10) A_Look
    Loop
	
  See:
    TNT1 A 0 A_JumpIfInventory ("RLFormerCyborgBattleRifleShotCounter", 20, "Reload")
    CRIF AA 4 A_Chase ("", "Missile")
    TNT1 A 0 A_PlaySound("cyberformer/step", 5)
    CRIF BB 4 A_Chase ("", "Missile")
    CRIF CC 4 A_Chase ("", "Missile")
    TNT1 A 0 A_PlaySound("cyberformer/step", 5)
    CRIF DD 4 A_Chase ("", "Missile")
    Loop
	
  MissileProper:
    CRIF E 12 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLFormerCyborgBattleRifleShotCounter", 20, "Reload")
    TNT1 A 0 A_GiveInventory ("RLFormerCyborgBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    CRIF F 2 Bright A_CustomBulletAttack (25, 5, 1, random(1,5) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    CRIF E 2 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLFormerCyborgBattleRifleShotCounter", 20, "MissileEnd")
    TNT1 A 0 A_GiveInventory ("RLFormerCyborgBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    CRIF F 2 Bright A_CustomBulletAttack (25, 5, 1, random(1,5) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    CRIF E 2 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLFormerCyborgBattleRifleShotCounter", 20, "MissileEnd")
    TNT1 A 0 A_GiveInventory ("RLFormerCyborgBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    CRIF F 2 Bright A_CustomBulletAttack (25, 5, 1, random(1,5) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    CRIF E 2 A_FaceTarget
	Goto MissileEnd
  MissileEnd:
    CRIF E 8 A_FaceTarget
    Goto See
	
  SummonMissile:
    CRIF F 2 Bright A_CustomBulletAttack (2, 0.5, 1, random(1,3) * 5, "RLEnemySummonBulletPuff", 0, CBAF_NORANDOM)
    CRIF E 2 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLFormerCyborgBattleRifleShotCounter", 20, "MissileEnd")
    TNT1 A 0 A_GiveInventory ("RLFormerCyborgBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    CRIF F 2 Bright A_CustomBulletAttack (2, 0.5, 1, random(1,3) * 5, "RLEnemySummonBulletPuff", 0, CBAF_NORANDOM)
    CRIF E 2 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLFormerCyborgBattleRifleShotCounter", 20, "MissileEnd")
    TNT1 A 0 A_GiveInventory ("RLFormerCyborgBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    CRIF F 2 Bright A_CustomBulletAttack (2, 0.5, 1, random(1,3) * 5, "RLEnemySummonBulletPuff", 0, CBAF_NORANDOM)
    CRIF E 2 A_FaceTarget
	Goto MissileEnd
	
  Reload:
    CRIF EE 4
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifleunload", 7)
    CRIF EEEEEEEE 4
    CRIF E 2
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifleload", 7)
    TNT1 A 0 A_TakeInventory ("RLFormerCyborgBattleRifleShotCounter", 20)
    CRIF EE 5 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/battleriflecock", 5)
    CRIF E 6 A_FaceTarget
    Goto See
	
  PainMain:
    CRIF G 3
    CRIF G 3 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLFormerCyborgKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    CRIF H 5
    CRIF I 5 A_Scream
    CRIF J 5 A_NoBlocking
    CRIF K 5
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    CRIF LM 5
    CRIF N 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    CRIF N 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLFormerCyborgKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    CRIF O 4
    CRIF P 4 A_XScream
    CRIF Q 4 A_NoBlocking
    CRIF RST 4
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    CRIF UV 4
    CRIF W 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLFormerCyborgKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    CRIF O 4
    CRIF P 4 A_XScream
    CRIF Q 4 A_NoBlocking
    CRIF RST 4
    CRIF UV 4
    CRIF W 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLFormerCyborgKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    CRIF L 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, 2)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_TakeInventory ("RLFormerCyborgBattleRifleShotCounter", 20)
    CRIF K 5
    CRIF J 5
    CRIF I 5
    CRIF H 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_ChangeFlag ("ALWAYSFAST", 1)
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1) 
    TNT1 A 0 A_ChangeFlag ("SEEINVISIBLE", 1)
    TNT1 A 0 A_ChangeFlag ("MISSILEMORE", 1)
    Goto RaiseContinue
	
  CrushDRLA:
    TNT1 A 30 A_SpawnItemEx("RLCrushedSmall",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
	
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F2 G 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F2 G 2 Bright
    Goto See
  Pain.CyberDisruptor:
    TNT1 A 0
    Goto Pain.LightningBlue
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLFormerCyborgKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLFormerCyborgKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  Duke2LaserAttack:
    CRIF E 15 A_FaceTarget
    CRIF F 2 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-3,3), CMF_OFFSETPITCH, frandom(-3,3))
    CRIF E 2
    CRIF F 2 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-3,3), CMF_OFFSETPITCH, frandom(-3,3))
    CRIF E 2
    CRIF F 2 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-3,3), CMF_OFFSETPITCH, frandom(-3,3))
    CRIF E 10
    Goto See
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MinorManaPod",-1,54)
    CRIF G 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		CRIF G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		CRIF G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		CRIF G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		CRIF G 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		CRIF G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		CRIF G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

Actor RLFormerCyborgBattleRifleShotCounter : Inventory
{
inventory.maxamount 20
}

ACTOR RLDRPGSummonedFormerCyborg : RLFormerCyborgBattleRifle
{
  -COUNTKILL
  +AVOIDMELEE
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCFormerCyborgBattleRifle : RLFormerCyborgBattleRifle
{
  +TOUCHY
  States
  {
  See:
    CRIF AABBCCDD 4
    Loop
  Missile:
    CRIF E 12
    CRIF F 2 Bright
    CRIF E 2
    CRIF F 2 Bright
    CRIF E 2
    CRIF F 2 Bright
    CRIF E 10
    Goto See
  Melee:
    Stop
  Death:
    CRIF H 5
    CRIF I 5 A_Scream
    CRIF J 5 A_NoBlocking
    CRIF KLM 5
    CRIF N -1
    Stop
  }
}
