
// BARONOFHELL
//
ACTOR RLBaronOfHell : RLBaronOfHellBase 16410
{
  Health 1000
  GibHealth -75
  
  Obituary "%o was put down by a Baron of Hell."
  HitObituary "%o was overpowered by a Baron of Hell."
  Tag "Baron of Hell"
    //$category "MP Standard"
  
	// Guncaster compatibility
	DropItem "Emerald"
  States
  {
  Spawn:
    BARO BD Random(9,10) A_Look
    Goto Spawn
	
  See:
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 2) // Friendly monsters do not use commands
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, "CommandMissile")
    BARO A 3 A_Chase
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 2) // Friendly monsters do not use commands
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, "CommandMissile")
    BARO A 3 A_Chase
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 2) // Friendly monsters do not use commands
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, "CommandMissile")
    BARO B 3 A_Chase
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 2) // Friendly monsters do not use commands
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, "CommandMissile")
    BARO B 3 A_Chase
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 2) // Friendly monsters do not use commands
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, "CommandMissile")
    BARO C 3 A_Chase
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 2) // Friendly monsters do not use commands
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, "CommandMissile")
    BARO C 3 A_Chase
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 2) // Friendly monsters do not use commands
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, "CommandMissile")
    BARO D 3 A_Chase
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 2) // Friendly monsters do not use commands
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, "CommandMissile")
    BARO D 3 A_Chase
    Loop
	
  MissileHatredOnUniqueEffect: // [incoherent tantrum sounds]
    "####" "#" 0 A_PlaySound ("baron/sight", CHAN_VOICE)
    "####" "#" 0 A_Jump (256, "MissileHatredOnUniqueDone")
	Goto MissileHatredOnUniqueDone
  MeleeHatredOnUniqueEffect: // [incoherent tantrum sounds]
    "####" "#" 0 A_PlaySound ("baron/sight", CHAN_VOICE)
    "####" "#" 0 A_Jump (256, "MeleeHatredOnUniqueDone")
	Goto MeleeHatredOnUniqueDone
	
  MeleeProper:
  MissileProper:
    TNT1 A 0 A_JumpIfInventory ("RLBaronOfHellArmToken", 1, "Missile2")
    BARO EF 8 A_FaceTarget
    TNT1 A 0 A_GiveInventory ("RLBaronOfHellArmToken", 1)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    BARO G 8 A_CustomComboAttack("RLBaronOfHellPlasmaBall", 32, 10 * random(1, 8), "baron/melee")
    TNT1 A 0 A_MonsterRefire(64, "See")
    TNT1 A 0 A_JumpIfCloser (256, 1)
    Goto See
    TNT1 A 0
    Goto Missile
  Missile2:
    BARO PQ 8 A_FaceTarget
    TNT1 A 0 A_TakeInventory ("RLBaronOfHellArmToken", 1)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile2") // Friendly monsters do not harm you
    BARO R 8 A_CustomComboAttack("RLBaronOfHellPlasmaBall", 32, 10 * random(1, 8), "baron/melee")
    TNT1 A 0 A_MonsterRefire(64, "See")
    TNT1 A 0 A_JumpIfCloser (256, 1)
    Goto See
    TNT1 A 0
    Goto Missile
	
  SummonMissile:
    BARO G 8 A_CustomComboAttack("RLSummonBaronOfHellPlasmaBall", 32, 10 * random(1, 8), "baron/melee")
    TNT1 A 0 A_MonsterRefire(64, "See")
    TNT1 A 0 A_JumpIfCloser (256, 1)
    Goto See
    TNT1 A 0
    Goto Missile
  SummonMissile2:
    BARO R 8 A_CustomComboAttack("RLSummonBaronOfHellPlasmaBall", 32, 10 * random(1, 8), "baron/melee")
    TNT1 A 0 A_MonsterRefire(64, "See")
    TNT1 A 0 A_JumpIfCloser (256, 1)
    Goto See
    TNT1 A 0
    Goto Missile
	
  CommandMissile:
    TNT1 A 0 A_JumpIfInventory ("RLBaronOfHellArmToken", 1, 3)
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, 1)
    Goto CommandMissile1
    BARO E 1 A_FaceTarget
    Goto CommandMissile
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, 1)
    Goto CommandMissile2
    BARO P 1 A_FaceTarget
    Goto CommandMissile
  CommandMissile1:
    TNT1 A 0 A_JumpIfInventory ("RLBaronOfHellArmToken", 1, "CommandMissile2")
    BARO EF 4 A_FaceTarget
    TNT1 A 0 A_GiveInventory ("RLBaronOfHellArmToken", 1)
    BARO G 4 A_CustomMissile("RLBaronOfHellPlasmaBall",32,4,frandom(0, 4))
    TNT1 A 0 A_MonsterRefire (0, "See")
    Goto CommandMissile1
  CommandMissile2:
    BARO PQ 4 A_FaceTarget
    TNT1 A 0 A_TakeInventory ("RLBaronOfHellArmToken", 1)
    BARO R 4 A_CustomMissile("RLBaronOfHellPlasmaBall",32,-4,frandom(-4, 0))
    TNT1 A 0 A_MonsterRefire (0, "See")
    Goto CommandMissile1
	
  PainMain:
    TNT1 A 0 A_TakeInventory ("PowerRLNightmareBaronCommand", 1)
    BARO H 2
    BARO H 2 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLBaronOfHellKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_Jump (128, "Death2", "Death3")
    BARO I 8
    BARO J 8 A_Scream
    BARO K 8
    BARO L 8 A_NoBlocking
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    BARO MN 8
    BARO O 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  Death2:
    BARO S 8
    BARO T 8 A_Scream
    BARO U 8
    BARO V 8 A_NoBlocking
    BARO W 8
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    BARO X 8
    BARO Y 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  Death3:
    BAR2 A 8
    BAR2 B 8 A_Scream
    BAR2 C 8
    BAR2 D 8 A_NoBlocking
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    BAR2 E 8
    BAR2 F 8
    BAR2 G 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    BARO O 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLBaronOfHellKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    BAR2 H 1
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_PlaySound ("misc/gibbed", 5)
    BAR2 H 3 A_Scream
    BAR2 IJ 4
    BAR2 K 4 A_NoBlocking
    BAR2 L 4
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    BAR2 MNO 4
    BAR2 P 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLBaronOfHellKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    BAR2 H 1
    BAR2 H 3 A_Scream
    BAR2 IJ 4
    BAR2 K 4 A_NoBlocking
    BAR2 L 4
    BAR2 MNO 4
    BAR2 P 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLBaronOfHellKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    BARO O 2
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    BARO O 8
    BARO NMLKJI 8
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_Die ("NightmareRemoval")
  Death.NightmareRemoval:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareBaronofHellReborn", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Stop
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_Die ("CyberneticRemoval")
  Death.CyberneticRemoval:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticBaronofHellReborn", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Stop
	
  CrushDRLA:
    "####" "#" 0 A_BossDeath
    TNT1 A 0 A_SpawnItemEx("RLCrushedMediumGreen",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 L 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 L 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLBaronOfHellKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLNeuralStunStarsBig", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION | SXF_SETMASTER)
    TNT1 A 0 A_Stop
    TNT1 A 0 ThrustThingZ (0, 20, 0, 0)
    CKD1 H -1
    Stop
  Death.RigelBlast:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLBaronOfHellKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLBaronOfHellKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2Gibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMeleeAttack:
  ShadowAuraMissileAttack:
    TNT1 A 0 A_JumpIfInventory ("RLBaronOfHellArmToken", 1, "ShadowAuraMissileAttack2")
    BARO E 8 A_FaceTarget
    BARO F 8 A_FaceTarget
    TNT1 A 0 A_GiveInventory ("RLBaronOfHellArmToken", 1)
    BARO G 8 A_CustomComboAttack("RLLordOfTheAbyssPlasmaBall2", 32, 10 * random(1, 8), "baron/melee")
    Goto See
  ShadowAuraMissileAttack2:
    BARO P 8 A_FaceTarget
    BARO Q 8 A_FaceTarget
    TNT1 A 0 A_TakeInventory ("RLBaronOfHellArmToken", 1)
    BARO R 8 A_CustomComboAttack("RLLordOfTheAbyssPlasmaBall2", 32, 10 * random(1, 8), "baron/melee")
    Goto See
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    BARO H 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		BARO H 0 A_SpawnItemEx("Midas_Statue_BaronOfHell", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		BARO H 0 A_SpawnItemEx("Midas_Statue_BaronOfHell", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		BARO H 0 A_SpawnItemEx("Midas_Statue_BaronOfHell", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		BARO H 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		BARO H 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		BARO H 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

ACTOR RLBaronOfHellPlasmaBall : BaronBall
{
   +NOTIMEFREEZE
   +THRUGHOST
   +BLOODSPLATTER
   Decal "BaronScorch"
   DamageType "Plasma"
   PainType "HellNobleFire"
   DeathType "HellNobleFire"
  States
  {
  Spawn:
    BAL7 AB 4 Bright
    Goto Spawn
//  Death:
//    BAL7 CDE 6 Bright
//    Stop
  }
}

ACTOR RLSummonBaronOfHellPlasmaBall : RLBaronOfHellPlasmaBall
{
   +MTHRUSPECIES
}

Actor RLBaronOfHellArmToken : Inventory
{
inventory.maxamount 1
}

ACTOR RLDRPGSummonedBaronOfHell : RLBaronOfHell
{
  -COUNTKILL
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCBaronOfHell : RLBaronOfHell
{
  +TOUCHY
  States
  {
  Spawn:
    BARO BD 10 A_Look
    Loop
  See:
    BARO AABBCCDD 3
    Loop
  Melee:
  Missile:
    BARO EF 8
    BARO G 8
    BARO PQ 8
    BARO R 8
    Goto See
  Death:
    BARO I 8
    BARO J 8 A_Scream
    BARO K 8
    BARO L 8 A_NoBlocking
    BARO MN 8
    BARO O -1 A_BossDeath
    Stop
  }
}
