
// HELL KNIGHT
//
ACTOR RLHellKnight : RLHellKnightBase 16409
{
  Health 500
  GibHealth -75
  
  PainSound "hellknight/pain"
  
  Obituary "%o was finished off by a Hell Knight."
  HitObituary "%o was opened up like a tin can by a Hell Knight."
  Tag "Hell Knight"
    //$category "MP Standard"
  
	// Guncaster compatibility
	DropItem "Ruby"
  States
  {
  Spawn:
    HKNI BD Random(9,10) A_Look
    Goto Spawn
	
  See:
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 2) // Friendly monsters do not use commands
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, "CommandMissile")
    HKNI A 3 A_Chase
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 2) // Friendly monsters do not use commands
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, "CommandMissile")
    HKNI A 3 A_Chase
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 2) // Friendly monsters do not use commands
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, "CommandMissile")
    HKNI B 3 A_Chase
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 2) // Friendly monsters do not use commands
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, "CommandMissile")
    HKNI B 3 A_Chase
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 2) // Friendly monsters do not use commands
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, "CommandMissile")
    HKNI C 3 A_Chase
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 2) // Friendly monsters do not use commands
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, "CommandMissile")
    HKNI C 3 A_Chase
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 2) // Friendly monsters do not use commands
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, "CommandMissile")
    HKNI D 3 A_Chase
    TNT1 A 0 A_CheckFlag ("FRIENDLY", 2) // Friendly monsters do not use commands
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, "CommandMissile")
    HKNI D 3 A_Chase
    Loop
	
  MissileHatredOnUniqueEffect: // [incoherent tantrum sounds]
    "####" "#" 0 A_PlaySound ("knight/sight", CHAN_VOICE)
    "####" "#" 0 A_Jump (256, "MissileHatredOnUniqueDone")
	Goto MissileHatredOnUniqueDone
  MeleeHatredOnUniqueEffect: // [incoherent tantrum sounds]
    "####" "#" 0 A_PlaySound ("knight/sight", CHAN_VOICE)
    "####" "#" 0 A_Jump (256, "MeleeHatredOnUniqueDone")
	Goto MeleeHatredOnUniqueDone
	
  MeleeProper:
  MissileProper:
    TNT1 A 0 A_JumpIfInventory ("RLHellKnightArmToken", 1, "Missile2")
    HKNI EF 8 A_FaceTarget
    TNT1 A 0 A_GiveInventory ("RLHellKnightArmToken", 1)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    HKNI G 8 A_CustomComboAttack("RLHellKnightPlasmaBall", 32, 8 * random(1, 8), "baron/melee")
    TNT1 A 0 A_Jump (64, "Missile")
    Goto See
  Missile2:
    HKNI PQ 8 A_FaceTarget
    TNT1 A 0 A_TakeInventory ("RLHellKnightArmToken", 1)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile2") // Friendly monsters do not harm you
    HKNI R 8 A_CustomComboAttack("RLHellKnightPlasmaBall", 32, 8 * random(1, 8), "baron/melee")
    TNT1 A 0 A_Jump (64, "Missile")
    Goto See
	
  SummonMissile:
    HKNI G 8 A_CustomComboAttack("RLSummonHellKnightPlasmaBall", 32, 8 * random(1, 8), "baron/melee")
    TNT1 A 0 A_Jump (64, "Missile")
    Goto See
  SummonMissile2:
    HKNI R 8 A_CustomComboAttack("RLSummonHellKnightPlasmaBall", 32, 8 * random(1, 8), "baron/melee")
    TNT1 A 0 A_Jump (64, "Missile")
    Goto See
	
  CommandMissile:
    TNT1 A 0 A_JumpIfInventory ("RLHellKnightArmToken", 1, 3)
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, 1)
    Goto CommandMissile1
    HKNI E 1 A_FaceTarget
    Goto CommandMissile
    TNT1 A 0 A_JumpIfInventory("PowerRLNightmareBaronCommand", 1, 1)
    Goto CommandMissile1
    HKNI P 1 A_FaceTarget
    Goto CommandMissile
  CommandMissile1:
    TNT1 A 0 A_JumpIfInventory ("RLHellKnightArmToken", 1, "CommandMissile2")
    HKNI EF 4 A_FaceTarget
    TNT1 A 0 A_GiveInventory ("RLHellKnightArmToken", 1)
    HKNI G 4 A_CustomMissile("RLHellKnightPlasmaBall",32,4,frandom(0, 4))
    TNT1 A 0 A_MonsterRefire (0, "See")
    Goto CommandMissile1
  CommandMissile2:
    HKNI PQ 4 A_FaceTarget
    TNT1 A 0 A_TakeInventory ("RLHellKnightArmToken", 1)
    HKNI R 4 A_CustomMissile("RLHellKnightPlasmaBall",32,-4,frandom(-4, 0))
    TNT1 A 0 A_MonsterRefire (0, "See")
    Goto CommandMissile1
	
  PainMain:
    TNT1 A 0 A_TakeInventory ("PowerRLNightmareBaronCommand", 1)
    HKNI H 2
    HKNI H 2 A_Pain
    Goto See

  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLHellKnightKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_GiveInventory ("RLMonsterKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills of all enemies
    TNT1 A 0 A_Jump (96, "Death2")
    HKNI I 8
    HKNI J 8 A_Scream
    HKNI K 8
    HKNI L 8 A_NoBlocking
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    HKNI MN 8
    HKNI O 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  Death2:
    HKNI S 8
    HKNI T 8 A_Scream
    HKNI UV 8
    HKNI W 8 A_NoBlocking
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    HKNI X 8
    HKNI Y 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    HKNI O 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLHellKnightKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_GiveInventory ("RLMonsterKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills of all enemies
    HKN2 A 1
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_PlaySound ("misc/gibbed", 5)
    HKN2 A 3 A_Scream
    HKN2 BC 4
    HKN2 D 4 A_NoBlocking
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    HKN2 E 4
    HKN2 FGH 4
    HKN2 I 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLHellKnightKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    HKN2 A 1
    HKN2 A 3 A_Scream
    HKN2 BC 4
    HKN2 D 4 A_NoBlocking
    HKN2 E 4
    HKN2 FGH 4
    HKN2 I 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLHellKnightKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    HKNI O 2
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    HKNI O 8
    HKNI NMLKJI 8
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_Die ("NightmareRemoval")
  Death.NightmareRemoval:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareHellKnightReborn", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Stop
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_Die ("CyberneticRemoval")
  Death.CyberneticRemoval:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticHellKnightReborn", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Stop
	
  CrushDRLA:
    TNT1 A 0 A_SpawnItemEx("RLCrushedMediumGreen",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 L 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 L 2 Bright
    Goto See
	
  Death.NeuralStun:
    TNT1 A 0 A_GiveInventory ("RLHellKnightKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLNeuralStunStarsBig", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION | SXF_SETMASTER)
    TNT1 A 0 A_Stop
    TNT1 A 0 ThrustThingZ (0, 20, 0, 0)
    CKD1 G -1
    Stop
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 800, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLHellKnightKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 800, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLHellKnightKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2Gibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMeleeAttack:
  ShadowAuraMissileAttack:
    TNT1 A 0 A_JumpIfInventory ("RLHellKnightArmToken", 1, "ShadowAuraMissileAttack2")
    HKNI EF 5 A_FaceTarget
    TNT1 A 0 A_GiveInventory ("RLHellKnightArmToken", 1)
    TNT1 AA 0 A_CustomMissile ("RLHellKnightPlasmaBall", 32, 0, frandom(6,-6), CMF_OFFSETPITCH, frandom(2,-2))
    HKNI G 6 A_CustomMissile ("RLHellKnightPlasmaBall", 32, 0, frandom(6,-6), CMF_OFFSETPITCH, frandom(2,-2))
    Goto See
  ShadowAuraMissileAttack2:
    HKNI PQ 5 A_FaceTarget
    TNT1 A 0 A_TakeInventory ("RLHellKnightArmToken", 1)
    TNT1 AA 0 A_CustomMissile ("RLHellKnightPlasmaBall", 32, 0, frandom(6,-6), CMF_OFFSETPITCH, frandom(2,-2))
    HKNI R 6 A_CustomMissile ("RLHellKnightPlasmaBall", 32, 0, frandom(6,-6), CMF_OFFSETPITCH, frandom(2,-2))
    Goto See
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    HKNI H 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		HKNI H 0 A_SpawnItemEx("Midas_Statue_Hellknight", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		HKNI H 0 A_SpawnItemEx("Midas_Statue_Hellknight", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		HKNI H 0 A_SpawnItemEx("Midas_Statue_Hellknight", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		HKNI H 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		HKNI H 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		HKNI H 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

ACTOR RLHellKnightPlasmaBall : BaronBall
{
   +NOTIMEFREEZE
   +THRUGHOST
   +BLOODSPLATTER
   Decal "BaronScorch"
   DamageType "Plasma"
   PainType "HellNobleFire"
   DeathType "HellNobleFire"
   Damage 6
  States
  {
  Spawn:
    BAL7 AB 4 Bright
    Goto Spawn
//  Death:
//    BAL7 CDE 6 Bright
//    Stop
  }
}

ACTOR RLSummonHellKnightPlasmaBall : RLHellKnightPlasmaBall
{
   +MTHRUSPECIES
}

Actor RLHellKnightArmToken : Inventory
{
inventory.maxamount 1
}

ACTOR RLDRPGSummonedHellKnight : RLHellKnight
{
  -COUNTKILL
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCHellKnight : RLHellKnight
{
  +TOUCHY
  States
  {
  Spawn:
    HKNI BD 10 A_Look
    Loop
  See:
    HKNI AABBCCDD 3
    Loop
  Melee:
    HKNI PQ 8
    HKNI R 8
    Goto See
  Missile:
    HKNI EF 8
    HKNI G 8
    Goto See
  Death:
    HKNI I 8
    HKNI J 8 A_Scream
    HKNI K 8
    HKNI L 8 A_NoBlocking
    HKNI MN 8
    HKNI O -1
    Stop
  }
}
