
// ARCH-VILE
//
ACTOR RLArchvile : RLArchvileBase 16415
{
  Health 700
  GibHealth -80
  
  DamageFactor "Fire", 0.7
  DamageFactor "Ice", 1.1
  
  Obituary "%o couldn't hide from the Arch-Vile."
  Tag "Arch-Vile"
    //$category "MP Standard"
  
	// Guncaster compatibility
	DropItem "Sapphire"
	DropItem "AmplifierGiver", 32, 0
	DropItem "TomeSpawner", 4, 0
  States
  {
  Spawn:
    VILE AB Random(9,10) A_Look
    Loop
	
  See:
    VILE AABBCCDDEEFF 2 A_Chase ("", "Missile", CHF_RESURRECT)
    Loop
	
  MissileProper:
    TNT1 A 0 A_VileStart
    VILE G 10 Bright A_FaceTarget
    VILE H 8 Bright A_VileTarget
    VILE IJKLMN 8 Bright A_FaceTarget
    VILE O 8 Bright A_VileAttack ("vile/stop", 20, 70, 70, 1, "Fire", VAF_DMGTYPEAPPLYTODIRECT)
    VILE P 20 Bright
    Goto See
	
  Heal:
    VILH CABACABACC 3 Bright
    Goto See
	
  PainMain:
    VILE Q 5   
    VILE Q 5 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLArchvileKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    VILE Q 7
    TNT1 A 0 A_SpawnItemEx ("RLReducedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    VILE R 7 A_Scream
    VILE S 7 A_NoBlocking
    VILE TU 7
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    VILE VWXY 7
    VILE Z 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    VILE Z 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLArchvileKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    VIL2 A 5
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_PlaySound ("misc/gibbed", 5)
    VIL2 B 5 A_Scream
    VIL2 C 5 A_NoBlocking
    VIL2 D 5
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    VIL2 EFG 5
    VIL2 H 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLArchvileKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    VIL2 A 5
    VIL2 B 5 A_Scream
    VIL2 C 5 A_NoBlocking
    VIL2 D 5
    VIL2 EFG 5
    VIL2 H 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLArchvileKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  CrushDRLA:
    TNT1 A 0 A_SpawnItemEx("RLCrushedSmall",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 Q 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 Q 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0 A_GiveInventory ("RLArchvileKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLNeuralStunStars", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION | SXF_SETMASTER)
    TNT1 A 0 A_Stop
    TNT1 A 0 ThrustThingZ (0, 20, 0, 0)
    CDK1 J -1
    Stop
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 2000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLArchvileKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 2000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLArchvileKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMissileAttack:
    TNT1 A 0 A_VileStart
    VILE G 10 Bright A_FaceTarget
    VILE H 8 Bright A_VileTarget ("RLArchvileShadowFire")
    VILE IJKLMN 8 Bright A_FaceTarget
    VILE O 8 Bright A_VileAttack ("vile/stop", 20, 128, 128, 10, "Unholy", VAF_DMGTYPEAPPLYTODIRECT)
    VILE P 20 Bright
    Goto See
	
  LegendaryMissileAttack:
    TNT1 A 0 A_VileStart
    VILE G 10 Bright A_FaceTarget
    VILE H 8 Bright A_VileTarget ("RLArchvileLegendaryFire")
    VILE IJKLMN 8 Bright A_FaceTarget
    VILE O 8 Bright A_VileAttack ("vile/stop", 20, 128, 128, 10, "Unholy", VAF_DMGTYPEAPPLYTODIRECT)
    VILE P 20 Bright
    Goto See
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    VILE Q 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		VILE Q 0 A_SpawnItemEx("Midas_Statue_Vile", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		VILE Q 0 A_SpawnItemEx("Midas_Statue_Vile", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		VILE Q 0 A_SpawnItemEx("Midas_Statue_Vile", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		VILE Q 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		VILE Q 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		VILE Q 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

ACTOR RLArchvileShadowFire : ArchvileFire
{
  +NOTIMEFREEZE
  +BLOODSPLATTER
  States
  {
  Spawn:
    TNT1 A 0
    TNT1 A 0 A_PlaySound("vile/firestrt", 7, 1, 0, 0.75)
    FIRE A 2 Bright A_Fire
    FIRE B 2 Bright A_Fire
    FIRE A 2 Bright A_Fire
    FIRE B 2 Bright A_Fire
    TNT1 A 0 A_PlaySound("vile/firecrkl", 7, 1, 0, 0.75)
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE C 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE B 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE C 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE B 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE C 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE D 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE C 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE D 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE C 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE D 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE E 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE D 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE E 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE D 2 Bright A_Fire
    TNT1 A 0 A_PlaySound("vile/firecrkl", 7, 1, 0, 0.75)
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE E 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE F 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE E 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE F 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE E 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE F 2 Bright A_Fire
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLArchvileShadowFloorFire", frandom(-8,8),frandom(-8,8),0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    FIRE GHGHGH 2 Bright A_Fire
    Stop
  }
}

Actor RLArchvileShadowFloorFire
{
  Radius 8
  Height 40
  Projectile
  RenderStyle Add
  DamageType "Fire"
  Species "RLArchvile"
  Alpha 0.90
  Scale 0.5
  -NOGRAVITY
  +DONTHARMSPECIES
  +THRUSPECIES
  +LOWGRAVITY
  +NOEXPLODEFLOOR
  +NODAMAGETHRUST
  +THRUGHOST
  +NOTIMEFREEZE
  +BLOODSPLATTER
  
  var int user_archfiretimer;
  States
  {
  Spawn:
    TNT1 A 0
    TNT1 A 0 A_Warp (AAPTR_DEFAULT, 0, 0, 0, 0, WARPF_NOCHECKPOSITION | WARPF_TOFLOOR)
    TNT1 A 0 A_SetUserVar("user_archfiretimer", random(3,24))
	Goto FireFour
  FireOne:
    TNT1 A 0 A_JumpIf (user_archfiretimer <= 0, "Death")
    TNT1 A 0 A_Playsound("rlmonsters/fireloop", 6, 1, 1, 1.6)
    TNT1 A 0 A_Explode(1, 32, XF_HURTSOURCE, 0, 16)
    AVFX AABBCC 2 Bright A_Explode(randompick(0,0,0,0,0,0,0,0,0,0,0,1,1,1,1,1,1,1,1,1,1,1,2,3,5), 16, XF_HURTSOURCE, 0, 16)
    TNT1 A 0 A_SetUserVar("user_archfiretimer", user_archfiretimer - 1)
    Loop
  FireTwo:
    TNT1 A 0 A_JumpIf (user_archfiretimer <= 6, "FireOne")
    TNT1 A 0 A_Playsound("rlmonsters/fireloop", 6, 1, 1, 1.6)
    TNT1 A 0 A_Explode(3, 32, XF_HURTSOURCE, 0, 16)
    AVFX DDEEFF 2 Bright A_Explode(randompick(0,0,0,0,0,0,0,0,0,0,0,1,1,1,1,1,1,1,1,1,1,1,2,3,5), 16, XF_HURTSOURCE, 0, 16)
    TNT1 A 0 A_SetUserVar("user_archfiretimer", user_archfiretimer - 1)
    Loop
  FireThree:
    TNT1 A 0 A_JumpIf (user_archfiretimer <= 12, "FireTwo")
    TNT1 A 0 A_Playsound("rlmonsters/fireloop", 6, 1, 1, 1.6)
    TNT1 A 0 A_Explode(5, 32, XF_HURTSOURCE, 0, 16)
    AVFX GGHHII 2 Bright A_Explode(randompick(0,0,0,0,0,0,0,0,0,0,0,1,1,1,1,1,1,1,1,1,1,1,2,3,5), 20, XF_HURTSOURCE, 0, 20)
    TNT1 A 0 A_SetUserVar("user_archfiretimer", user_archfiretimer - 1)
    Loop
  FireFour:
    TNT1 A 0 A_JumpIf (user_archfiretimer <= 18, "FireThree")
    TNT1 A 0 A_Playsound("rlmonsters/fireloop", 6, 1, 1, 1.6)
    TNT1 A 0 A_Explode(10, 32, XF_HURTSOURCE, 0, 32)
    AVFX JJKKLL 2 Bright A_Explode(randompick(0,0,0,0,0,0,0,0,0,0,0,1,1,1,1,1,1,1,1,1,1,1,2,3,5), 24, XF_HURTSOURCE, 0, 24)
    TNT1 A 0 A_SetUserVar("user_archfiretimer", user_archfiretimer - 1)
    Loop
  Death:
    TNT1 A 0 A_StopSound(6)
    AVFX AABBCC 2 Bright A_SetScale(scalex*0.8)
    Stop
  }
}

ACTOR RLArchvileLegendaryFire : ArchvileFire
{
  +NOTIMEFREEZE
  +BLOODSPLATTER
  States
  {
  Spawn:
    TNT1 A 0
    TNT1 A 0 A_PlaySound("vile/firestrt", 6, 1, 0, 0.75)
    FIRE ABAB 2 Bright A_Fire
    TNT1 A 0 A_PlaySound("vile/firecrkl", 7, 1, 0, 0.75)
    FIRE CBCBCDCDCDEDED 2 Bright A_Fire
    TNT1 A 0 A_PlaySound("vile/firecrkl", 7, 1, 0, 0.75)
    FIRE EFEFEFGHGHGH 2 Bright A_Fire
    Stop
  }
}

ACTOR RLDRPGSummonedArchvile : RLArchvile
{
  -COUNTKILL
  -NOTARGET
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCArchvile : RLArchvile
{
  +TOUCHY
  States
  {
  Missile:
    VILE G 0 Bright
    VILE G 10 Bright
    VILE H 8 Bright
    VILE IJKLMN 8 Bright
    VILE O 8 Bright
    VILE P 20 Bright
    Goto See
  Melee:
    VILH CABACABACC 3 Bright
    Goto See
  Death:
    VILE Q 7
    VILE R 7 A_Scream
    VILE S 7 A_NoBlocking
    VILE TU 7
    VILE VWXY 7
    VILE Z -1
  }
}
