
// SPIDER MASTERMIND (FUSION MORTAR)
//
ACTOR RLSpiderMastermindMortar : RLSpiderMastermindBase 16638
{
  Health 3000
  Obituary "%o underwent fusion due to the Spider Disastermind."
  
  +MISSILEMORE
  +MISSILEEVENMORE
  
  SeeSound "mortarspider/sight"
  PainSound "mortarspider/pain"
  
  Tag "Spider Disastermind"
    //$category "MP Standard"
  
	// Guncaster compatibility
	DropItem "TreasureChest"
	
  var int user_guessed_target_dx;
  var int user_guessed_target_dy;
  var int user_aim_vel_hor;
  var int user_aim_vel_ver;
  var int user_can_aim_arc;
  States
  {
  Spawn:
    SFUM A 2 A_Look
    Goto Spawn
	
  See:
    TNT1 A 0 A_PlaySound("spider/walk", 5, 1, 0, 0.7)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(1, 12, 0, 384, "")
    SFUM AABB 3 A_Chase ("", "Missile")
    TNT1 A 0 A_PlaySound("spider/walk", 5, 1, 0, 0.7)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(1, 12, 0, 384, "")
    SFUM CCDD 3 A_Chase ("", "Missile")
    TNT1 A 0 A_PlaySound("spider/walk", 5, 1, 0, 0.7)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(1, 12, 0, 384, "")
    SFUM EEFF 3 A_Chase ("", "Missile")
    Loop
	
  MissileProper:
    TNT1 A 0 A_PlaySound("rlmonsters/fusionmortaractivate", CHAN_WEAPON, 1, 0, 0.9)
  MissileProperOverwatch:
	TNT1 A 0 A_JumpIf(CallACS(
		"RLStoreArc",
		30 << 16,		// speed
		AAPTR_TARGET,	// what to hit
		32 << 16,		// z-offset you wanna spawn the projectile at
		false) == false, "CantHit") // aim low (false) or high (true)
    TNT1 A 0 ACS_NamedExecuteWithResult("RLStoreCircleStrafePrediction", AAPTR_TARGET)
	
    SFUM G 12 A_FaceTarget
    TNT1 A 0 A_FaceTarget
    TNT1 A 0 A_CustomMissile("RLMastermindFusionMortar", 32, 10, 0, CMF_OFFSETPITCH, 45)
    SFUM H 12 Bright A_FaceTarget
    SFUM G 6 A_FaceTarget
    TNT1 A 0 A_PlaySound("rlmonsters/fusionmortarreload", 7, 1, 0, 1.1)
    SFUM G 12 A_FaceTarget
	Goto See
  CantHit:
    SFUM G 12 A_FaceTarget
    TNT1 A 0 A_Jump (80, "MissileProperOverwatch")
	Goto See
	
/*	TNT1 A 0 A_SetUserVar("user_can_aim_arc", 30)
    TNT1 A 0 A_SetUserVar("user_can_aim_arc", user_can_aim_arc - 1)
	TNT1 A 0 A_JumpIf(0 < user_can_aim_arc, "MajorTom")*/
	
  PainMain:
    TNT1 A 0 ACS_NamedExecuteAlways("DRLA_BossPainCheck", 0)
    SFUM I 3
    SFUM I 3 A_Pain
    Goto See
	
  DeathMain:
    TNT1 A 0 A_GiveInventory ("RLSpiderMastermindKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_GiveToTarget ("RLBerserkerBloodlustBonusCheck", 1)
    SFUM J 20 A_Scream
    SFUM K 10 A_NoBlocking
    SFUM L 10
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(7, 30, 0, 1536, "")
    SFUM MNO 10 Bright
    TNT1 A 0 A_SpawnItemEx ("RLGibber", 0,0,0, VelX,VelY,VelZ, 0, SXF_ABSOLUTEMOMENTUM | SXF_USEBLOODCOLOR | SXF_NOCHECKPOSITION)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(1, 20, 0, 768, "")
    SFUM PQ 10 Bright
    SFUM R 10
    SFUM S 30
    SFUM S 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
  DeathFrame:
    SFUM S 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathEnd")
    Goto DeathEnd
	
	//Ice
  GenericFreezeDeath:
	"####" "#" 0 A_GiveInventory ("RLSpiderMastermindKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    "####" "#" 0 A_Jump(256, "GenericFreezeMana")
    Goto GenericFreezeMana
	
  CrushDRLA:
    TNT1 A 30 A_SpawnItemEx("RLCrushedLarge",0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
    "####" "#" 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "CrushEnd")
    Goto CrushEnd
//==============================================================================
//					--	DOOMRL ARSENAL STUFF  --
//==============================================================================
  Pain.RigelBlast:
    TNT1 A 0 A_PlaySound("weapons/dn2gunhit", CHAN_BODY)
    D2F1 S 2 Bright
    Goto See
  Pain.NeuralStun:
    D2F1 S 2 Bright
    Goto See
  Pain.CyberDisruptor:
    TNT1 A 0
    Goto Pain.LightningBlue
	
  Death.NeuralStun:
    TNT1 A 0
    Goto Death
  XDeath.RigelBlast:
  Death.RigelBlast:
    TNT1 A 0 A_GiveInventory ("RLDuke2Score", 10000, AAPTR_TARGET)
    TNT1 A 0 A_GiveInventory ("RLSpiderMastermindKillIncrementer", 1, AAPTR_PLAYER1) // Used for tallying total kills and bestiary info
    TNT1 A 0 A_PlaySound("weapons/dn2gunbigexplosion", 7, 1, 0, 0.3)
    TNT1 A 0 A_NoBlocking
    TNT1 A 0 A_SetUserVar("user_dn2bossexplosiontimer", 80)
  DN2BossExplosionLoop:
    TNT1 A 0 A_JumpIf (user_dn2bossexplosiontimer <= 0, "DN2BossExplosionFinish")
    TNT1 A 0 A_Jump(190, 2)
    TNT1 A 0 A_RadiusGive ("RLDN2BossFlash", 768, RGF_PLAYERS, 1)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(4, 2, 0, 768, "")
    SFUM I 1 Bright
    TNT1 A 0 A_Jump(150, 2)
    TNT1 A 0 A_PlaySound("weapons/dn2gunbigexplosion", 7, 1, 0, 0.3)
    TNT1 A 0 A_Jump(100, 2)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RandomExplosion", frandom(-84,84),frandom(-84,84),frandom(4,90), 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 1
    TNT1 A 0 A_SpawnItemEx ("RLDuke2RandomExplosion", frandom(-84,84),frandom(-84,84),frandom(4,90), 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SetUserVar("user_dn2bossexplosiontimer", user_dn2bossexplosiontimer - 1)
    Goto DN2BossExplosionLoop
  DN2BossExplosionFinish:
    TNT1 A 0 A_RadiusGive ("RLDN2BossFlash2", 1560, RGF_PLAYERS, 1)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 2)
    TNT1 A 0 A_Quake(9, 15, 0, 1560, "")
    TNT1 A 0 A_FaceTarget
    TNT1 A 0 A_PlaySound("weapons/dn2gunbigexplosion", 7, 1, 0, 0)
//    TNT1 A 0 A_SpawnItemEx ("RLDuke2BossExplosion", 0,0,48, 0,0,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2ShockwaveLeft", 0,12,48, 0,14,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 0 A_SpawnItemEx ("RLDuke2ShockwaveRight", 0,-12,48, 0,-14,0, 0, SXF_NOCHECKPOSITION)
    TNT1 A 35
    TNT1 A 0 A_BossDeath
	Stop
	
//==============================================================================
//					--	Special Monster Attacks  --
//==============================================================================

//==============================================================================
//					--	Final Doomer Compatibility Stuff  --
//==============================================================================
  DeathXSparkFrame:
    "####" "#" 0 A_JumpIfInTargetInventory("Mana",0,2)
    "####" "#" 0 A_DropItem("MajorManaPod",-1,54)
    SFUM I 0 A_BossDeath
    "####" "#" 0 A_Jump(256, "DeathXSpark")
	Goto DeathXSpark
	
//==============================================================================
//					--	Guncaster Compatibility Stuff  --
//==============================================================================
	MidasFrame1:
		SFUM I 0 A_SpawnItemEx("Midas_Statue_Mastermind", 0,0,0, 0,0,0, 0,SXF_TRANSFERPOINTERS|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame2:
		SFUM I 0 A_SpawnItemEx("Midas_Statue_Mastermind", 0,0,0, frandom(-10.0,-12.0),0,frandom(1.0,3.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
	MidasFrame3:
		SFUM I 0 A_SpawnItemEx("Midas_Statue_Mastermind", 0,0,0, frandom(-15.0,-20.0),0,frandom(10.0,15.0), 0,SXF_TRANSFERPOINTERS|SXF_SETMASTER|SXF_TRANSFERSPRITEFRAME)
		TNT1 A 10 A_KillChildren
		TNT1 A 0 A_JumpIf(1, "DestroyedEnd")
		Goto DestroyedEnd
		
	//Gumpop
	Death.Acid:
		SFUM I 1 A_ChangeFlag("SOLID",0)
		"####" "#" 1 A_Playsound("Gumpop/Expand",5)
		"####" "###################################" 1 A_SetScale(ScaleX+frandom(0.01,0.025))
		"####" "#" 1 A_Playsound("Gumpop/Pop",5)
		"####" "#" 0 A_Jump(256,"XDeathMain")
		Goto XDeathMain
		
	//Thunderstruck
	Pain.Lightning:
		"####" "#" 0 A_Jump(164,1)
		Goto Pain
		SFUM I 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"LightningLock")
		Goto LightningLock
		
	//Cauterizer
	Pain.LightningBlue:
		"####" "#" 0 A_Jump(48,1)
		Goto Pain
		SFUM I 0 A_ChangeFlag("NOPAIN",1)
		"####" "#" 0 A_SetUserVar("User_LightningLock", User_LightningLock + 10)
		"####" "#" 0 A_Jump(256,"BlueLightningLock")
		Goto BlueLightningLock
  }
}

ACTOR RLMastermindFusionMortar
{
  Radius 12
  Height 8
  Speed 16
  Scale 1.0
  Damage (100)
  DamageType "Plasma"
  Projectile
  +SEEKERMISSILE
  +NOTIMEFREEZE
  +BLOODSPLATTER
  -NOGRAVITY
  Gravity 0.5
  States
  {
  Spawn:
    TNT1 A 0
	TNT1 A 0 ACS_NamedExecuteWithResult("RLVelToTargetArc")
    TNT1 A 0 A_PlaySound("rlmonsters/fusionmortarfire", CHAN_WEAPON, 1, 0, 0.5)
    TNT1 A 0 A_PlaySound("rlmonsters/fusionmortarloop", 7, 1, 1, 1.2)
  SpawnLoop:
    FUMP A 1 Bright A_SpawnItemEx ("RLMastermindFusionMortarTrail", 16,0,0, 0,0,0, 180, SXF_NOCHECKPOSITION)
    Loop
	
  Death:
	TNT1 A 0 A_SpawnItemEx ("RLMastermindFusionMortarRing", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
	TNT1 A 0 A_SpawnItemEx ("RLMastermindFusionMortarFlame3", 0,0,0, 0,0,0, 0, SXF_NOCHECKPOSITION)
	TNT1 AAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAAA 0 A_SpawnItemEx ("RLMastermindFusionMortarFlame2", frandom(-5.0,5.0),frandom(-5.0,5.0),frandom(1.0,8.0), frandom(-5.0,5.0),frandom(-5.0,5.0),frandom(-5.0,5.0), 0, SXF_NOCHECKPOSITION)
	TNT1 AAAAA 0 A_SpawnItemEx ("RLMastermindFusionMortarShrapnel", frandom(-5.0,5.0),frandom(-5.0,5.0),frandom(1.0,8.0), frandom(-14.0,14.0),frandom(-14.0,14.0),frandom(12.0,20.0), 0, SXF_NOCHECKPOSITION)
	TNT1 A 0 A_JumpIf(CallACS("DRLA_MonsterQuake") == 0, 4)
    TNT1 A 0 A_Quake (1, 50, 0, 2048, "")
    TNT1 A 0 A_Quake (3, 40, 0, 1024, "")
    TNT1 A 0 A_Quake (9, 32, 0, 300, "")
    TNT1 A 0 A_PlaySound("rlmonsters/fusionmortarexplosion", CHAN_WEAPON, 1, 0, 0.7)
    TNT1 A 0 A_PlaySound("rlmonsters/fusionmortarexplosion", 7, 0.1, 0, 0.05)
	TNT1 A 0 A_Explode (256, 256, 0)
	TNT1 A 0 A_SetScale (2.5)
    FUMX AAAA 1 Bright A_SpawnItemEx ("RLMastermindFusionMortarFlame", frandom(-5.0,5.0),frandom(-5.0,5.0),1+frandom(1.0,3.0), frandom(-1.0,1.0),frandom(-1.0,1.0),frandom(-1.0,1.0), 0, SXF_NOCHECKPOSITION)
    FUMX BBBBB 1 Bright A_SpawnItemEx ("RLMastermindFusionMortarFlame", frandom(-5.0,5.0),frandom(-5.0,5.0),8+frandom(1.0,3.0), frandom(-1.0,1.0),frandom(-1.0,1.0),frandom(-1.0,1.0), 0, SXF_NOCHECKPOSITION)
    FUMX CCCCCC 1 Bright A_SpawnItemEx ("RLMastermindFusionMortarFlame", frandom(-5.0,5.0),frandom(-5.0,5.0),14+frandom(1.0,3.0), frandom(-1.0,1.0),frandom(-1.0,1.0),frandom(-1.0,1.0), 0, SXF_NOCHECKPOSITION)
    FUMX D 7 Bright
    FUMX E 8 Bright
    Stop
  }
}

ACTOR RLMastermindFusionMortarTrail
{
  RenderStyle Translucent
  Alpha 0.85
  Scale 0.9
  +NOGRAVITY
  +NOINTERACTION
  +NOCLIP
  +THRUACTORS
  +FORCEXYBILLBOARD
  States
  {
  Spawn:
    TNT1 A 1
    TNT1 A 0 A_SetScale (scalex+frandom(0.0,0.06))
    TNT1 A 0 A_FadeTo (0, 0.03, 1)
    FMSK A 1 A_SetScale (scalex+frandom(0.1,0.13))
    TNT1 A 0 A_FadeTo (0, 0.03, 1)
    FMSK B 1 A_SetScale (scalex+frandom(0.1,0.13))
    TNT1 A 0 A_FadeTo (0, 0.03, 1)
    FMSK C 1 A_SetScale (scalex+frandom(0.1,0.13))
    TNT1 A 0 A_FadeTo (0, 0.03, 1)
    FMSK D 1 A_SetScale (scalex+frandom(0.1,0.13))
    TNT1 A 0 A_FadeTo (0, 0.03, 1)
    FMSK E 1 A_SetScale (scalex+frandom(0.1,0.13))
    TNT1 A 0 A_FadeTo (0, 0.03, 1)
    FMSK F 1 A_SetScale (scalex+frandom(0.1,0.13))
  SpawnLoop:
    TNT1 A 0 A_FadeTo (0, 0.03, 1)
    FMSK G 1 A_SetScale (scalex+frandom(0.1,0.13))
    Loop
  }
}

ACTOR RLMastermindFusionMortarRing
{
  RenderStyle Add
  Alpha 0.75
  Scale 2.0
  +NOGRAVITY
  +NOINTERACTION
  +NOCLIP
  +THRUACTORS
  +FORCEXYBILLBOARD
  States
  {
  Spawn:
    TNT1 A 0
    SHOK ABCDEFGHIJKLMNOPQR 1 A_FadeTo (0, 0.01, 1)
    Stop
  }
}

ACTOR RLMastermindFusionMortarFlame
{
  RenderStyle Add
  Alpha 0.65
  Scale 1.0
  +NOGRAVITY
  +NOINTERACTION
  +NOCLIP
  +THRUACTORS
  +FORCEXYBILLBOARD
  States
  {
  Spawn:
    TNT1 A random(0,3)
    TNT1 A 0 A_SetScale (scalex*frandom(1.0,1.2))
    PFRX ABCDEFGHIJKLMNO random(1,3) A_FadeTo (0, 0.02, 1)
    Stop
  }
}

ACTOR RLMastermindFusionMortarFlame2 : RLMastermindFusionMortarFlame
{
  Alpha 0.85
  Scale 1.6
  States
  {
  Spawn:
    TNT1 A random(0,1)
    TNT1 A 0 A_SetScale (scalex*frandom(1.0,1.2))
    PFRX ABCDEFGHIJKLMNO random(2,4) A_FadeTo (0, 0.04, 1)
    Stop
  }
}

ACTOR RLMastermindFusionMortarFlame3 : RLMastermindFusionMortarFlame
{
  Alpha 0.35
  Scale 2.5
  States
  {
  Spawn:
    TNT1 A 0
    TNT1 A 0 A_SetScale (scalex*frandom(1.0,1.2))
    PFRX ABCDEFGHIJKLMNO 3 A_FadeTo (0, 0.04, 1)
    Stop
  }
}

ACTOR RLMastermindFusionMortarShrapnel
{
  RenderStyle None
  Projectile
  Gravity 0.65
  -NOGRAVITY
  +THRUACTORS
  +FORCEXYBILLBOARD
  +ROCKETTRAIL
  States
  {
  Spawn:
    TNT1 A 1
    Loop
  Death:
    TNT1 A 1
    Stop
  }
}
