
// PAIN ELEMENTAL
//
ACTOR RLPainElemental : RLPainElementalBase 16412
{
  Health 400
  GibHealth -80
  
  DamageFactor "Ice", 1.25
  
  Obituary "%o was overwhelmed by a Pain Elemental."
  HitObituary "%o forgot the Pain Elemental has teeth too."
  Tag "Pain Elemental"
    //$category "MP Standard"
  
	// Guncaster compatibility
	DropItem "Emerald"
  States
  {
  Spawn:
    PELE A Random(9,10) A_Look
    Loop
	
  See:
    PELE AABBCCBB 3 A_Chase
    Loop
	
  MeleeProper:
    PELE DNOO 3 A_FaceTarget
    TNT1 A 0 A_FaceTarget
    PELE N 1 A_CustomMeleeAttack (6 * random(1, 10), "rlmonsters/bite", "", "Melee")
    PELE D 1 A_FaceTarget
    Goto See
	
  MissileProper:
    PELE DE 5 A_FaceTarget
    PELE F 4 Bright A_FaceTarget
    PELE F 1 Bright A_PainAttack ("RLLostSoulPE")
    PELE ED 3 A_Chase ("", "")
    Goto See
	
  PainMain:
    PELE G 6
    PELE G 6 A_Pain
    Goto See
	
  XDeathMain:
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLPainElementalKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    PELE H 8
    PELE I 8 A_Scream
    PELE JK 8 Bright
    TNT1 A 0 A_SpawnItemEx ("RLReducedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
//    TNT1 A 0 A_JumpIfTargetInLOS (3,0, JLOSF_DEADNOJUMP | JLOSF_ALLYNOJUMP)
    PELE L 8 Bright A_PainDie ("RLLostSoulPE")
    PELE M 8 Bright
	TNT1 A 0
    "####" "#" 0 A_Jump(256, "DestroyedEnd")
    Goto DestroyedEnd
  SimpleXDeathMain:
    TNT1 A 0 A_GiveInventory ("RLPainElementalKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    PELE H 8
    PELE I 8 A_Scream
    PELE JK 8 Bright
    PELE L 8 Bright
    PELE M 8 Bright
	TNT1 A 0
    "####" "#" 0 A_Jump(256, "DestroyedEnd")
    Goto DestroyedEnd
  DeathFrame:
    TNT1 A 0
    "####" "#" 0 A_Jump(256, "DestroyedEnd")
    Goto DestroyedEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLPainElementalKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  CrushDRLA:
    TNT1 A 0 A_SpawnItemEx("RLCrushedMedium",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 N 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 N 2 Bright
    Goto See
	
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 800, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLPainElementalKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2AdvancedEnemyExplosions", 0,0,32, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
  XDeath.RigelBlast:
	TNT1 A 0 A_JumpIf(CallACS("DRLA_Gibs"), 1)
	Goto Death.RigelBlast
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 800, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLPainElementalKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gungib", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2AdvancedEnemyExplosions", 0,0,32, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RedGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMissileAttack:
    PELE DE 5 A_FaceTarget
    PELE FF 2 Bright A_PainAttack ("RLLostSoulAgony", frandom(-30,30))
    PELE F 1 Bright
    PELE ED 3 A_Chase ("", "")
    Goto See
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    PELE G 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		PELE G 0 A_SpawnItemEx("Midas_Statue_Painis", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		PELE G 0 A_SpawnItemEx("Midas_Statue_Painis", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		PELE G 0 A_SpawnItemEx("Midas_Statue_Painis", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		PELE G 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		PELE G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		PELE G 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
		
		// Overwrite these for monsters that do not leave corpses behind
	//Dreadful
	Death.Tiberium:
		"####" "#" 0 A_Jump(256, "Death")
		Goto Death
	Death.BlueTiberium:
		"####" "#" 0 A_Jump(256, "Death")
		Goto Death
	//Fire and Lightning
	Death.Fire:
		"####" "#" 0 A_Jump(256,"Death")
		Goto Death
  }
}

ACTOR RLPainElementalAgony : RLPainElemental
{
  +NOINFIGHTING
  -COUNTKILL
  States
  {
  Spawn:
    TNT1 A 0 NoDelay A_JumpIfInventory ("RLMonsterInitializerToken", 1, "NotInTheFuckingVoid")
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_JumpIfTargetInLOS ("NotInTheFuckingVoid", 0)
	Stop
  NotInTheFuckingVoid:
    PELE A 10 A_Look
    Loop
  Missile:
    PELE DE 5 A_FaceTarget
    PELE F 4 Bright A_FaceTarget
    PELE F 1 Bright A_PainAttack ("RLLostSoulAgony")
    PELE ED 3 A_Chase ("", "")
    Goto See
  Death:
    PELE H 8
    PELE I 8 A_Scream
    PELE JK 8 Bright
    PELE L 8 Bright A_PainDie ("RLLostSoulAgony")
    PELE M 8 Bright
	TNT1 A 0
    "####" "#" 0 A_Jump(256, "DestroyedEnd")
    Goto DestroyedEnd
	
  DestroyedEnd:  // Redefined here so that Pain Elemental corpses do not linger
    "####" "#" 0
    Stop
  }
}

ACTOR RLDRPGSummonedPainElemental : RLPainElemental
{
  -COUNTKILL
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCPainElemental : RLPainElemental
{
  +TOUCHY
  States
  {
  See:
    PELE AABBCCBB 3
    Loop
  Melee:
    PELE DNOO 3
    PELE ND 1
    Goto See
  Missile:
    PELE DE 5
    PELE F 4 Bright
    PELE F 1 Bright
    PELE ED 3
    Goto See
  Death:
    PELE H 8
    PELE I 8 A_Scream
    PELE JK 8 Bright
    PELE L 8 Bright
    PELE M 8 Bright
    Stop
  }
}
