
// FORMER HUMAN COMMANDO
//
ACTOR RLFormerCommandoChaingun : RLChaingunguyBase
{
  Health 70
  
  Tag "Former Commando [Chaingun]"
  Obituary "A Former Human Commando made %o do the chaingun cha-cha."
    //$category "MP Standard"
  
	DropItem "RLFormerCommandoChaingunDrop"
	// Guncaster compatibility
	DropItem "Dosh5", 128
	DropItem "Dosh10", 192
	DropItem "Dosh25"
  States
  {
  Spawn:
    ZCCH AB Random(9,10) A_Look
    Loop
	
  See:
    TNT1 A 0 A_JumpIfInventory ("RLFormerCommandoChaingunShotCounter", 40, "RetreatReload")
    ZCCH AABBCCDD 3 A_Chase ("", "Missile")
    Loop
	
  RetreatReload:
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 1)
    ZCCH AA 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    ZCCH BB 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    ZCCH CC 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    ZCCH DD 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (24, "Reload")
    TNT1 A 0
    Goto RetreatReload+1

  MissileProper:
    ZCCH U 10 A_FaceTarget
  RepeatProper:
    TNT1 A 0 A_JumpIfInventory ("RLFormerCommandoChaingunShotCounter", 40, "MissileEnd")
    TNT1 A 0 A_GiveInventory ("RLFormerCommandoChaingunShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/chaingun", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/chaingun", CHAN_ITEM, 0.05, 0, 0.20)
    TNT1 A 0 A_JumpIfInventory ("RLFormerCommandoChaingunStateCounter", 1, "MissileAlt")
    TNT1 A 0 A_GiveInventory ("RLFormerCommandoChaingunStateCounter", 1)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    ZCCH F 3 Bright A_CustomBulletAttack (22.5, 0, 1, random(1,5) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ZCCH U 1 A_MonsterRefire(30, "MissileEnd")
    Goto RepeatSpecialAttackCheck
  MissileAlt:
    TNT1 A 0 A_TakeInventory ("RLFormerCommandoChaingunStateCounter", 1)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissileAlt") // Friendly monsters do not harm you
    ZCCH E 3 Bright A_CustomBulletAttack (22.5, 0, 1, random(1,5) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ZCCH U 1 A_MonsterRefire(30, "MissileEnd")
    Goto RepeatSpecialAttackCheck
  MissileEnd:
    TNT1 A 0 A_PlaySound("rlmonsters/chaingunwinddown", 7)
    ZCCH U 10
    Goto See
	
  SummonMissile:
    ZCCH F 3 Bright A_CustomBulletAttack (6, 2, 1, random(1,3) * 5, "RLEnemySummonBulletPuff", 0, CBAF_NORANDOM)
    ZCCH U 1 A_MonsterRefire(30, "MissileEnd")
    Goto RepeatSpecialAttackCheck
  SummonMissileAlt:
    ZCCH E 3 Bright A_CustomBulletAttack (6, 2, 1, random(1,3) * 5, "RLEnemySummonBulletPuff", 0, CBAF_NORANDOM)
    ZCCH U 1 A_MonsterRefire(30, "MissileEnd")
    Goto RepeatSpecialAttackCheck
	
  Reload:
    ZCCH UUU 5 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/pistolreloadout", 7)
    ZCCH UU 5 A_FaceTarget
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_PlaySound("rlmonsters/chaingunload", 7)
    TNT1 A 0 A_TakeInventory ("RLFormerCommandoChaingunShotCounter", 40)
    ZCCH UUUUU 5 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/chaingunwinddown", 7)
    ZCCH UU 5 A_FaceTarget
    Goto See
	
  PainMain:
    ZCCH G 3
    ZCCH G 3 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLFormerCommandoKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    ZCCH H 5
    ZCCH I 5 A_Scream
    ZCCH J 5 A_NoBlocking
    ZCCH K 5
    ZCCH L 5
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    ZCCH M 5
    ZCCH N 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    ZCCH N 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLFormerCommandoKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    ZCCH O 5
    ZCCH P 5 A_XScream
    ZCCH Q 5 A_NoBlocking
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    ZCCH R 5
    ZCCH S 5
    ZCCH T 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLFormerCommandoKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    ZCCH O 5
    ZCCH P 5 A_XScream
    ZCCH Q 5 A_NoBlocking
    ZCCH R 5
    ZCCH S 5
    ZCCH T 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLFormerCommandoKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
		
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    ZCCH N 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, 2)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_TakeInventory ("RLFormerCommandoChaingunShotCounter", 40)
    ZCCH N 5
    ZCCH M 5
    ZCCH L 5
    ZCCH K 5
    ZCCH J 5
    ZCCH I 5
    ZCCH H 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_ChangeFlag ("ALWAYSFAST", 1)
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1) 
    TNT1 A 0 A_ChangeFlag ("SEEINVISIBLE", 1)
    TNT1 A 0 A_ChangeFlag ("MISSILEMORE", 1)
    Goto RaiseContinue
	
  CrushDRLA:
    TNT1 A 0 A_SpawnItemEx("RLCrushedSmall",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
	
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 E 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 E 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0 A_GiveInventory ("RLFormerCommandoKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLNeuralStunStars", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION | SXF_SETMASTER)
    TNT1 A 0 A_Stop
    TNT1 A 0 ThrustThingZ (0, 20, 0, 0)
    CKD1 C -1
    Stop
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 400, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLFormerCommandoKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 400, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLFormerCommandoKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  Duke2LaserAttack:
    ZCCH U 10 A_FaceTarget
  Duke2LaserRepeat:
    ZCCH F 3 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-8,8), CMF_OFFSETPITCH, frandom(-4,4))
    ZCCH U 1
    ZCCH E 3 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-8,8), CMF_OFFSETPITCH, frandom(-4,4))
    ZCCH U 1
	TNT1 A 0 A_MonsterRefire (100, "See")
    Goto RepeatSpecialAttackCheck
	
  ShadowAuraMissileAttack:
    ZCCH U 15 A_FaceTarget
  ShadowAuraRepeatAttack:
    TNT1 A 0 A_PlaySound("rlmonsters/bulletstormchaingun", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/bulletstormchaingun", CHAN_ITEM, 0.05, 0, 0.20)
    TNT1 A 0 A_JumpIfInventory ("RLFormerCommandoChaingunStateCounter", 1, "ShadowAuraMissileAttackAlt")
    TNT1 A 0 A_GiveInventory ("RLFormerCommandoChaingunStateCounter", 1)
    ZCCH F 3 Bright A_CustomBulletAttack (11, 0, 1, random(1,5) * 4, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ZCCH U 1 A_MonsterRefire(30, "MissileEnd")
    Goto RepeatSpecialAttackCheck
  ShadowAuraMissileAttackAlt:
    TNT1 A 0 A_TakeInventory ("RLFormerCommandoChaingunStateCounter", 1)
    ZCCH E 3 Bright A_CustomBulletAttack (11, 0, 1, random(1,5) * 4, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ZCCH U 1 A_MonsterRefire(30, "MissileEnd")
    Goto RepeatSpecialAttackCheck
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MinorManaPod",-1,54)
    ZCCH G 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		ZCCH G 0 A_SpawnItemEx("Midas_Statue_ChaingunGuy", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		ZCCH G 0 A_SpawnItemEx("Midas_Statue_ChaingunGuy", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		ZCCH G 0 A_SpawnItemEx("Midas_Statue_ChaingunGuy", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		ZCCH G 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		ZCCH G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		ZCCH G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

Actor RLFormerCommandoChaingunShotCounter : Inventory
{
inventory.maxamount 40
}

Actor RLFormerCommandoChaingunStateCounter : Inventory
{
inventory.maxamount 1
}

ACTOR RLDRPGSummonedFormerCommando : RLFormerCommandoChaingun
{
  -COUNTKILL
  +AVOIDMELEE
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCFormerCommandoChaingun : RLFormerCommandoChaingun
{
  +TOUCHY
  States
  {
  See:
    ZCCH AABBCCDD 3
    Loop
  Missile:
    ZCCH U 10
    ZCCH E 3 Bright
    ZCCH U 1
    ZCCH F 3 Bright
    ZCCH U 1
    ZCCH E 3 Bright
    ZCCH U 1
    ZCCH F 3 Bright
    ZCCH U 1
    ZCCH E 3 Bright
    ZCCH U 6
    Goto See
  Melee:
    Stop
  Death:
    ZCCH H 5
    ZCCH I 5 A_Scream
    ZCCH J 5 A_NoBlocking
    ZCCH K 5
    ZCCH L 5
    ZCCH M 5
    ZCCH N -1
    Stop
  }
}

//==============================================================================
//							MONSTER'S ITEM POOL

ACTOR RLFormerCommandoChaingunDrop : RLEnemyWeaponDrop
{
	States
	{
	WeaponDrop: // Drops for DRLA Arsenal + Monsterpack
		TNT1 A 0 A_DropItem("RLChaingunPickup")
		Stop
	WeaponDropNoArsenal: // Drops for Monsterpack
		TNT1 A 0 A_DropItem("Chaingun")
		Stop
	WeaponDropVanilla: // Drops for Monsterpack if vanilla drops option is enabled
		TNT1 A 0 A_DropItem("Chaingun")
		Stop
	DonutstealDrop: // Drops for Demonsteele
		TNT1 A 0 A_DropItem("ClipBox")
		Stop
	}
}
