
// CACODEMON
//
ACTOR RLCacodemon : RLCacodemonBase 16408
{
  Health 400
  GibHealth -60
  Bloodcolor "Blue"
  
  PainChance "Lightning", 0
  PainChance "LightningBlue", 0
  
  Obituary "%o was blasted by a Cacodemon."
  HitObituary "%o was consumed by a Cacodemon."
  Tag "Cacodemon"
    //$category "MP Standard"
  
	// Guncaster compatibility
	DropItem "Amber"
  States
  {
  Spawn:
    CACO A Random(9,10) A_Look
    Goto Spawn
	
  See:
    CACO A 3 A_Chase
    Loop
	
  MissileHatredOnUniqueEffect: // [incoherent tantrum sounds]
    "####" "#" 0 A_PlaySound ("caco/sight", CHAN_VOICE)
    "####" "#" 0 A_Jump (256, "MissileHatredOnUniqueDone")
	Goto MissileHatredOnUniqueDone
  MeleeHatredOnUniqueEffect: // [incoherent tantrum sounds]
    "####" "#" 0 A_PlaySound ("caco/sight", CHAN_VOICE)
    "####" "#" 0 A_Jump (256, "MeleeHatredOnUniqueDone")
	Goto MeleeHatredOnUniqueDone
	
  MeleeProper:
    CACO BCDD 3 A_FaceTarget
    TNT1 A 0 A_FaceTarget
    CACO C 1 A_CustomMeleeAttack (6 * random(1, 10), "rlmonsters/bite", "", "Melee")
    CACO B 1 A_FaceTarget
    Goto See
	
  MissileProper:
    CACO BC 5 A_FaceTarget
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    CACO D 5 Bright A_CustomComboAttack("RLCacodemonPlasmaBall", 24, 10 * random(1, 6), "rlmonsters/bite")
    CACO CB 3 A_Chase ("", "")
    Goto See
	
  SummonMissile:
    CACO D 5 Bright A_CustomComboAttack("RLSummonCacodemonPlasmaBall", 24, 10 * random(1, 6), "rlmonsters/bite")
    CACO CB 3 A_Chase ("", "")
    Goto See
	
  PainMain:
    CACO E 3
    CACO E 3 A_Pain
    CACO F 6
    Goto See

  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLCacodemonKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    CACO G 8
    CACO H 8 A_Scream
    CACO I 8 A_ChangeFlag ("CORPSE", 1)
    TNT1 A 0 A_ChangeFlag ("DONTCORPSE", 0)
  DeathFall:
    CACO I 1 A_JumpIf (velz <= 0.01, "Splat")
	Loop
  Splat:
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    CACO J 8
    CACO K 8 A_NoBlocking
    CACO L 0 A_SetFloorClip
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    TNT1 A 0 A_ChangeFlag ("CORPSE", 1)
    TNT1 A 0 A_ChangeFlag ("DONTCORPSE", 0)
    CACO L 0 A_SetFloorClip
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLCacodemonKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    CACO M 2
    CACO M 3 A_XScream
    CACO N 5
    CACO O 5 A_NoBlocking
  XDeathFall:
    CACO O 1 A_JumpIf (velz <= 0.01, "XSplat")
	Loop
  XSplat:
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    CACO P 5
    TNT1 A 0 A_ChangeFlag ("CORPSE", 1)
    TNT1 A 0 A_ChangeFlag ("DONTCORPSE", 0)
    CACO Q 0 A_SetFloorClip
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLCacodemonKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    CACO M 2
    CACO M 3 A_XScream
    CACO N 5
    CACO O 5 A_NoBlocking
    CACO P 5
    TNT1 A 0 A_ChangeFlag ("CORPSE", 1)
    TNT1 A 0 A_ChangeFlag ("DONTCORPSE", 0)
    CACO Q 0 A_SetFloorClip
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLCacodemonKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_TakeInventory ("RLCacodemonFallCheckToken", 350)
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    CACO L 2
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_ChangeFlag ("CORPSE", 0)
    TNT1 A 0 A_ChangeFlag ("DONTCORPSE", 1)
    CACO L 8 A_UnSetFloorClip
    CACO KJIHG 8
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_Die ("NightmareRemoval")
  Death.NightmareRemoval:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareCacodemonReborn", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Stop
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_Die ("CyberneticRemoval")
  Death.CyberneticRemoval:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareCacodemonReborn", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
//    TNT1 A 0 A_SpawnItemEx ("RLCyberneticCacodemonReborn", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Stop
	
  CrushDRLA:
    "####" "#" 0 A_ChangeFlag ("CORPSE", 1)
    TNT1 A 0 A_SpawnItemEx("RLCrushedMediumBlue",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 K 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 K 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0 A_GiveInventory ("RLCacodemonKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLNeuralStunStarsBigger", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION | SXF_SETMASTER)
    TNT1 A 0 A_Stop
    TNT1 A 0 ThrustThingZ (0, 20, 0, 0)
    TNT1 A 0 A_ChangeFlag ("CORPSE", 1)
    TNT1 A 0 A_ChangeFlag ("DONTCORPSE", 0)
    CKD1 F -1 A_SetFloorClip
    Stop
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 700, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLCacodemonKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2AdvancedEnemyExplosions", 0,0,32, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 700, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLCacodemonKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2AdvancedEnemyExplosions", 0,0,32, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BlueGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMeleeAttack:
  ShadowAuraMissileAttack:
    CACO BC 5 A_FaceTarget
    CACO D 5 Bright A_CustomComboAttack("RLCacodemonFragmentationPlasmaBall", 24, 10 * random(1, 6), "rlmonsters/bite")
    CACO CB 3 A_Chase ("", "")
    Goto See
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    CACO E 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		CACO F 0 A_SpawnItemEx("Midas_Statue_Cacodemon", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		CACO F 0 A_SpawnItemEx("Midas_Statue_Cacodemon", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		CACO F 0 A_SpawnItemEx("Midas_Statue_Cacodemon", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		CACO F 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0// A_Jump(164,1)
		Goto Pain
		CACO F 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0// A_Jump(48,1)
		Goto Pain
		CACO F 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

ACTOR RLCacodemonPlasmaBall : CacodemonBall
{
   +NOTIMEFREEZE
   +THRUGHOST
   +BLOODSPLATTER
   Decal "CacoScorch"
   DamageType "Plasma"
   PainType "LightningBlue"
   DeathType "LightningBlue"
   SeeSound "nightmarecacodemon/ball"
  States
  {
  Spawn:
    BAL2 AB 4 Bright
    Goto Spawn
//  Death:
//    BAL2 CDE 6 Bright
//   Stop
  }
}

ACTOR RLCacodemonFragmentationPlasmaBall : CacodemonBall
{
   +THRUGHOST
   +NOTIMEFREEZE
   +BLOODSPLATTER
   Decal "CacoScorch"
   DamageType "Plasma"
   PainType "LightningBlue"
   DeathType "LightningBlue"
   DeathSound "nightmarecacodemon/ballimpact"
  States
  {
  Spawn:
    BAL2 AB 2 Bright
    Loop
  Death:
    TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_CustomMissile("RLCacodemonPlasmaBallFragments",0,0,random(0, 359), CMF_AIMDIRECTION | CMF_TRACKOWNER, Random(-90, 90))
    BAL2 CDE 6 Bright
   Stop
  }
}

Actor RLCacodemonPlasmaBallFragments
{
  Damage (3)
  DamageType "Plasma"
  PainType "LightningBlue"
  DeathType "LightningBlue"
  Speed 8
  Radius 3
  Height 5
  -NOGRAVITY
  +THRUGHOST
  +NOTIMEFREEZE
  +BLOODSPLATTER
  Scale 0.4
  Gravity 1.8
  DeathSound "caco/shotx"
  RenderStyle Add
  Alpha 0.9
  Projectile
  states
  {
  Spawn:
    FLBL ABCBABCBABCBABCBIJKLM 3 Bright
    Stop
  Death:
    FLBL DEFGH 4 Bright
    Stop
  }
}

ACTOR RLSummonCacodemonPlasmaBall : RLCacodemonPlasmaBall
{
   +MTHRUSPECIES
}

Actor RLCacodemonFallCheckToken : Inventory
{
inventory.maxamount 350
}

ACTOR RLDRPGSummonedCacodemon : RLCacodemon
{
  -COUNTKILL
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCCacodemon : RLCacodemon
{
  -DONTCORPSE
  +TOUCHY
  States
  {
  Spawn:
    CACO A 10 A_Look
    Loop
  See:
    CACO A 3
    Loop
  Melee:
    CACO BCDD 3
    CACO CB 1
    Goto See
  Missile:
    CACO BC 5
    CACO D 5 Bright
    CACO CB 3
    Goto See
  Death:
    CACO G 8
    CACO H 8 A_Scream
    CACO I 8
    CACO J 8
    CACO K 8 A_NoBlocking
    CACO L -1 A_SetFloorClip
    Stop
  }
}
