
// REVENANT
//
ACTOR RLRevenant : RLRevenantBase 16413
{
  Health 150
  GibHealth -75
  
  DamageFactor "Bullet", 0.5
  DamageFactor "Fire", 0.75
  DamageFactor "Ice", 0.8
  
  ActiveSound "revenant/aaaactive"
  PainSound "revenant/pain"
  
  Obituary "%o was unable to escape a Revenant."
  HitObituary "%o was slugged by a Revenant."
  Tag "Revenant"
    //$category "MP Standard"
  
	// Guncaster compatibility
	DropItem "Ruby"
  States
  {
  Spawn:
    REVE BE Random(9,10) A_Look
    Loop
	
  See:
    TNT1 A 0 A_CheckSight ("Unsee")
    REVE AABBCCDDEEFF 2 A_Chase
    Loop
  UnSee: // Secret Morse Code
    REVE AABBCCDDEEFF 2 A_Chase ("Melee", "Missile", CHF_NOPLAYACTIVE | CHF_NIGHTMAREFAST )
    TNT1 A 0 A_Jump (240, "See")
    TNT1 A 0 A_Jump (14, 2) // Morse code enabled
    TNT1 A 0 A_PlaySound("revenant/active", CHAN_VOICE)
    Goto See
    TNT1 A 0 A_PlaySound("revenant/aaaactive", CHAN_VOICE)
    Goto See
	
  MeleeProper:
    REVE G 1 A_FaceTarget
    TNT1 A 0 A_PlaySound("skeleton/swing", CHAN_VOICE)
    REVE G 6 A_FaceTarget
    REVE H 6 A_FaceTarget
    REVE I 6 A_CustomBulletAttack (0, 0, 1, (6 * random(1, 10)), "RLEnemyRevenantBluntMeleePuff", 50, CBAF_NORANDOM | CBAF_AIMFACING)
//    REVE I 6 A_CustomMeleeAttack (6 * random(1, 10), "skeleton/melee", "", "Melee")
    Goto See
	
  MissileProper:
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    REVE Z 8 A_FaceTarget
    TNT1 A 0 A_FaceTarget
    TNT1 A 0 A_JumpIfCloser(2048, 1)
    Goto MissileNormal
    TNT1 A 0 A_Jump(128, "MissileHoming")
  MissileNormal:
    TNT1 A 0 A_JumpIfInventory("RLRevenantMissileToken", 1, 3)
    TNT1 A 0 A_CustomMissile("RLRevenantMissile", 52, 14, 0)
    TNT1 A 0 A_GiveInventory("RLRevenantMissileToken", 1)
    Goto MissileEnd
    TNT1 A 0 A_CustomMissile("RLRevenantMissile", 52, -14, 0)
    TNT1 A 0 A_TakeInventory("RLRevenantMissileToken", 1)
    Goto MissileEnd
  MissileHoming:
    TNT1 A 0 A_JumpIfInventory("RLRevenantMissileToken", 1, 3)
    TNT1 A 0 A_CustomMissile("RLRevenantHomingMissile", 52, 14, 0)
    TNT1 A 0 A_GiveInventory("RLRevenantMissileToken", 1)
    Goto MissileEnd
    TNT1 A 0 A_CustomMissile("RLRevenantHomingMissile", 52, -14, 0)
    TNT1 A 0 A_TakeInventory("RLRevenantMissileToken", 1)
    Goto MissileEnd
  MissileEnd:
    REVE J 8 Bright
    REVE K 14
    Goto See
	
  SummonMissile:
    REVE Z 8 A_FaceTarget
    TNT1 A 0 A_JumpIfCloser(2048, 1)
    Goto SummonMissileNormal
    TNT1 A 0 A_Jump(128, "SummonMissileHoming")
  SummonMissileNormal:
    TNT1 A 0 A_JumpIfInventory("RLRevenantMissileToken", 1, 3)
    TNT1 A 0 A_CustomMissile("RLSummonRevenantMissile", 52, 14, 0)
    TNT1 A 0 A_GiveInventory("RLRevenantMissileToken", 1)
    Goto MissileEnd
    TNT1 A 0 A_CustomMissile("RLSummonRevenantMissile", 52, -14, 0)
    TNT1 A 0 A_TakeInventory("RLRevenantMissileToken", 1)
    Goto MissileEnd
  SummonMissileHoming:
    TNT1 A 0 A_JumpIfInventory("RLRevenantMissileToken", 1, 3)
    TNT1 A 0 A_CustomMissile("RLSummonRevenantHomingMissile", 52, 14, 0)
    TNT1 A 0 A_GiveInventory("RLRevenantMissileToken", 1)
    Goto MissileEnd
    TNT1 A 0 A_CustomMissile("RLSummonRevenantHomingMissile", 52, -14, 0)
    TNT1 A 0 A_TakeInventory("RLRevenantMissileToken", 1)
    Goto MissileEnd
	
  PainMain:
    REVE L 5
    REVE L 5 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLRevenantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    REVE LM 7
    REVE N 7 A_Scream
    REVE O 7 A_NoBlocking
    TNT1 A 0 A_SpawnItem ("RLBodyThud", 0, 0, 0, 0)
    REVE P 7
    REVE Q 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    REVE Q 0
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
  XDeathMain:
    TNT1 A 0 A_GiveInventory ("RLRevenantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    REVE R 4
    TNT1 A 0 A_PlaySound ("misc/gibbed", 5)
    REVE S 4 A_Scream
    REVE T 4 A_NoBlocking
    REVE UVW 4
    TNT1 A 0 A_SpawnItem ("RLGibThud", 0, 0, 0, 0)
    REVE X 4
    REVE Y 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
  SimpleXDeathMain:
    REVE R 4
    REVE S 4 A_Scream
    REVE T 4 A_NoBlocking
    REVE UVW 4
    REVE X 4
    REVE Y 0
    "####" "#" 0 A_Jump(256, "XDeathEnd")
    Goto XDeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLRevenantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  Raise:
	TNT1 A 0 ACS_NamedExecuteAlways("DRLA_Normalization") // Removes any palette abnormalities
	TNT1 A 0 A_SetScale(1) // resets altered enemies to default, make sure to match the scale factor in properties here!
    TNT1 A 0 A_ChangeFlag ("NOBLOCKMAP", 0)
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 1)
    REVE Q 2
    TNT1 A 0 A_ChangeFlag ("NOPAIN", 0)
    TNT1 A 0 A_JumpIfInventory ("RLNightmareResurrectionToken", 1, "NightmareRaise")
    TNT1 A 0 A_JumpIfInventory ("RLCyberneticResurrectionToken", 1, "CyberneticRaise")
    TNT1 A 0 A_SpawnItemEx ("RLResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    REVE Q 5
    REVE PONML 5
    Goto See
  NightmareRaise:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareResurrectionFire", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    TNT1 A 0 A_Die ("NightmareRemoval")
  Death.NightmareRemoval:
    TNT1 A 0 A_SpawnItemEx ("RLNightmareRevenantReborn", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Stop
  CyberneticRaise:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticResurrectionSparks", 0, 0, 20, 0, 0, 0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_Die ("CyberneticRemoval")
  Death.CyberneticRemoval:
    TNT1 A 0 A_SpawnItemEx ("RLCyberneticRevenantReborn", 0, 0, 0, 0, 0, 0, 0, SXF_NOCHECKPOSITION) 
    Stop
	
  CrushDRLA:
    TNT1 A 0 A_SpawnItemEx("RLCrushedSmall",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 O 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 O 2 Bright
    Goto See
  Pain.CyberDisruptor:
    TNT1 A 0
    Goto Pain.LightningBlue
	
  Death.NeuralStun:
    TNT1 A 0 A_GiveInventory ("RLRevenantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLNeuralStunStars", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION | SXF_SETMASTER)
    TNT1 A 0 A_Stop
    TNT1 A 0 ThrustThingZ (0, 20, 0, 0)
    REVE Q -1
    Stop
  XDeath.RigelBlast:
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 500, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLRevenantKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunexplosion", CHAN_BODY)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SpawnItemEx ("RLDuke2BasicEnemyExplosions", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  ShadowAuraMissileAttack:
    REVE Z 8 A_FaceTarget
    TNT1 A 0 A_CustomMissile("RLRevenantHomingMissile", 52, 14, 0)
    TNT1 A 0 A_CustomMissile("RLRevenantHomingMissile", 52, -14, 0)
    Goto MissileEnd
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    REVE L 0
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		REVE L 0 A_SpawnItemEx("Midas_Statue_Agitation", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		REVE L 0 A_SpawnItemEx("Midas_Statue_Agitation", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		REVE L 0 A_SpawnItemEx("Midas_Statue_Agitation", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		REVE L 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		REVE L 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		REVE L 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

ACTOR RLRevenantMissile : RevenantTracer
{
   +NOTIMEFREEZE
   -SEEKERMISSILE
   +THRUGHOST
   +BLOODSPLATTER
   Decal "RevenantScorch"
   DamageType "Fire"
   PainType "Explosion"
   DeathType "Explosion"
   DeathSound ""
  States
  {
  Spawn:
    FATB AB 2 Bright
    Goto Spawn
  Death:
    TNT1 A 0 A_SetTranslucent (0.95, 1)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 3)
    TNT1 A 0 A_Quake (1, 8, 0, 256, "")
    TNT1 A 0 A_Quake (3, 8, 0, 128, "")
    TNT1 A 0 A_PlaySound ("skeleton/tracex", 7, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("skeleton/tracex", CHAN_ITEM, 0.05, 0, 0.15)
    FBXP A 8 Bright
    FBXP B 6 Bright
    FBXP C 4 Bright
    Stop
  }
}

ACTOR RLRevenantHomingMissile : RLRevenantMissile
{
   +SEEKERMISSILE
   +DONTSEEKINVISIBLE
   +ROCKETTRAIL
  States
  {
  Spawn:
    FATB AB 2 Bright A_SeekerMissile (9, 9,SMF_LOOK,128)
    Goto Spawn
  }
}
//17, 17, to keep track of Kate knowledge

ACTOR RLRevenantMissile2 : RLRevenantMissile
{
   Damage 5
}

ACTOR RLRevenantHomingMissile2 : RLRevenantMissile2
{
   Damage 5
}

ACTOR RLSummonRevenantMissile : RLRevenantMissile
{
   +MTHRUSPECIES
}

ACTOR RLSummonRevenantHomingMissile : RLRevenantHomingMissile
{
   +MTHRUSPECIES
}

ACTOR RLSummonRevenantMissile2 : RLRevenantMissile2
{
   +MTHRUSPECIES
}

ACTOR RLSummonRevenantHomingMissile2 : RLRevenantHomingMissile2
{
   +MTHRUSPECIES
}

Actor RLRevenantMissileToken : Inventory
{
inventory.maxamount 1
}

ACTOR RLDRPGSummonedRevenant : RLRevenant
{
  -COUNTKILL
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  Raise:
    Stop
  }
}

ACTOR RLCCRevenant : RLRevenant
{
  +TOUCHY
  States
  {
  See:
    REVE AABBCCDDEEFF 2 A_Chase
    Loop
  Melee:
    REVE G 7
    REVE H 6
    REVE I 6
    Goto See
  Missile:
    REVE Z 8
    REVE J 8 Bright
    REVE K 14
    Goto See
  Death:
    REVE LM 7
    REVE N 7 A_Scream
    REVE O 7 A_NoBlocking
    REVE P 7
    REVE Q -1
    Stop
  }
}
