
// FORMER HUMAN
//
ACTOR RLFormerHumanBattleRifle2 : RLZombiemanBase
{
  Health 20
  
  Obituary "%o was finished off by a Former Human."
  Tag "Former Human [Battle Rifle]"
    //$category "MP Standard"
  
	DropItem "RLFormerHumanBattleRifleDrop"
	// Guncaster compatibility
	DropItem "Dosh1"
	DropItem "Dosh1"
	DropItem "Dosh1"
	DropItem "Dosh1", 192
	DropItem "Dosh1", 192
	DropItem "Dosh5", 128
  States
  {
  Spawn:
    ZHR2 V Random(9,10) A_Look
    Loop
	
  See:
    TNT1 A 0 A_JumpIfInventory ("RLFormerHumanBattleRifleShotCounter", 20, "RetreatReload")
    ZHR2 AABBCCDD 4 A_Chase ("", "Missile")
    Loop
  RetreatReload:
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 1)
    ZHR2 AA 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (32, "Reload")
    ZHR2 BB 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (32, "Reload")
    ZHR2 CC 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (32, "Reload")
    ZHR2 DD 3 A_Wander
    TNT1 A 0 A_JumpIfCloser (180, 2)
    TNT1 A 0 A_Jump (32, "Reload")
    TNT1 A 0
    Goto RetreatReload+1
	
  MissileProper:
    ZHR2 E 10 A_FaceTarget
    TNT1 A 0 A_JumpIfInventory ("RLFormerHumanBattleRifleShotCounter", 20, "RetreatReload")
    TNT1 A 0 A_GiveInventory ("RLFormerHumanBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    ZHR2 F 4 Bright A_CustomBulletAttack (16, 0, 1, random(1,5) * 3, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ZHR2 E 8
    Goto See
	
  Reload:
    ZHR2 EE 4 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifleunload", 7)
    ZHR2 EEEEEEEE 4 A_FaceTarget
    ZHR2 E 2 A_FaceTarget
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_PlaySound("rlmonsters/battlerifleload", 7)
    TNT1 A 0 A_TakeInventory ("RLFormerHumanBattleRifleShotCounter", 20)
    ZHR2 EE 5 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/battleriflecock", 5)
    ZHR2 E 6 A_FaceTarget
    Goto See
	
  PainMain:
    ZHR2 G 3
    ZHR2 G 3 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLFormerHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    ZHR2 H 5
    ZHR2 I 5 A_Scream
    ZHR2 J 5 A_NoBlocking
    ZHR2 K 5
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    ZHR2 L 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    ZHR2 L 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLFormerHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    ZHR2 M 5
    ZHR2 N 5 A_XScream
    ZHR2 O 5 A_NoBlocking
    ZHR2 PQ 5
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    ZHR2 RST 5
    ZHR2 U 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLFormerHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    ZHR2 M 5
    ZHR2 N 5 A_XScream
    ZHR2 O 5 A_NoBlocking
    ZHR2 PQ 5
    ZHR2 RST 5
    ZHR2 U 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLFormerHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    ZHR2 L 2
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
  RaiseContinue:
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, 2)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag ("FRIGHTENED", 0)
    TNT1 A 0 A_TakeInventory ("RLFormerHumanBattleRifleShotCounter", 20)
    ZHR2 K 5
    ZHR2 J 5
    ZHR2 I 5
    ZHR2 H 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_ChangeFlag ("ALWAYSFAST", 1)
    Goto RaiseContinue
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1) 
    TNT1 A 0 A_ChangeFlag ("SEEINVISIBLE", 1)
    TNT1 A 0 A_ChangeFlag ("MISSILEMORE", 1)
    Goto RaiseContinue
	
  CrushDRLA:
    TNT1 A 0 A_SpawnItemEx("RLCrushedSmall",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
	
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 B 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 B 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0 A_GiveInventory ("RLFormerHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLNeuralStunStars", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION | SXF_SETMASTER)
    TNT1 A 0 A_Stop
    TNT1 A 0 ThrustThingZ (0, 20, 0, 0)
    CKD1 A -1
    Stop
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 100, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLFormerHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 100, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLFormerHumanKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  Duke2LaserAttack:
    ZHR2 E 10 A_FaceTarget
    ZHR2 F 4 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 30, 12, frandom(-3,3), CMF_OFFSETPITCH, frandom(-3,3))
    ZHR2 E 8
    Goto See
	
  ShadowAuraMissileAttack:
    ZHR2 E 15 A_FaceTarget
  ShadowAuraRepeatAttack:
    TNT1 A 0 A_JumpIfInventory ("RLFormerHumanBattleRifleShotCounter", 14, "Reload")
    TNT1 A 0 A_GiveInventory ("RLFormerHumanBattleRifleShotCounter", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/hpbattlerifle", CHAN_WEAPON, 1, 0, 0.6)
    TNT1 A 0 A_PlaySound("rlmonsters/hpbattlerifle", CHAN_ITEM, 0.05, 0, 0.20)
    ZHR2 F 2 Bright A_CustomBulletAttack (8, 0, 1, random(1,7) * 5, "RLEnemyBulletPuff", 0, CBAF_NORANDOM)
    ZHR2 E 2
    TNT1 A 0 A_MonsterRefire (0, "See")
    TNT1 A 0 A_JumpIfInventory("DRPGShadowAuraToken", 1, "ShadowAuraRepeatAttack")
    Goto See
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MinorManaPod",-1,54)
    ZHR2 G 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		ZHR2 G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		ZHR2 G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		ZHR2 G 0 A_SpawnItemEx("Midas_Statue_Zombieman", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		ZHR2 G 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		ZHR2 G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		ZHR2 G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}
