
// MANCUBUS
//
ACTOR RLMancubus : RLMancubusBase 16414
{
  Health 600
  GibHealth -100
  
  DamageFactor "Fire", 1.2
  DamageFactor "Ice", 0.7
  
  Obituary "%o was incinerated by a Mancubus."
  Tag "Mancubus"
    //$category "MP Standard"
  
	// Guncaster compatibility
	DropItem "Amber", 192
	DropItem "Ruby", 128
  States
  {
  Spawn:
    MANC CF Random(14,15) A_Look
    Loop
	
  See:
    MANC AABBCCDDEEFF 4 A_Chase ("", "Missile")
    Loop
	
  MissileProper:
    TNT1 A 0 A_PlaySound("fatso/raiseguns", CHAN_VOICE)
    MANC G 20 A_FaceTarget
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, -29, 0)
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, 26, 0)
    TNT1 A 0 A_CustomMissile("RLMancubusFireball", 20, -29, 20)
    MANC H 10 Bright A_CustomMissile("RLMancubusFireball", 20, 26, 0)
    MANC IG 5 A_FaceTarget
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, -29, 0)
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, 26, 0)
    TNT1 A 0 A_CustomMissile("RLMancubusFireball", 20, -29, 0)
    MANC H 10 Bright A_CustomMissile("RLMancubusFireball", 20, 26, -20)
    MANC IG 5 A_FaceTarget
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, -29, 0)
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, 26, 0)
    TNT1 A 0 A_CustomMissile("RLMancubusFireball", 20, -29, 10)
    MANC H 10 Bright A_CustomMissile("RLMancubusFireball", 20, 26, -10)
    MANC IG 5
    Goto See
	
  SummonMissile:
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, -29, 0)
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, 26, 0)
    TNT1 A 0 A_CustomMissile("RLSummonMancubusFireball", 20, -29, 20)
    MANC H 10 Bright A_CustomMissile("RLSummonMancubusFireball", 20, 26, 0)
    MANC IG 5 A_FaceTarget
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, -29, 0)
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, 26, 0)
    TNT1 A 0 A_CustomMissile("RLSummonMancubusFireball", 20, -29, 0)
    MANC H 10 Bright A_CustomMissile("RLSummonMancubusFireball", 20, 26, -20)
    MANC IG 5 A_FaceTarget
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, -29, 0)
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, 26, 0)
    TNT1 A 0 A_CustomMissile("RLSummonMancubusFireball", 20, -29, 10)
    MANC H 10 Bright A_CustomMissile("RLSummonMancubusFireball", 20, 26, -10)
    MANC IG 5
    Goto See
	
  PainMain:
    MANC J 3
    MANC J 3 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLMancubusKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_Jump(96, "Death2")
    MANC K 6
    MANC L 6 A_Scream
    MANC M 6 A_NoBlocking
    MANC N 6
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    MANC OPQRS 6
    MANC T 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  Death2:
    MNC2 A 7
    MNC2 B 7 A_Scream
    MNC2 C 7 A_NoBlocking
    MNC2 DEF 5
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    MNC2 GHI 5
    MNC2 J 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    MANC T 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLMancubusKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
    TNT1 A 0 A_BossDeath
    MNC2 K 4 A_XScream
    MNC2 L 4 A_NoBlocking
    MNC2 MN 4
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    MNC2 O 4
    MNC2 P 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLMancubusKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    MNC2 K 4 A_XScream
    MNC2 L 4 A_NoBlocking
    MNC2 MN 4
    MNC2 O 4
    MNC2 P 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLMancubusKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    MANC T 2
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    MANC R 5
    MANC QPONMLK 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_Die ("NightmareRemoval")
  Death.NightmareRemoval:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareMancubusReborn", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Stop
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_Die ("CyberneticRemoval")
  Death.CyberneticRemoval:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticMancubusReborn", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Stop
	
  CrushDRLA:
    "####" "#" 0 A_BossDeath
    TNT1 A 0 A_SpawnItemEx("RLCrushedMedium",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 P 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 P 2 Bright
    Goto See
  Pain.CyberDisruptor:
    TNT1 A 0
    Goto Pain.LightningBlue
	
  Death.NeuralStun:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLMancubusKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLNeuralStunStarsBig", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION | SXF_SETMASTER)
    TNT1 A 0 A_Stop
    TNT1 A 0 ThrustThingZ (0, 20, 0, 0)
    CKD1 I -1
    Stop
  Death.RigelBlast:
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLMancubusKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2AdvancedEnemyExplosions", 0,0,32, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_BossDeath
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 1000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLMancubusKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2AdvancedEnemyExplosions", 0,0,32, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMissileAttack:
    TNT1 A 0 A_PlaySound("fatso/raiseguns", CHAN_VOICE)
    MANC G 20 A_FaceTarget
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, -29, 0)
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, 26, 0)
    TNT1 A 0 A_CustomMissile("RLMancubusGrenade", 20, -29, 20)
    MANC H 10 Bright A_CustomMissile("RLMancubusGrenade", 20, 26, 0)
    MANC IG 5 A_FaceTarget
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, -29, 0)
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, 26, 0)
    TNT1 A 0 A_CustomMissile("RLMancubusGrenade", 20, -29, 0)
    MANC H 10 Bright A_CustomMissile("RLMancubusGrenade", 20, 26, -20)
    MANC IG 5 A_FaceTarget
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, -29, 0)
    TNT1 A 0 A_CustomMissile("RLMancubusSmoke", 20, 26, 0)
    TNT1 A 0 A_CustomMissile("RLMancubusGrenade", 20, -29, 10)
    MANC H 10 Bright A_CustomMissile("RLMancubusGrenade", 20, 26, -10)
    MANC IG 5
    Goto See
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    MANC J 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		MANC J 0 A_SpawnItemEx("Midas_Statue_Fatality", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		MANC J 0 A_SpawnItemEx("Midas_Statue_Fatality", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		MANC J 0 A_SpawnItemEx("Midas_Statue_Fatality", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		MANC J 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		MANC J 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		MANC J 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

ACTOR RLMancubusFireBall : FatShot
{
   +NOTIMEFREEZE
   +THRUGHOST
   +BLOODSPLATTER
   Decal "Scorch"
   DamageType "Fire"
  States
  {
  Spawn:
    MANF AB 4 Bright
    Goto Spawn
  Death:
    MEXP A 4 Bright
    MEXP B 4 Bright
    MEXP C 3 Bright
    MEXP D 3 Bright
    MEXP E 2 Bright
    MEXP F 2 Bright
    Stop
  }
}

ACTOR RLSummonMancubusFireBall : RLMancubusFireBall
{
   +MTHRUSPECIES
}

ACTOR RLMancubusGrenade : Rocket
{
  Radius 6
  Height 4
  Speed 20
  Damage (8*random(2,3))
  DamageType "Fire"
  PainType "Explosion"
  DeathType "Explosion"
  Gravity 0.65
  BounceType "Doom"
  BounceFactor 0.25
  WallBounceFactor 0.5
  BounceCount 5
  ReactionTime 139
  +MTHRUSPECIES
  +THRUGHOST
  +NOTIMEFREEZE
  +BLOODSPLATTER
  +USEBOUNCESTATE
  +EXPLODEONWATER
  -RANDOMIZE
  -DEHEXPLOSION
  BounceSound "rlmonsters/grenadebounce"
  DeathSound ""
  Obituary "%o was not expecting a super destructive Mancubus."
  States
  {
  Spawn:
    TNT1 A 0 A_CountDown
    TBO1 A 1 Bright
    Loop
  Bounce:
    TNT1 A 0 A_ChangeFlag ("NOGRAVITY", 0)
    TNT1 A 0 A_CountDown
    TBO1 A 1 Bright
    Goto Spawn
  Death:
    TNT1 A 0 A_ChangeFlag ("NOGRAVITY", 1)
    TNT1 A 0 A_Stop
    TNT1 A 0 A_SetTranslucent (0.95, 1)
    TNT1 A 0 A_Explode (32,96,1)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 3)
    TNT1 A 0 A_Quake (1, 8, 0, 1024, "")
    TNT1 A 0 A_Quake (6, 8, 0, 512, "")
	TNT1 A 0 A_JumpIf(CallACS("GnuCustardCheck"), "GuncasterImpact")
    TNT1 A 0 A_PlaySound ("weapons/rocklx", 7, 1, 0, 0.5)
    TNT1 A 0 A_PlaySound("weapons/rocklx", CHAN_ITEM, 0.05, 0, 0.05)
    TNT1 A 0 A_CheckFloor ("FloorDeathAnimation")
	Goto DeathAnimation
  DeathAnimation:
    MEXP A 4 Bright
    MEXP B 4 Bright
    MEXP C 3 Bright
    MEXP D 3 Bright
    MEXP E 2 Bright
    MEXP F 2 Bright
    Stop
  FloorDeathAnimation:
    GLXP ABCDEFGHIJ 2 Bright
    Stop
	
  GuncasterImpact:
    TNT1 A 0 A_PlaySound("Matriarch/Hit", 5, 0.8)
    TNT1 A 0 A_PlaySound("Matriarch/Exp", 6, 1.0)
    TNT1 A 0 A_PlaySound("Matriarch/Exp", CHAN_ITEM, 0.05, 0, 0.05)
    TNT1 A 0 A_SpawnItemEx("RLGuncasterMonsterExplosion", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    Stop
  }
}

ACTOR RLMancubusSmoke
{
   Projectile 
   Radius 8
   Height 8
   Speed 2
   VSpeed 5
   Scale 0.4
   Damage 0
   RENDERSTYLE ADD
   Alpha 0.95
   +NOCLIP
   +NOINTERACTION
   +NOTONAUTOMAP
   States
   {
   Spawn:
   SMK2 ABCDEFGHIJKLMNOPQ 1 
   Stop
   }
}

ACTOR RLDRPGSummonedMancubus : RLMancubus
{
  -COUNTKILL
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCMancubus : RLMancubus
{
  +TOUCHY
  States
  {
  Missile:
    MANC G 20
    MANC H 10 Bright
    MANC IG 5
    MANC H 10 Bright
    MANC IG 5
    MANC H 10 Bright
    MANC IG 5
    Goto See
  Melee:
    Stop
  Death:
    MANC K 6
    MANC L 6 A_Scream
    MANC M 6 A_NoBlocking
    MANC N 6
    MANC OPQRS 6
    MANC T -1 A_BossDeath
    Stop
  }
}
