
// SPIDER MASTERMIND
//
ACTOR RLSpiderMastermind : RLSpiderMastermindBase 16417
{
  Health 3000
  
  Obituary "%o was outwitted by the Spider Mastermind."
  Tag "Spider Mastermind"
    //$category "MP Standard"
  
	// Guncaster compatibility
	DropItem "TreasureChest"
  States
  {
  Spawn:
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_JumpIfInventory("DRPGGreenAuraToken", 1, 2)
    TNT1 A 0 A_ChangeFlag("NOPAIN", 0)
  SpawnLoop:
    SMAS A Random(9,10) A_Look
    Goto SpawnLoop
	
  ClearTargetWindDown:
    TNT1 A 0 A_ClearTarget
    TNT1 A 0 A_LookEx (LOF_NOSEESOUND, 0, 0, 0, 360, "See")
    Goto MissileEnd
  FriendlyTarget:
    TNT1 A 0
    Goto ClearTargetWindDown
	
  See:
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_JumpIfInventory("DRPGGreenAuraToken", 1, 2)
    TNT1 A 0 A_ChangeFlag("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag("QUICKTORETALIATE", 1)
    TNT1 A 0 A_PlaySound("spider/walk", 5, 1, 0, 0.7)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(1, 12, 0, 384, "")
    SMAS AABB 3 A_Chase ("", "Missile")
    TNT1 A 0 A_PlaySound("spider/walk", 5, 1, 0, 0.7)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(1, 12, 0, 384, "")
    SMAS CCDD 3 A_Chase ("", "Missile")
    TNT1 A 0 A_PlaySound("spider/walk", 5, 1, 0, 0.7)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(1, 12, 0, 384, "")
    SMAS EEFF 3 A_Chase ("", "Missile")
    Loop
  Repositioning:
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_JumpIfInventory("DRPGGreenAuraToken", 1, 2)
    TNT1 A 0 A_ChangeFlag("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag("QUICKTORETALIATE", 1)
    TNT1 A 0 A_PlaySound("spider/walk", 5, 1, 0, 0.7)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(1, 12, 0, 384, "")
    SMAS AA 3 A_Wander
    TNT1 A 0 A_Jump (64, 2)
    TNT1 A 0 A_Chase ("", "Missile", CHF_DONTMOVE)
    SMAS BB 3 A_Wander
    TNT1 A 0 A_PlaySound("spider/walk", 5, 1, 0, 0.7)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(1, 12, 0, 384, "")
    SMAS CC 3 A_Wander
    TNT1 A 0 A_Jump (64, 2)
    TNT1 A 0 A_Chase ("", "Missile", CHF_DONTMOVE)
    SMAS DD 3 A_Wander
    TNT1 A 0 A_PlaySound("spider/walk", 5, 1, 0, 0.7)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(1, 12, 0, 384, "")
    SMAS EE 3 A_Wander
    TNT1 A 0 A_Jump (64, 2)
    TNT1 A 0 A_Chase ("", "Missile", CHF_DONTMOVE)
    SMAS FF 3 A_Wander
    TNT1 A 0 A_Jump (32, 1)
    Loop
    TNT1 A 0
    Goto Missile
	
  Overwatch:
    TNT1 A 0 A_PlaySound("rlmonsters/masterminigunendfire", CHAN_WEAPON, 1, 0, 0.4)
    TNT1 A 0 A_JumpIfInventory("DRPGGreenAuraToken", 1, 2)
    TNT1 A 0 A_ChangeFlag("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag("QUICKTORETALIATE", 1)
	Goto OverwatchLoop
  OverwatchLoop:
    TNT1 A 0 A_PlaySound("rlmonsters/masterminigunspin", 7, 1, 1, 1.2)
    TNT1 A 0 A_Chase ("", "MissileRestartFire", CHF_DONTMOVE)
    SMAS TU 1 A_FaceTarget
    TNT1 A 0 A_Chase ("", "MissileRestartFire", CHF_DONTMOVE)
    SMAS TU 1 A_FaceTarget
    TNT1 A 0 A_Jump (5, "MissileEnd")
    Loop
  MissileRestartFire:
    SMAS TUT 1 A_FaceTarget
    TNT1 A 0 A_Jump (256, 4,8,12,16,20,24)
    SMAS TUTUTUTUTUTUTUTUTUTUTUTU 1 A_FaceTarget
    TNT1 A 0 A_ChangeFlag("NOPAIN", 1)
    Goto RepeatFriendlyCheck
	
  MissileProper:
    TNT1 A 0 A_ChangeFlag("QUICKTORETALIATE", 0)
    SMAS U 8 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/chaingunwindup", 7)
    SMAS TU 4 A_FaceTarget
    SMAS TUTU 2 A_FaceTarget
    SMAS TUTUTUTU 1 A_FaceTarget
    TNT1 A 0 A_MonsterRefire(0, "Overwatch")
  RepeatProper:
    TNT1 A 0 A_ChangeFlag("QUICKTORETALIATE", 0)
    TNT1 A 0 A_PlaySound("rlmonsters/masterminigunspin", 7, 1, 1, 1.2)
    TNT1 A 0 A_PlaySound("rlmonsters/masterminigun", CHAN_WEAPON, 1, 1, 0.3)
    TNT1 A 0 A_JumpIfInventory ("RLSpiderMastermindStateCounter", 1, "MissileAlt")
    TNT1 A 0 A_GiveInventory ("RLSpiderMastermindStateCounter", 1)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissile") // Friendly monsters do not harm you
    SMAS G 1 Bright A_CustomBulletAttack (30, 5, 1, random(1,5) * 3, "RLSpiderMastermindBulletPuff", 0, CBAF_NORANDOM)
    TNT1 A 0 A_MonsterRefire(164, "Overwatch")
    Goto RepeatFriendlyCheck
  MissileAlt:
    TNT1 A 0 A_TakeInventory ("RLSpiderMastermindStateCounter", 1)
    TNT1 A 0 A_CheckFlag ("FRIENDLY", "SummonMissileAlt") // Friendly monsters do not harm you
    SMAS H 1 Bright A_CustomBulletAttack (30, 5, 1, random(1,5) * 3, "RLSpiderMastermindBulletPuff", 0, CBAF_NORANDOM)
    TNT1 A 0 A_MonsterRefire(164, "Overwatch")
    Goto RepeatFriendlyCheck
  MissileEnd:
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_JumpIfInventory("DRPGGreenAuraToken", 1, 2)
    TNT1 A 0 A_ChangeFlag("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag("QUICKTORETALIATE", 1)
    TNT1 A 0 A_PlaySound("rlmonsters/masterminigunend", 7)
    SMAS TUTUTUTU 1
    SMAS TUTU 2
    SMAS TU 4
    TNT1 A 0 A_Jump (180, "Repositioning")
    Goto See
	
  SummonMissile:
    SMAS G 1 Bright A_CustomBulletAttack (6, 2, 1, random(1,3) * 5, "RLSpiderMastermindBulletPuff", 0, CBAF_NORANDOM)
    TNT1 A 0 A_MonsterRefire(164, "Overwatch")
    Goto RepeatFriendlyCheck
  SummonMissileAlt:
    SMAS H 1 Bright A_CustomBulletAttack (6, 2, 1, random(1,3) * 5, "RLSpiderMastermindBulletPuff", 0, CBAF_NORANDOM)
    TNT1 A 0 A_MonsterRefire(164, "Overwatch")
    Goto RepeatFriendlyCheck
	
  PainMain:
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_ChangeFlag("QUICKTORETALIATE", 0)
    TNT1 A 0 ACS_NamedExecuteAlways("DRLA_BossPainCheck", 0)
    SMAS I 3
    SMAS I 3 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLSpiderMastermindKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_StopSound(7)
    SMAS J 20 A_Scream
    SMAS K 10 A_NoBlocking
    SMAS L 10
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(7, 30, 0, 1536, "")
    SMAS MNO 10 Bright
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(1, 20, 0, 768, "")
    SMAS PQ 10 Bright
    SMAS R 10
    SMAS S 30
    SMAS S 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    SMAS S 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLSpiderMastermindKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_StopSound(7)
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  CrushDRLA:
    TNT1 A 30 A_SpawnItemEx("RLCrushedLarge",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
	
  Pain.RigelBlast:
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 S 2 Bright
    Goto See
  Pain.NeuralStun:
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_StopSound(7)
    D2F1 S 2 Bright
    Goto See
  Pain.CyberDisruptor:
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_JumpIfInventory("DRPGGreenAuraToken", 1, 2)
    TNT1 A 0 A_ChangeFlag("NOPAIN", 0)
    TNT1 A 0 A_ChangeFlag("QUICKTORETALIATE", 1)
    Goto Pain.LightningBlue
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  XDeath.RigelBlast:
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 10000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLSpiderMastermindKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_StopSound(CHAN_WEAPON)
    TNT1 A 0 A_StopSound(7)
    TNT1 A 0 A_PlaySound("weapons/dn2gunbigexplosion", 7, 1, 0, 0.3)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SetUserVar("user_dn2bossexplosiontimer", 80)
  DN2BossExplosionLoop:
    TNT1 A 0 A_JumpIf (user_dn2bossexplosiontimer <= 0, "DN2BossExplosionFinish")
    TNT1 A 0 A_Jump(190, 2)
    TNT1 A 0 A_RadiusGive ("RLDN2BossFlash", 768, RGF_PLAYERS, 1)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(4, 2, 0, 768, "")
    SMAS I 1 Bright
    TNT1 A 0 A_Jump(150, 2)
    TNT1 A 0 A_PlaySound("weapons/dn2gunbigexplosion", 7, 1, 0, 0.3)
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RandomExplosion", frandom(-84,84),frandom(-84,84),frandom(4,90), 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 1
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RandomExplosion", frandom(-84,84),frandom(-84,84),frandom(4,90), 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SetUserVar("user_dn2bossexplosiontimer", user_dn2bossexplosiontimer - 1)
    Goto DN2BossExplosionLoop
  DN2BossExplosionFinish:
    TNT1 A 0 A_RadiusGive ("RLDN2BossFlash2", 1560, RGF_PLAYERS, 1)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(9, 15, 0, 1560, "")
    TNT1 A 0 A_FaceTarget
    TNT1 A 0 A_PlaySound("weapons/dn2gunbigexplosion", 7, 1, 0, 0)
//    TNT1 A 0 A_SpawnItemEx ("RLDuke2BossExplosion", 0,0,48, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2ShockwaveLeft", 0,12,48, 0,14,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2ShockwaveRight", 0,-12,48, 0,-14,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    TNT1 A 0 A_BossDeath
	Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================
  Duke2LaserAttack:
    SMAS T 10 A_FaceTarget
  Duke2LaserRepeat:
    TNT1 A 0 A_ChangeFlag("QUICKTORETALIATE", 0)
    SMAS GH 1 Bright A_CustomMissile ("RLDuke2EnemyBasicShot", 43, 8, frandom(-15,15), CMF_OFFSETPITCH, frandom(-3,3))
	TNT1 A 0 A_MonsterRefire (200, "Duke2LaserEnd")
    Goto Duke2LaserRepeat
  Duke2LaserEnd:
    SMAS U 10 A_FaceTarget
    Goto See
	
  ShadowAuraMissileAttack:
    TNT1 A 0 A_ChangeFlag("QUICKTORETALIATE", 0)
    SMAS TUTUTUTUTUTUTUTU 1 A_FaceTarget
  ShadowAuraRepeatAttack:
    TNT1 A 0 A_PlaySound("rlmonsters/masterminigunspin", 7, 1, 1, 1.2)
    TNT1 A 0 A_PlaySound("rlmonsters/masterminigun", CHAN_WEAPON, 1, 1, 0.3)
    TNT1 A 0 A_JumpIfInventory ("RLSpiderMastermindStateCounter", 1, "ShadowAuraMissileAttackAlt")
    TNT1 A 0 A_GiveInventory ("RLSpiderMastermindStateCounter", 1)
    SMAS G 1 Bright A_CustomBulletAttack (5, 5, 1, random(1,5) * 3, "RLSpiderMastermindBulletPuff", 0, CBAF_NORANDOM)
    TNT1 A 0 A_MonsterRefire(164, "Overwatch")
    Goto RepeatFriendlyCheck
  ShadowAuraMissileAttackAlt:
    TNT1 A 0 A_TakeInventory ("RLSpiderMastermindStateCounter", 1)
    SMAS H 1 Bright A_CustomBulletAttack (5, 5, 1, random(1,5) * 3, "RLSpiderMastermindBulletPuff", 0, CBAF_NORANDOM)
    TNT1 A 0 A_MonsterRefire(164, "Overwatch")
    Goto RepeatFriendlyCheck
	
//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    SMAS I 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		"####" "#" 0 A_StopSound(CHAN_WEAPON)
		"####" "#" 0 A_StopSound(7)
		SMAS I 0 A_SpawnItemEx("Midas_Statue_Mastermind", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		"####" "#" 0 A_StopSound(CHAN_WEAPON)
		"####" "#" 0 A_StopSound(7)
		SMAS I 0 A_SpawnItemEx("Midas_Statue_Mastermind", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		"####" "#" 0 A_StopSound(CHAN_WEAPON)
		"####" "#" 0 A_StopSound(7)
		SMAS I 0 A_SpawnItemEx("Midas_Statue_Mastermind", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		"####" "#" 0 A_StopSound(CHAN_WEAPON)
		"####" "#" 0 A_StopSound(7)
		SMAS I 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		"####" "#" 0 A_StopSound(CHAN_WEAPON)
		"####" "#" 0 A_StopSound(7)
		SMAS I 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		"####" "#" 0 A_StopSound(CHAN_WEAPON)
		"####" "#" 0 A_StopSound(7)
		SMAS I 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

Actor RLSpiderMastermindStateCounter : Inventory
{
inventory.maxamount 1
}

ACTOR RLDRPGSummonedSpiderMastermind : RLSpiderMastermind
{
  -COUNTKILL
  +NOBLOCKMONST
  +NOTELESTOMP
  +NOFEAR
  +SEEINVISIBLE
  +DONTDRAIN
  +ALWAYSFAST
  +QUICKTORETALIATE
  +MISSILEMORE
  +THRUSPECIES
  Species "Player"
  States
  {
  Spawn:
	TNT1 A 0 NoDelay ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::Spawn
	See:
	TNT1 A 0 ACS_NamedExecuteAlways("MonsterInit", 0)
    TNT1 A 0 A_GiveInventory ("RLMonsterInitializerToken", 1)
    TNT1 A 0 A_GiveInventory ("DRPGDRLASummonedMonsterToken", 1)
	Goto Super::See
  }
}

ACTOR RLCCSpiderMastermind : RLSpiderMastermind
{
  +TOUCHY
  States
  {
  See:
    SMAS TUTUTUTUTUTUTUTU 1
    Loop
  Missile:
    SMAS GH 1 Bright
    Loop
  Melee:
    Stop
  Death:
    SMAS J 20 A_Scream
    SMAS K 10 A_NoBlocking
    SMAS L 10
    SMAS MNOPQ 10 Bright
    SMAS R 10
    SMAS S 30
    SMAS S -1 A_BossDeath
    Stop
  }
}
